(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module L = Log
module P = Output
module B = Brg
module O = BrgOutput
module E = BrgEnvironment
module S = BrgSubstitution

exception LRefNotFound of B.message

type machine = {
   c: B.context;
   s: (B.term * int) list
}

(* Internal functions *******************************************************)

let level = 5

let error i = raise (LRefNotFound (L.items1 (string_of_int i)))

let log1 s c t =
   let sc, st = s ^ " in the context", "the term" in
   L.log O.specs level (L.ct_items1 sc c st t)

let log2 s c u t =
   let sc, su, st = s ^ " in the context", "the term", "and the term" in
   L.log O.specs level (L.ct_items2 sc c su u st t)

let empty_machine = {
   c = B.empty_context; s = []
}

let get f c m i =
   let f e = function
      | Some (_, b) -> f e b
      | None        -> error i
   in
   let f c = B.get f c i in
   B.append f c m.c

let lift_stack f s =
   let map f (v, i) = f (v, succ i) in
   Cps.list_map f map s

let unwind_to_term f m t =
   let map f t (a, b) = f (B.Bind (a, b, t)) in
   let f mc = C.list_fold_left f map t mc in
   assert (m.s = []);
   B.contents f m.c

let push f m a b = 
   assert (m.s = []);
   f {m with c = (a, b) :: m.c}

(* to share *)
let rec step f ?(delta=false) ?(rt=false) c m x = 
(*   L.warn "entering R.step"; *)
   match x with
   | B.Sort _                -> f m x
   | B.GRef (a, uri)         ->
      let f = function
         | _, _, B.Abbr v when delta ->
            P.add ~gdelta:1 ();
	    step f ~delta ~rt c m v
         | _, _, B.Abst w when rt   ->
            P.add ~grt:1 ();
	    step f ~delta ~rt c m w	 
	 | e, _, b                   ->
	    f m (B.GRef (B.Entry (e, b) :: a, uri))
      in
      E.get_obj f uri
   | B.LRef (a, i)           ->
      let f e = function
	 | B.Abbr v          ->
	    P.add ~ldelta:1 ();
	    step f ~delta ~rt c m v
	 | B.Abst w when rt ->
            P.add ~lrt:1 ();
            step f ~delta ~rt c m w
	 | b                 ->
	    f m (B.LRef (B.Entry (e, b) :: a, i))
      in
      let f e = S.lift_bind (f e) (succ i) (0) in 
      get f c m i
   | B.Cast (_, _, t)        ->
      P.add ~tau:1 ();
      step f ~delta ~rt c m t
   | B.Appl (_, v, t)        ->
      step f ~delta ~rt c {m with s = (v, 0) :: m.s} t   
   | B.Bind (a, B.Abst w, t) -> 
      begin match m.s with
         | []           -> f m x
	 | (v, h) :: tl -> 
            P.add ~beta:1 ~upsilon:(List.length tl) ();
	    let f mc sc = step f ~delta ~rt c {c = mc; s = sc} t in
	    let f mc = lift_stack (f mc) tl in 
	    let f v = B.push f m.c a (B.Abbr v (* (B.Cast ([], w, v)) *) ) in
	    S.lift f h (0) v
      end
   | B.Bind (a, b, t)        -> 
      P.add ~upsilon:(List.length m.s) ();
      let f sc mc = step f ~delta ~rt c {c = mc; s = sc} t in
      let f sc = B.push (f sc) m.c a b in
      lift_stack f m.s

(* Interface functions ******************************************************)
   
let domain f c t =
   let f r = L.unbox level; f r in
   let f m = function
      | B.Bind (_, B.Abst w, _) ->
         let f w = f (Some w) in unwind_to_term f m w
      | x                       -> f None
   in
   L.box level; log1 "Now scanning" c t;
   step f ~delta:true ~rt:true c empty_machine t

let rec ac_nfs f ~si r c m1 u m2 t =
(*   L.warn "entering R.are_convertible_aux"; *)
   log2 "Now converting nfs" c u t;
   match u, t with
      | B.Sort (_, h1), B.Sort (_, h2)             ->
         if h1 = h2 then f r else f false 
      | B.LRef (B.Entry (e1, B.Abst _) :: _, i1), 
        B.LRef (B.Entry (e2, B.Abst _) :: _, i2)   ->
	 P.add ~zeta:(i1+i2-e1-e2) ();
	 if e1 = e2 then ac_stacks f ~si r c m1 m2 else f false
      | B.GRef (B.Entry (e1, B.Abst _) :: _, _), 
        B.GRef (B.Entry (e2, B.Abst _) :: _, _)    ->
	 if e1 = e2 then ac_stacks f ~si r c m1 m2 else f false
      | B.GRef (B.Entry (e1, B.Abbr v1) :: _, _), 
        B.GRef (B.Entry (e2, B.Abbr v2) :: _, _)   ->
         if e1 = e2 then
	    let f r = 
	       if r then f r 
	       else begin  
                  P.add ~gdelta:2 ();
	          ac f ~si true c m1 v1 m2 v2
	       end
	    in
	    ac_stacks f ~si r c m1 m2
	 else if e1 < e2 then begin 
            P.add ~gdelta:1 ();
	    step (ac_nfs f ~si r c m1 u) c m2 v2
	 end else begin
	    P.add ~gdelta:1 ();
	    step (ac_nfs_rev f ~si r c m2 t) c m1 v1
         end
      | _, B.GRef (B.Entry (_, B.Abbr v2) :: _, _) ->
         P.add ~gdelta:1 ();
         step (ac_nfs f ~si r c m1 u) c m2 v2      
      | B.GRef (B.Entry (_, B.Abbr v1) :: _, _), _ ->
         P.add ~gdelta:1 ();
	 step (ac_nfs_rev f ~si r c m2 t) c m1 v1            
      | B.Bind (a1, (B.Abst w1 as b1), t1), 
        B.Bind (a2, (B.Abst w2 as b2), t2)         ->
	 let g m1 m2 = ac f ~si r c m1 t1 m2 t2 in
         let g m1 = push (g m1) m2 a2 b2 in 
	 let f r = if r then push g m1 a1 b1 else f false in
	 ac f ~si r c m1 w1 m2 w2      
      | B.Sort _, B.Bind (a, b, t) when si         ->
	 P.add ~si:1 ();
	 let f m1 m2 = ac f ~si r c m1 u m2 t in
	 let f m1 = push (f m1) m2 a b in
	 push f m1 a b
      | _                                          -> f false

and ac_nfs_rev f ~si r c m2 t m1 u = ac_nfs f ~si r c m1 u m2 t

and ac f ~si r c m1 t1 m2 t2 =
(*   L.warn "entering R.are_convertible"; *)
   let g m1 t1 = step (ac_nfs f ~si r c m1 t1) c m2 t2 in 
   if r = false then f false else step g c m1 t1

and ac_stacks f ~si r c m1 m2 =
(*   L.warn "entering R.are_convertible_stacks"; *)
   let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
   let map f r (v1, h1) (v2, h2) =
      let f v1 = S.lift (ac f ~si r c mm1 v1 mm2) h2 (0) v2 in
      S.lift f h1 (0) v1
   in
   if List.length m1.s <> List.length m2.s then 
      begin 
(*         L.warn (Printf.sprintf "Different lengths: %u %u"
	    (List.length m1.s) (List.length m2.s) 
	 ); *)
	 f false
      end
   else
      C.list_fold_left2 f map r m1.s m2.s

let are_convertible f ?(si=false) c u t = 
   let f b = L.unbox level; f b in
   L.box level; log2 "Now converting" c u t;
   ac f ~si true c empty_machine u empty_machine t