(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

type uri = NUri.uri
type id = Aut.id

type bind = Void         (* exclusion *)
          | Abst of term (* abstraction *)
          | Abbr of term (* abbreviation *)

and term = Sort of int              (* hierarchy index *)
         | LRef of int              (* reverse de Bruijn index *)
         | GRef of uri              (* reference *)
         | Cast of term * term      (* type, term *)
         | Appl of term * term      (* argument, function *)
         | Bind of id * bind * term (* name, binder, scope *)

type obj = int * uri * bind (* age, uri, binder, contents *)

type item = obj option

type context = int * (id * bind) list

type message = (context, term) Log.item list

(* Currified constructors ***************************************************)

let abst w = Abst w

let abbr v = Abbr v

let cast u t = Cast (u, t)

let appl u t = Appl (u, t)

let bind id b t = Bind (id, b, t)

let bind_abst id u t = Bind (id, Abst u, t)

let bind_abbr id v t = Bind (id, Abbr v, t)

(* context handling functions ***********************************************)

let empty_context = 0, []

let push f (l, es) id b =
   let c = succ l, (id, b) :: es in 
   f c

let append f (l1, es1) (l2, es2) =
   f (l2 + l1, List.append es2 es1)

let map f map (l, es) =
   let f es = f (l, es) in
   Cps.list_map f map es

let contents f (l, es) = f l es

let get f (l, es) i =
   if i < 0 || i >= l then f None else 
   let result = List.nth es (l - succ i) in
   f (Some result)