(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id$ *)

type 'a foterm = 
  | Leaf of 'a
  | Var of int
  | Node of ('a foterm) list

type 'a substitution = (int * 'a foterm) list

type comparison = Lt | Le | Eq | Ge | Gt | Incomparable

type rule = SuperpositionRight | SuperpositionLeft | Demodulation
type direction = Left2Right | Right2Left | Nodir
type position = int list

type 'a proof =
  | Exact of 'a
  | Step of rule * int * int * direction * position * 'a substitution
         (* rule, eq1, eq2, direction of eq2, position, substitution *)

type 'a literal = 
 | Equation of    'a foterm  (* lhs *)
                * 'a foterm  (* rhs *)
                * 'a foterm  (* type *)
                * comparison (* orientation *)
 | Predicate of   'a foterm 

type varlist = int list

type 'a unit_clause =
   int        (* ID *)
 * 'a literal
 * varlist
 * 'a proof      (* proof *)

type 'a passive_clause = int * 'a unit_clause (* weight * equation *)

module M : Map.S with type key = int 

type 'a bag = 'a unit_clause M.t

module type Blob =
  sig
    type t
    val eq : t -> t -> bool
    val compare : t -> t -> int
    val pp : t -> string
  end

module Utils (B : Blob) :
  sig
    val eq_literal : B.t literal -> B.t literal -> bool
    val compare_literal : B.t literal -> B.t literal -> int

    val eq_unit_clause : B.t unit_clause -> B.t unit_clause -> bool
    val compare_unit_clause : B.t unit_clause -> B.t unit_clause -> int
  end