(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: nCicRefiner.ml 9802 2009-05-25 15:39:26Z tassi $ *)

class type ctstatus =
 object ('self)
  inherit NCicUnifHint.status
  inherit NCicCoercion.status
  inherit NCicLibrary.status
  method set_rstatus : ctstatus -> 'self
 end

class status : ctstatus =
 object (self)
  inherit NCicUnifHint.status
  inherit NCicCoercion.status
  inherit NCicLibrary.status
  method set_rstatus o =
   ((self#set_unifhint_status (o :> NCicUnifHint.status))
         #set_coercion_status (o :> NCicCoercion.status))
         #set_library_status  (o :> NCicLibrary.status)
 end

type sstatus = status

module Serializer =
 struct
  include NCicLibrary.Serializer(struct type status = sstatus end)

  let require ~baseuri status = 
   let rstatus = require ~baseuri (status : #status :> status) in
   let status = status#set_uhint_db (rstatus#uhint_db) in
   let status = status#set_coerc_db (rstatus#coerc_db) in
   let status = status#set_timestamp (rstatus#timestamp) in
    status 
 end

class type ctdumpable_status =
 object ('self)
  inherit status
  method dump: Serializer.obj list
  method set_dump: Serializer.obj list -> 'self
  method set_dumpable_status: ctdumpable_status -> 'self
 end

class dumpable_status : ctdumpable_status =
 object
  inherit status
  val dump = ([] : Serializer.obj list)
  method dump = dump
  method set_dump v = {< dump = v >}
  method set_dumpable_status o =
   {< dump = o#dump >}#set_rstatus (o :> status)
 end