(* Copyright (C) 2002, HELM Team.
 *
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 *
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 *
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(* $Id$ *)

module C    = Cic
module P    = PrimitiveTactics
module T    = Tacticals
module S    = ProofEngineStructuralRules
module F    = FreshNamesGenerator
module PET  = ProofEngineTypes
module H    = ProofEngineHelpers
module RT   = ReductionTactics
module E    = CicEnvironment
module R    = CicReduction
module Un   = CicUniv

(* from ProceduralClasify ***************************************************)

let split c t =
   let add s v c = Some (s, C.Decl v) :: c in
   let rec aux whd a n c = function
      | C.Prod (s, v, t)  -> aux false (v :: a) (succ n) (add s v c) t
      | v when whd        -> v :: a, n
      | v                 -> aux true a n c (R.whd ~delta:true c v)
    in
    aux false [] 0 c t

(****************************************************************************)

type type_class = Other
                | Ind
 	        | Con of C.lazy_term

let premise_pattern what = None, [what, C.Implicit (Some `Hole)], None 

let get_inductive_type uri tyno =
   match E.get_obj Un.empty_ugraph uri with
      | C.InductiveDefinition (tys, _, lpsno, _), _ -> 
         let _, inductive, arity, _ = List.nth tys tyno in
         lpsno, inductive, arity
      | _                                           -> assert false

let rec check_type = function 
   | C.MutInd (uri, tyno, _) -> 
      let lpsno, inductive, arity = get_inductive_type uri tyno in
      let _, psno = split [] arity in
      if lpsno <> psno && inductive then Other else Ind 
(*   | C.Const (uri, _) as t     -> 
      if List.mem (uri, None) types then Con (PET.const_lazy_term t) else Other
*)   | C.Appl (hd :: tl)         -> check_type hd
   | _                         -> Other

(* unexported tactics *******************************************************)

let rec scan_tac ~old_context_length ~index ~tactic =
   let scan_tac status =
      let (proof, goal) = status in
      let _, metasenv, _, _, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let context_length = List.length context in
      let rec aux index =
         match H.get_name context index with 
	    | _ when index <= 0 -> (proof, [goal])
	    | None              -> aux (pred index)
	    | Some what         -> 
	       let tac = T.then_ ~start:(tactic ~what)
	                         ~continuation:(scan_tac ~old_context_length:context_length ~index ~tactic)
               in
	       try PET.apply_tactic tac status 
	       with PET.Fail _ -> aux (pred index)
      in aux (index + context_length - old_context_length)
   in
   PET.mk_tactic scan_tac

let elim_clear_unfold_tac ~mk_fresh_name_callback ~what =
   let elim_clear_unfold_tac status =
      let (proof, goal) = status in
      let _, metasenv, _, _, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let index, ty = H.lookup_type metasenv context what in
      let tac = match check_type ty with 
         | Ind   -> T.then_ ~start:(P.elim_intros_tac ~mk_fresh_name_callback (C.Rel index))
	                    ~continuation:(S.clear [what])
         | Con t -> RT.unfold_tac (Some t) ~pattern:(premise_pattern what)
	 | Other -> 
	    let msg = "unexported elim_clear: not an decomposable type" in
	    raise (PET.Fail (lazy msg))
      in
      PET.apply_tactic tac status
   in
   PET.mk_tactic elim_clear_unfold_tac

(* elim type ****************************************************************)

let elim_type_tac ?(mk_fresh_name_callback = F.mk_fresh_name ~subst:[]) ?depth
  ?using what
=
  let elim what =
    P.elim_intros_simpl_tac ?using ?depth ~mk_fresh_name_callback what
  in
  let elim_type_tac status =
    let tac =
      T.thens ~start: (P.cut_tac what) ~continuations:[elim (C.Rel 1); T.id_tac]
    in
    PET.apply_tactic tac status
  in
  PET.mk_tactic elim_type_tac

(* decompose ****************************************************************)

(* robaglia --------------------------------------------------------------- *)

  (** perform debugging output? *)
let debug = false
let debug_print = fun _ -> ()

  (** debugging print *)
let warn s = debug_print (lazy ("DECOMPOSE: " ^ (Lazy.force s)))

(* roba seria ------------------------------------------------------------- *)

let decompose_tac ?(mk_fresh_name_callback = F.mk_fresh_name ~subst:[]) () =
   let decompose_tac status =
      let (proof, goal) = status in
      let _, metasenv,_,_, _ = proof in
      let _, context, _ = CicUtil.lookup_meta goal metasenv in
      let tactic = elim_clear_unfold_tac ~mk_fresh_name_callback in
      let old_context_length = List.length context in      
      let tac = scan_tac ~old_context_length ~index:old_context_length ~tactic
      in
      PET.apply_tactic tac status
   in
   PET.mk_tactic decompose_tac