(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)

exception Error of string lazy_t
let fail msg = raise (Error msg)

type lowtac_status = {
        pstatus : NCic.obj;
        lstatus : LexiconEngine.status
}

type lowtactic = lowtac_status -> int -> lowtac_status 

type tac_status = {
        gstatus : Continuationals.Stack.t; 
        istatus : lowtac_status;
} 

type tactic = tac_status -> tac_status

type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input

let pp_tac_status status = 
  prerr_endline (NCicPp.ppobj status.istatus.pstatus)
;;

let pp_lowtac_status status = 
  prerr_endline "--------------------------------------------";
  prerr_endline (NCicPp.ppobj status.pstatus)
;;

type cic_term = NCic.conjecture (* name, context, term *)
let ctx_of (_,c,_) = c ;;

let relocate status destination (name,source,t as orig) =
 if source == destination then status, orig else
  let u, d, metasenv, subst, o = status.pstatus in 
  let rec lcp ctx j i = function
    | (n1, NCic.Decl t1 as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
        if n1 = n2 && 
           NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
          NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
        else
          HExtlib.mk_list (NCic.Appl 
            [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
    | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Def (b2,t2))::cl2 ->
        if n1 = n2 && 
           NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
           NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
          NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
        else
          HExtlib.mk_list (NCic.Appl 
            [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
    | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
        if n1 = n2 && 
           NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
          NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
        else
          HExtlib.mk_list (NCic.Appl 
            [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
    | (n1, NCic.Decl _)::cl1, (n2, NCic.Def _)::cl2 -> assert false
    | _::_, [] -> 
          HExtlib.mk_list (NCic.Appl 
            [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
    | _ -> []
  in
  let lc = 
    lcp [] (List.length destination) (List.length source) 
      (List.rev destination, List.rev source)
  in
  let lc = (0,NCic.Ctx (List.rev lc)) in
  let db = NCicUnifHint.db () in (* XXX fixme *)
  let (metasenv, subst), t =
    NCicMetaSubst.delift 
       ~unify:(fun m s c t1 t2 -> 
         try Some (NCicUnification.unify db m s c t1 t2)
         with 
          | NCicUnification.UnificationFailure _ 
          | NCicUnification.Uncertain _ -> None) 
     metasenv subst source 0 lc t
  in
  let status = { status with pstatus = u, d, metasenv, subst, o } in
  status, (name, destination, t)
;;

let term_of_cic_term s t c = 
  let s, (_,_,t) = relocate s c t in
  s, t
;;

let disambiguate status t ty context =
 let status, expty = 
   match ty with 
   | None -> status, None 
   | Some ty -> 
       let status, (_,_,x) = relocate status context ty in status, Some x 
 in
 let uri,height,metasenv,subst,obj = status.pstatus in
 let metasenv, subst, lexicon_status, t = 
   GrafiteDisambiguate.disambiguate_nterm expty
    status.lstatus context metasenv subst t 
 in
 let new_pstatus = uri,height,metasenv,subst,obj in
 { lstatus = lexicon_status; pstatus = new_pstatus }, (None, context, t) 
;;

let typeof status ctx t =
  let status, (_,_,t) = relocate status ctx t in
  let _,_,metasenv,subst,_ = status.pstatus in
  let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
  status, (None, ctx, ty)
;;
  
let whd status ?delta ctx t =
  let status, (name,_,t) = relocate status ctx t in
  let _,_,_,subst,_ = status.pstatus in
  let t = NCicReduction.whd ~subst ?delta ctx t in
  status, (name, ctx, t)
;;
  
let unify status ctx a b =
  let status, (_,_,a) = relocate status ctx a in
  let status, (_,_,b) = relocate status ctx b in
  let n,h,metasenv,subst,o = status.pstatus in
  let metasenv, subst = 
    NCicUnification.unify (NCicUnifHint.db ()) metasenv subst ctx a b
  in
  { status with pstatus = n,h,metasenv,subst,o }
;;

let refine status ctx term expty =
  let status, (nt,_,term) = relocate status ctx term in
  let status, ne, expty = 
    match expty with None -> status, None, None 
    | Some e -> 
        let status, (n,_, e) = relocate status ctx e in status, n, Some e
  in
  let name,height,metasenv,subst,obj = status.pstatus in
  let db = NCicUnifHint.db () in (* XXX fixme *)
  let coercion_db = NCicCoercion.db () in
  let look_for_coercion = NCicCoercion.look_for_coercion coercion_db in
  let metasenv, subst, t, ty = 
   NCicRefiner.typeof db ~look_for_coercion metasenv subst ctx term expty
  in
  { status with pstatus = name,height,metasenv,subst,obj }, 
  (nt,ctx,t), (ne,ctx,ty)
;;

let get_goalty (status : lowtac_status) (g : int) =
 let _,_,metasenv,_,_ = status.pstatus in
 List.assoc g metasenv
;;

let instantiate status i t =
 let (gname, context, _ as gty) = get_goalty status i in
 let status, (_,_,t), (_,_,ty) = 
   refine status (ctx_of gty) t (Some gty) 
 in

 let name,height,metasenv,subst,obj = status.pstatus in
 let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 let subst = (i, (gname, context, t, ty)) :: subst in
 { status with pstatus = (name,height,metasenv,subst,obj) }
;;

let mk_meta status ?name ctx bo_or_ty =
  match bo_or_ty with
  | `Decl ty ->
      let status, (_,_,ty) = relocate status ctx ty in
      let n,h,metasenv,subst,o = status.pstatus in
      let metasenv, _, instance, _ = 
        NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty)
      in
      let status = { status with pstatus = n,h,metasenv,subst,o } in
      status, (None,ctx,instance)
  | `Def bo ->
      let status, (_,_,bo_ as bo) = relocate status ctx bo in
      let status, (_,_,ty) = typeof status ctx bo in
      let n,h,metasenv,subst,o = status.pstatus in
      let metasenv, metano, instance, _ = 
        NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty) in
      let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
      let subst = (metano, (name, ctx, bo_, ty)) :: subst in
      let status = { status with pstatus = n,h,metasenv,subst,o } in
      status, (None,ctx,instance)
;;

let mk_in_scope status t = 
  mk_meta status ~name:NCicMetaSubst.in_scope_tag (ctx_of t) (`Def t)
;;

let mk_out_scope n status t = 
  mk_meta status ~name:(NCicMetaSubst.out_scope_tag n) (ctx_of t) (`Def t)
;;

(* the following unification problem will be driven by 
 *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 *
 *   ? args = t
 *
 *   where argsn = length args and the pattern matches t
 *
 *  found is called on every selected term to map them
 *  postprocess is called on the entire term after selection
 *)
let select_term 
  low_status ~found ~postprocess (name,context,term) (wanted,path) 
=
  let is_found status ctx t wanted =
    (* we could lift wanted step-by-step *)
    try true, unify status ctx (None, ctx, t) wanted
    with 
    | NCicUnification.UnificationFailure _ 
    | NCicUnification.Uncertain _ -> false, status
  in
  let match_term status ctx (wanted : cic_term) t =
    let rec aux ctx status t =
      let b, status = is_found status ctx t wanted in
      if b then
         let status , (_,_,t) = found status (None, ctx, t) in 
         status, t
      else
        let _,_,_,subst,_ = status.pstatus in
        match t with
        | NCic.Meta (i,lc) when List.mem_assoc i subst ->
            let _,_,t,_ = NCicUtils.lookup_subst i subst in
            aux ctx status t
        | NCic.Meta _ -> status, t
        | _ ->      
            NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux status t
     in 
       aux ctx status t
  in 
  let _,_,_,subst,_ = low_status.pstatus in
  let rec select status ctx pat cic = 
    match pat, cic with
    | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
        let cic = 
          let _,_,t,_ = NCicUtils.lookup_subst i subst in
          NCicSubstitution.subst_meta lc t
        in
        select status ctx pat cic
    | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
        let status, t = select status ctx t1 t2 in
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Def (s2,t2)) :: ctx in
        let status, b = select status ctx b1 b2 in
        status, NCic.LetIn (n,t,s,b)
    | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Decl s2) :: ctx in
        let status, t = select status ctx t1 t2 in
        status, NCic.Lambda (n,s,t)
    | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
        let status, s = select status ctx s1 s2 in
        let ctx = (n, NCic.Decl s2) :: ctx in
        let status, t = select status ctx t1 t2 in
        status, NCic.Prod (n,s,t)
    | NCic.Appl l1, NCic.Appl l2 ->
        let status, l = 
           List.fold_left2
             (fun (status,l) x y -> 
              let status, x = select status ctx x y in
              status, x::l)
             (status,[]) l1 l2
        in
        status, NCic.Appl (List.rev l)
    | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
        let status, t = select status ctx t1 t2 in
        let status, ot = select status ctx ot1 ot2 in
        let status, pl = 
           List.fold_left2
             (fun (status,l) x y -> 
              let status, x = select status ctx x y in
              status, x::l)
             (status,[]) pl1 pl2
        in
        status, NCic.Match (u,ot,t,List.rev pl)
    | NCic.Implicit `Hole, t -> 
        (match wanted with
        | Some wanted -> 
             let status, wanted = disambiguate status wanted None ctx in
             match_term status ctx wanted t
        | None -> match_term status ctx (None,ctx,t) t)
    | NCic.Implicit _, t -> status, t
    | _,t -> 
        fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
          ~context:[] ~subst:[] pat ^ " against " ^ 
          NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
  in
  let status, term = select low_status context path term in
  let term = (name, context, term) in
  postprocess status term
;;

let analyse_indty status ty = 
 let status, reduct = whd status (ctx_of ty) ty in
 let ref, args =
  match reduct with
   | _,_,NCic.Const ref -> ref, []
   | _,_,NCic.Appl (NCic.Const ref :: args) -> ref, args
   | _,_,_ -> fail (lazy ("not an inductive type")) in
 let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 let _,_,_,cl = List.nth tl i in
 let consno = List.length cl in
 let left, right = HExtlib.split_nth lno args in
 status, (ref, consno, left, right)
;;

let mk_cic_term c t = None,c,t ;;

let apply_subst status ctx t =
 let status, (name,_,t) = relocate status ctx t in
 let _,_,_,subst,_ = status.pstatus in
 let rec aux ctx =
  function
     NCic.Meta (i,lc) ->
      (try
        let _,_,t,_ = NCicUtils.lookup_subst i subst in
        let t = NCicSubstitution.subst_meta lc t in
         aux ctx t
       with
        Not_found ->
         match lc with
            _,NCic.Irl _ -> NCic.Meta (i,lc)
          | n,NCic.Ctx l ->
             NCic.Meta
              (i,(0,NCic.Ctx
                  (List.map (fun t -> aux ctx (NCicSubstitution.lift n t)) l))))
   | t -> NCicUtils.map (fun item ctx -> item::ctx) ctx aux t
 in
  status, (name, ctx, aux ctx t)
;;