(* Copyright (C) 2002, HELM Team.
 *
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 *
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 *
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(* $Id$ *)

module C = Cic
module P = PrimitiveTactics
module T = Tacticals
module S = ProofEngineStructuralRules
module F = FreshNamesGenerator
module E = ProofEngineTypes
module H = ProofEngineHelpers
module R = ReductionTactics

(*
(* search in term the Inductive Types and return a list of uris as triples like this: (uri,typeno,exp_named_subst) *)
let search_inductive_types ty =
   let rec aux types = function 
      | C.MutInd (uri, typeno, _) when (not (List.mem (uri, typeno) types)) -> 
         (uri, typeno) :: types
      | C.Appl applist -> List.fold_left aux types applist
      | _              -> types
   in
   aux [] ty
(* N.B: in un caso tipo (and A forall C:Prop.(or B C)) l'or *non* viene selezionato! *)
*)

(* unexported tactics *******************************************************)

type type_class = Other
                | Ind
 	        | Con of C.lazy_term

let premise_pattern what = None, [what, C.Implicit (Some `Hole)], None 

let rec scan_tac ~old_context_length ~index ~tactic =
   let scan_tac status =
      let (proof, goal) = status in
      let _, metasenv, _, _, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let context_length = List.length context in
      let rec aux index =
         match H.get_name context index with 
	    | _ when index <= 0 -> (proof, [goal])
	    | None              -> aux (pred index)
	    | Some what         -> 
	       let tac = T.then_ ~start:(tactic ~what)
	                         ~continuation:(scan_tac ~old_context_length:context_length ~index ~tactic)
               in
	       try E.apply_tactic tac status 
	       with E.Fail _ -> aux (pred index)
      in aux (index + context_length - old_context_length)
   in
   E.mk_tactic scan_tac

let rec check_types types = function 
   | C.MutInd (uri, typeno, _) -> 
      if List.mem (uri, Some typeno) types then Ind else Other
   | C.Const (uri, _) as t     -> 
      if List.mem (uri, None) types then Con (E.const_lazy_term t) else Other
   | C.Appl (hd :: tl)         -> check_types types hd
   | _                         -> Other

let elim_clear_unfold_tac ~mk_fresh_name_callback ~types ~what =
   let elim_clear_unfold_tac status =
      let (proof, goal) = status in
      let _, metasenv, _, _, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let index, ty = H.lookup_type metasenv context what in
      match check_types types ty with 
         | Ind   ->
	    let tac = T.then_ ~start:(P.elim_intros_tac ~mk_fresh_name_callback (C.Rel index))
	                      ~continuation:(S.clear [what])
	    in
	    E.apply_tactic tac status
         | Con t ->
	    let tac = R.unfold_tac (Some t) ~pattern:(premise_pattern what) in
	    E.apply_tactic tac status
	 | Other -> 
	    raise (E.Fail (lazy "unexported elim_clear: not an eliminable type"))
   in
   E.mk_tactic elim_clear_unfold_tac

(* elim type ****************************************************************)

let elim_type_tac ?(mk_fresh_name_callback = F.mk_fresh_name ~subst:[]) ?depth
  ?using what
=
  let elim what =
    P.elim_intros_simpl_tac ?using ?depth ~mk_fresh_name_callback what
  in
  let elim_type_tac status =
    let tac =
      T.thens ~start: (P.cut_tac what) ~continuations:[elim (C.Rel 1); T.id_tac]
    in
    E.apply_tactic tac status
  in
  E.mk_tactic elim_type_tac

(* decompose ****************************************************************)

(* robaglia --------------------------------------------------------------- *)

  (** perform debugging output? *)
let debug = false
let debug_print = fun _ -> ()

  (** debugging print *)
let warn s = debug_print (lazy ("DECOMPOSE: " ^ (Lazy.force s)))

(* roba seria ------------------------------------------------------------- *)

let decompose_tac ?(mk_fresh_name_callback = F.mk_fresh_name ~subst:[])
                  ?(user_types=[]) ?what ~dbd =
   let decompose_tac status =
      let (proof, goal) = status in
      let _, metasenv,_,_, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let types = List.rev_append user_types (FwdQueries.decomposables dbd) in
      let tactic = elim_clear_unfold_tac ~mk_fresh_name_callback ~types in
      let old_context_length = List.length context in      
      let tac = match what with
	 | Some what -> 
	    T.then_ ~start:(tactic ~what)
                    ~continuation:(scan_tac ~old_context_length ~index:1 ~tactic)
	 | None      ->
            scan_tac ~old_context_length ~index:old_context_length ~tactic
      in
      E.apply_tactic tac status
   in
   E.mk_tactic decompose_tac