(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)

exception Error of string lazy_t
let fail msg = raise (Error msg)

type lowtac_status = {
        pstatus : NCic.obj;
        lstatus : LexiconEngine.status
}

type lowtactic = lowtac_status -> int -> lowtac_status 

type tac_status = {
        gstatus : Continuationals.Stack.t; 
        istatus : lowtac_status;
} 

type tactic = tac_status -> tac_status

type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input

let pp_tac_status status = 
  prerr_endline (NCicPp.ppobj status.istatus.pstatus)
;;

let pp_lowtac_status status = 
  prerr_endline "--------------------------------------------";
  prerr_endline (NCicPp.ppobj status.pstatus)
;;

type cic_term = NCic.conjecture (* name, context, term *)
let ctx_of (_,c,_) = c ;;

let relocate context (name,ctx,t as term) =
  let is_prefix l1 l2 =
    let rec aux = function
      | [],[] -> true
      | x::xs, y::ys -> x=y && aux (xs,ys)
      | _ -> false
    in
      aux (List.rev l1, List.rev l2)
  in
  if ctx == context then term else 
  if ctx = context then term else 
  if is_prefix ctx context then 
    (name, context, 
      NCicSubstitution.lift (List.length context - List.length ctx) t)
  else
    assert false
;;

let term_of_cic_term t c = 
  let _,_,t = relocate c t in
  t
;;

type ast_term = string * int * CicNotationPt.term

let disambiguate (status : lowtac_status) (t : ast_term)  
                 (ty : cic_term option) context =
 let uri,height,metasenv,subst,obj = status.pstatus in
 let expty = 
   match ty with 
   | None -> None | Some ty -> let _,_,x = relocate context ty in Some x 
 in
 let metasenv, subst, lexicon_status, t = 
   GrafiteDisambiguate.disambiguate_nterm expty
    status.lstatus context metasenv subst t 
 in
 let new_pstatus = uri,height,metasenv,subst,obj in
 { lstatus = lexicon_status; pstatus = new_pstatus }, (None, context, t) 
;;

let typeof status ctx t =
  let _,_,metasenv,subst,_ = status.pstatus in
  let _,_,t = relocate ctx t in
  let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
  None, ctx, ty
;;
  
let whd status ?delta ctx t =
  let _,_,metasenv,subst,_ = status.pstatus in
  let name,_,t = relocate ctx t in
  let t = NCicReduction.whd ~subst ?delta ctx t in
  name, ctx, t
;;
  
let unify status ctx a b =
  let n,h,metasenv,subst,o = status.pstatus in
  let _,_,a = relocate ctx a in
  let _,_,b = relocate ctx b in
  let metasenv, subst = 
    NCicUnification.unify (NCicUnifHint.db ()) metasenv subst ctx a b
  in
  { status with pstatus = n,h,metasenv,subst,o }
;;

let refine status ctx term expty =
  let nt,_,term = relocate ctx term in
  let ne, expty = 
    match expty with None -> None, None 
    | Some e -> let n,_, e = relocate ctx e in n, Some e
  in
  let name,height,metasenv,subst,obj = status.pstatus in
  let db = NCicUnifHint.db () in (* XXX fixme *)
  let coercion_db = NCicCoercion.db () in
  let look_for_coercion = NCicCoercion.look_for_coercion coercion_db in
  let metasenv, subst, t, ty = 
   NCicRefiner.typeof db ~look_for_coercion metasenv subst ctx term expty
  in
  { status with pstatus = (name,height,metasenv,subst,obj) }, 
  (nt,ctx,t), (ne,ctx,ty)
;;

let get_goalty (status : lowtac_status) (g : int) =
 let _,_,metasenv,_,_ = status.pstatus in
 List.assoc g metasenv
;;

let instantiate status i t =
 let (gname, context, _ as gty) = get_goalty status i in
 let status, (_,_,t), (_,_,ty) = 
   refine status (ctx_of gty) t (Some gty) 
 in

 let name,height,metasenv,subst,obj = status.pstatus in
 let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 let subst = (i, (gname, context, t, ty)) :: subst in
 { status with pstatus = (name,height,metasenv,subst,obj) }
;;

let mk_meta status ?name ctx bo_or_ty =
  let n,h,metasenv,subst,o = status.pstatus in
  match bo_or_ty with
  | `Decl ty ->
      let _,_,ty = relocate ctx ty in
      let metasenv, _, instance, _ = 
        NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty)
      in
      let status = { status with pstatus = n,h,metasenv,subst,o } in
      status, (None,ctx,instance)
  | `Def bo ->
      let _,_,bo_ as bo = relocate ctx bo in
      let _,_,ty = typeof status ctx bo in
      let metasenv, metano, instance, _ = 
        NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty) in
      let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
      let subst = (metano, (name, ctx, bo_, ty)) :: subst in
      let status = { status with pstatus = n,h,metasenv,subst,o } in
      status, (None,ctx,instance)
;;

(* the following unification problem will be driven by 
 *   select s argsno t pattern
 *
 *   ? args = t
 *
 *   where argsn = length args and the pattern matches t
 *)
let select_term low_status argsno (name,context,term) (wanted,path) =
  let found status ctx t wanted =
    (* we could lift wanted step-by-step *)
    try true, unify status ctx (None, ctx, t) wanted
    with 
    | NCicUnification.UnificationFailure _ 
    | NCicUnification.Uncertain _ -> false, status
  in
  let match_term status ctx (wanted : cic_term) t =
    let rec aux ctx status t =
      let b, status = found status ctx t wanted in
      if b then 
        let status, (_,_,t) = 
          mk_meta status ~name:NCicMetaSubst.in_scope_tag 
            ctx (`Def (None, ctx, t))
        in    
        status, t
      else NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux status t
     in 
       aux ctx status t
  in 
  let _,_,_,subst,_ = low_status.pstatus in
  let rec select status ctx pat cic = 
    match pat, cic with
    | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
        let cic = 
          let _,_,t,_ = NCicUtils.lookup_subst i subst in
          NCicSubstitution.subst_meta lc t
        in
        select status ctx pat cic
    | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
        let status, t = select status ctx t1 t2 in
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Def (s2,t2)) :: ctx in
        let status, b = select status ctx b1 b2 in
        status, NCic.LetIn (n,t,s,b)
    | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Decl s2) :: ctx in
        let status, t = select status ctx t1 t2 in
        status, NCic.Lambda (n,s,t)
    | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Decl s2) :: ctx in
        let status, t = select status ctx t1 t2 in
        status, NCic.Prod (n,s,t)
    | NCic.Appl l1, NCic.Appl l2 ->
        let status, l = 
           List.fold_left2
             (fun (status,l) x y -> 
              let status, x = select status ctx x y in
              status, x::l)
             (status,[]) l1 l2
        in
        status, NCic.Appl (List.rev l)
    | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
        let status, t = select status ctx t1 t2 in
        let status, ot = select status ctx ot1 ot2 in
        let status, pl = 
           List.fold_left2
             (fun (status,l) x y -> 
              let status, x = select status ctx x y in
              status, x::l)
             (status,[]) pl1 pl2
        in
        status, NCic.Match (u,ot,t,List.rev pl)
    | NCic.Implicit `Hole, t -> 
        (match wanted with
        | Some wanted -> 
             let status, wanted = disambiguate status wanted None ctx in
             match_term status ctx wanted t
        | None -> match_term status ctx (None,ctx,t) t)
    | NCic.Implicit _, t -> status, t
    | _,t -> 
        fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
          ~context:[] ~subst:[] pat ^ " against " ^ 
          NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
  in
  let status, term = select low_status context path term in
  let term = (name, context, term) in
  mk_meta status ~name:(NCicMetaSubst.out_scope_tag argsno) context (`Def term)
;;

let analyse_indty status ty = 
 let ref, args =
  match whd status (ctx_of ty) ty with
   | _,_,NCic.Const ref -> ref, []
   | _,_,NCic.Appl (NCic.Const ref :: args) -> ref, args
   | _,_,_ -> fail (lazy ("not an inductive type")) in
 let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 let _,_,_,cl = List.nth tl i in
 let consno = List.length cl in
 let left, right = HExtlib.split_nth lno args in
 ref, consno, left, right
;;

let mk_cic_term c t = None,c,t ;;