(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P = Printf
module F = Format
module U = NUri
module C = Cps
module L = Log
module H = Hierarchy
module B = Brg

(* nodes count **************************************************************)

type counters = {
   eabsts: int;
   eabbrs: int;
   tsorts: int;
   tlrefs: int;
   tgrefs: int;
   tcasts: int;
   tappls: int;
   tabsts: int;
   tabbrs: int
}

let initial_counters = {
   eabsts = 0; eabbrs = 0; tsorts = 0; tlrefs = 0; tgrefs = 0;
   tcasts = 0; tappls = 0; tabsts = 0; tabbrs = 0
}

let rec count_term_binder f c = function
   | B.Abst w ->
      let c = {c with tabsts = succ c.tabsts} in
      count_term f c w
   | B.Abbr v -> 
      let c = {c with tabbrs = succ c.tabbrs} in
      count_term f c v
   | B.Void   -> f c

and count_term f c = function
   | B.Sort _            -> 
      f {c with tsorts = succ c.tsorts}
   | B.LRef _         -> 
      f {c with tlrefs = succ c.tlrefs}
   | B.GRef _         -> 
      f {c with tgrefs = succ c.tgrefs}
   | B.Cast (_, v, t) -> 
      let c = {c with tcasts = succ c.tcasts} in
      let f c = count_term f c t in
      count_term f c v
   | B.Appl (_, v, t) -> 
      let c = {c with tappls = succ c.tappls} in
      let f c = count_term f c t in
      count_term f c v
   | B.Bind (_, b, t) -> 
      let f c = count_term_binder f c b in
      count_term f c t

let count_obj_binder f c = function
   | B.Abst w -> 
      let c = {c with eabsts = succ c.eabsts} in
      count_term f c w
   | B.Abbr v -> 
      let c = {c with eabbrs = succ c.eabbrs} in
      count_term f c v
   | B.Void   -> f c

let count_obj f c (_, _, b) =
   count_obj_binder f c b

let count_item f c = function
   | Some obj -> count_obj f c obj
   | None     -> f c

let print_counters f c =
   let terms =
      c.tsorts + c.tgrefs + c.tgrefs + c.tcasts + c.tappls + c.tabsts +
      c.tabbrs
   in
   let items = c.eabsts + c.eabbrs in
   L.warn (P.sprintf "  Kernel representation summary (basic_rg)");
   L.warn (P.sprintf "    Total entry items:        %7u" items);
   L.warn (P.sprintf "      Declaration items:      %7u" c.eabsts);
   L.warn (P.sprintf "      Definition items:       %7u" c.eabbrs);
   L.warn (P.sprintf "    Total term items:         %7u" terms);
   L.warn (P.sprintf "      Sort items:             %7u" c.tsorts);
   L.warn (P.sprintf "      Local reference items:  %7u" c.tlrefs);
   L.warn (P.sprintf "      Global reference items: %7u" c.tgrefs);
   L.warn (P.sprintf "      Explicit Cast items:    %7u" c.tcasts);
   L.warn (P.sprintf "      Application items:      %7u" c.tappls);
   L.warn (P.sprintf "      Abstraction items:      %7u" c.tabsts);
   L.warn (P.sprintf "      Abbreviation items:     %7u" c.tabbrs);   
   f ()

(* reductions count *********************************************************)

type reductions = {
   beta   : int;
   upsilon: int;
   tau    : int;
   ldelta : int;
   gdelta : int
}

let initial_reductions = {
   beta = 0; upsilon = 0; tau = 0; ldelta = 0; gdelta = 0
}

let add ?(beta=0) ?(upsilon=0) ?(tau=0) ?(ldelta=0) ?(gdelta=0) r = {
   beta = r.beta + beta;
   upsilon = r.upsilon + upsilon;
   tau = r.tau + tau;
   ldelta = r.ldelta + ldelta;
   gdelta = r.gdelta + gdelta
}

(* context/term pretty printing *********************************************)

let indexes = ref false

let id frm a =
   let f = function
      | None            -> assert false
      | Some (true, n)  -> F.fprintf frm "%s" n
      | Some (false, n) -> F.fprintf frm "^%s" n
   in      
   B.name f a

let rec pp_term c frm = function
   | B.Sort (_, h)           -> 
      let f = function 
         | Some s -> F.fprintf frm "@[%s@]" s
	 | None   -> F.fprintf frm "@[*%u@]" h
      in
      H.get_sort f h 
   | B.LRef (_, i)           -> 
      let f _ = function
         | Some (a, _) -> F.fprintf frm "@[%a@]" id a
         | None        -> F.fprintf frm "@[#%u@]" i
      in
      if !indexes then f 0 None else B.get f c i
   | B.GRef (_, s)           -> F.fprintf frm "@[$%s@]" (U.string_of_uri s)
   | B.Cast (_, u, t)        ->
      F.fprintf frm "@[{%a}.%a@]" (pp_term c) u (pp_term c) t
   | B.Appl (_, v, t)        ->
      F.fprintf frm "@[(%a).%a@]" (pp_term c) v (pp_term c) t
   | B.Bind (a, B.Abst w, t) ->
      let f cc =
         F.fprintf frm "@[[%a:%a].%a@]" id a (pp_term c) w (pp_term cc) t
      in
      B.push f c a (B.Abst w)
   | B.Bind (a, B.Abbr v, t) ->
      let f cc = 
         F.fprintf frm "@[[%a=%a].%a@]" id a (pp_term c) v (pp_term cc) t
      in
      B.push f c a (B.Abbr v)
   | B.Bind (a, B.Void, t)   ->
      let f cc = F.fprintf frm "@[[%a].%a@]" id a (pp_term cc) t in
      B.push f c a B.Void

let pp_context frm c =
   let pp_entry frm = function
      | a, B.Abst w -> 
         F.fprintf frm "@,@[%a : %a@]" id a (pp_term c) w
      | a, B.Abbr v -> 
         F.fprintf frm "@,@[%a = %a@]" id a (pp_term c) v
      | a, B.Void   -> 
         F.fprintf frm "@,%a" id a
   in
   let iter map frm l = List.iter (map frm) l in
   let f es = F.fprintf frm "%a" (iter pp_entry) (List.rev es) in
   B.contents f c

let specs = {
   L.pp_term = pp_term; L.pp_context = pp_context
}