(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module L = Log
module I = AutItem
module B = Bag
module O = BagOutput
module E = BagEnvironment
module S = BagSubstitution

exception LRefNotFound of B.message

type machine = {
   i: int;
   c: B.context;
   s: B.term list
}

type whd_result =
   | Sort_ of int
   | LRef_ of int * B.term option
   | GRef_ of B.obj
   | Bind_ of int * B.id * B.term * B.term

type ho_whd_result =
   | Sort of int
   | GRef of U.uri * B.term list
   | Abst of B.term

type ac_result = (int * NUri.uri * Bag.term list) list option

type extension = No | NSI

(* Internal functions *******************************************************)

let term_of_whdr = function
   | Sort_ h             -> B.Sort h
   | LRef_ (i, _)        -> B.LRef i
   | GRef_ (_, uri, _)   -> B.GRef uri
   | Bind_ (l, id, w, t) -> B.bind_abst l id w t

let level = 5

let error i = raise (LRefNotFound (L.items1 (string_of_int i)))

let log1 s c t =
   let sc, st = s ^ " in the context", "the term" in
   L.log O.specs level (L.ct_items1 sc c st t)

let log2 s c u t =
   let sc, su, st = s ^ " in the context", "the term", "and the term" in
   L.log O.specs level (L.ct_items2 sc c su u st t)

let empty_machine = {i = 0; c = B.empty_context; s = []}

let inc m = {m with i = succ m.i}

let unwind_to_term f m t =
   let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
   let f mc = C.list_fold_left f map t mc in
   B.contents f m.c

let unwind_stack f m =
   let map f v = unwind_to_term f m v in
   C.list_map f map m.s

let get f c m i =
   let f = function
      | Some (_, b) -> f b
      | None        -> error i
   in
   let f c = B.get f c i in
   B.append f c m.c

let push f c m l id w = 
   assert (m.s = []);
   let f w = B.push f c l id (B.Abst w) in
   unwind_to_term f m w

(* to share *)
let rec whd f c m x = match x with
   | B.Sort h                    -> f m (Sort_ h)
   | B.GRef uri                  ->
      let f obj = f m (GRef_ obj) in
      E.get_obj f uri
   | B.LRef i                    ->
      let f = function
         | B.Void   -> f m (LRef_ (i, None))
	 | B.Abst t -> f m (LRef_ (i, Some t))
	 | B.Abbr t -> whd f c m t
      in
      get f c m i
   | B.Cast (_, t)               -> whd f c m t
   | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t   
   | B.Bind (l, id, B.Abst w, t) -> 
      begin match m.s with
         | []      -> f m (Bind_ (l, id, w, t))
	 | v :: tl -> 
	    let f mc = whd f c {m with c = mc; s = tl} t in
	    B.push f m.c l id (B.Abbr (B.Cast (w, v)))
      end
   | B.Bind (l, id, b, t)         -> 
      let f mc = whd f c {m with c = mc} t in
      B.push f m.c l id b

let insert f i uri vs = function
   | Some l -> f (Some ((i, uri, vs) :: l))
   | None   -> assert false

(* Interface functions ******************************************************)

let ext = ref No

let rec ho_whd f c m x =
   let aux m = function
      | Sort_ h                  -> f (Sort h)
      | Bind_ (_, _, w, _)       -> 
         let f w = f (Abst w) in unwind_to_term f m w
      | LRef_ (_, Some w)        -> ho_whd f c m w
      | GRef_ (_, uri, B.Abst w) -> 
         let h = function 
	    | Abst _ as r -> f r 
	    | GRef _ as r -> f r
	    | Sort _      ->
	       let f vs = f (GRef (uri, vs)) in unwind_stack f m
	 in
	 if !ext = No then ho_whd h c m w else ho_whd f c m w 
      | GRef_ (_, _, B.Abbr v)   -> ho_whd f c m v
      | LRef_ (_, None)          -> assert false
      | GRef_ (_, _, B.Void)     -> assert false
   in
   whd aux c m x
   
let ho_whd f c t =
   let f r = L.unbox level; f r in
   L.box level; log1 "Now scanning" c t;
   ho_whd f c empty_machine t

let rec are_convertible f xl c m1 t1 m2 t2 =
   let rec aux m1 r1 m2 r2 =
   let u, t = term_of_whdr r1, term_of_whdr r2 in
   log2 "Now really converting" c u t;   
   match r1, r2 with
      | Sort_ h1, Sort_ h2                                 -> 
         if h1 = h2 then f xl else f None
      | LRef_ (i1, _), LRef_ (i2, _)                       ->
         if i1 = i2 then are_convertible_stacks f xl c m1 m2 else f None
      | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
         if a1 = a2 then are_convertible_stacks f xl c m1 m2 else f None
      | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
         if a1 = a2 then are_convertible_stacks f xl c m1 m2 else
	 if a1 < a2 then whd (aux m1 r1) c m2 v2 else
	 whd (aux_rev m2 r2) c m1 v1
      | _, GRef_ (_, _, B.Abbr v2)                         ->
         whd (aux m1 r1) c m2 v2
      | GRef_ (_, _, B.Abbr v1), _                         ->
	 whd (aux_rev m2 r2) c m1 v1      
      | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
         let f xl =
	    let h c =
 	       let m1, m2 = inc m1, inc m2 in
	       S.subst (are_convertible f xl c m1 t1 m2) l1 l2 t2
	    in
            if xl = None then f xl else push h c m1 l1 id1 w1
	 in
	 are_convertible f xl c m1 w1 m2 w2
(* we detect the AUT-QE reduction rule for type/prop inclusion *)      
      | GRef_ (_, uri, B.Abst _), Bind_ (l1, _, _, _) when !ext = No ->
         let g vs = insert f l1 uri vs xl in
	 if U.eq uri I.imp then unwind_stack g m1 else 
	 if U.eq uri I.all then unwind_stack g m1 else
	 begin L.warn (U.string_of_uri uri); f None end
      | Sort_ _, Bind_ (l2, id2, w2, t2)  when !ext = NSI  ->
 	 let m1, m2 = inc m1, inc m2 in
	 let f c = are_convertible f xl c m1 (term_of_whdr r1) m2 t2 in
	 push f c m2 l2 id2 w2
      | _                                                  -> f None
   and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
   let f m1 r1 = whd (aux m1 r1) c m2 t2 in 
   whd f c m1 t1

and are_convertible_stacks f xl c m1 m2 =
   let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
   let map f xl v1 v2 = are_convertible f xl c mm1 v1 mm2 v2 in
   if List.length m1.s <> List.length m2.s then f None else
   C.list_fold_left2 f map xl m1.s m2.s

let are_convertible f c u t = 
   let f b = L.unbox level; f b in
   L.box level; log2 "Now converting" c u t;
   are_convertible f (Some []) c empty_machine u empty_machine t