(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module S = Share
module L = Log
module Y = Entity
module P = Output
module B = Brg
module O = BrgOutput
module E = BrgEnvironment

type kam = {
   c: B.lenv;
   s: (B.lenv * B.term) list;
   i: int
}

(* Internal functions *******************************************************)

let level = 5

let log1 s c t =
   let sc, st = s ^ " in the environment", "the term" in
   L.log O.specs level (L.et_items1 sc c st t)

let log2 s cu u ct t =
   let s1, s2, s3 = s ^ " in the environment", "the term", "and in the environment" in
   L.log O.specs level (L.et_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)

let are_alpha_convertible err f t1 t2 =
   let rec aux f = function
      | B.Sort (_, p1), B.Sort (_, p2)
      | B.LRef (_, p1), B.LRef (_, p2)         ->
         if p1 = p2 then f () else err ()
      | B.GRef (_, u1), B.GRef (_, u2)         ->
         if U.eq u1 u2 then f () else err ()
      | B.Cast (_, v1, t1), B.Cast (_, v2, t2)         
      | B.Appl (_, v1, t1), B.Appl (_, v2, t2) ->
         let f _ = aux f (t1, t2) in
	 aux f (v1, v2)
      | B.Bind (b1, t1), B.Bind (b2, t2)       ->
         let f _ = aux f (t1, t2) in
	 aux_bind f (b1, b2)
      | _                                      -> err ()
   and aux_bind f = function
      | B.Abbr (_, v1), B.Abbr (_, v2)
      | B.Abst (_, v1), B.Abst (_, v2)         -> aux f (v1, v2)
      | B.Void _, B.Void _                     -> f ()
      | _                                      -> err ()
   in
   if S.eq t1 t2 then f () else aux f (t1, t2)

let get err f m i =
   B.get err f m.c i

(* to share *)
let rec step f ?(delta=false) ?(rt=false) m x = 
(*   L.warn "entering R.step"; *)
   match x with
   | B.Sort _                  -> f m None x
   | B.GRef (_, uri)           ->
      let f = function
         | _, _, Y.Abbr v when delta ->
	    P.add ~gdelta:1 (); step f ~delta ~rt m v
         | _, _, Y.Abst w when rt    ->
            P.add ~grt:1 (); step f ~delta ~rt m w	 
	 | a, _, Y.Abbr v            ->
	    let f e = f m (Some (e, B.Abbr (a, v))) x in
	    Y.apix C.err f a	    
	 | a, _, Y.Abst w            ->
	    let f e = f m (Some (e, B.Abst (a, w))) x in
	    Y.apix C.err f a	    
      in
      E.get_entity C.err f uri
   | B.LRef (_, i)             ->
      let f c = function
	 | B.Abbr (_, v)         ->
	    P.add ~ldelta:1 ();
	    step f ~delta ~rt {m with c = c} v
	 | B.Abst (_, w) when rt ->
            P.add ~lrt:1 ();
            step f ~delta ~rt {m with c = c} w
	 | B.Void _              ->
	    assert false
	 | B.Abst (a, _) as b    ->
	    let f e = f {m with c = c} (Some (e, b)) x in 
	    Y.apix C.err f a
      in 
      get C.err f m i
   | B.Cast (_, _, t)          ->
      P.add ~tau:1 ();
      step f ~delta ~rt m t
   | B.Appl (_, v, t)          ->
      step f ~delta ~rt {m with s = (m.c, v) :: m.s} t   
   | B.Bind (B.Abst (a, w), t) ->
      begin match m.s with
         | []          -> f m None x
	 | (c, v) :: s ->
            P.add ~beta:1 ~upsilon:(List.length s) ();
	    let f c = step f ~delta ~rt {m with c = c; s = s} t in 
	    B.push f m.c ~c (B.abbr a v) (* (B.Cast ([], w, v)) *)
      end
   | B.Bind (b, t)             ->
      P.add ~upsilon:(List.length m.s) ();
      let f c = step f ~delta ~rt {m with c = c} t in
      B.push f m.c ~c:m.c b

let push f m b = 
   assert (m.s = []);
   let b, i = match b with
      | B.Abst (a, w) -> B.abst (Y.Apix m.i :: a) w, succ m.i
      | b             -> b, m.i
   in
   let f c = f {m with c = c; i = i} in
   B.push f m.c ~c:m.c b

let rec ac_nfs err f ~si m1 a1 u m2 a2 t =
   log2 "Now converting nfs" m1.c u m2.c t;
   match a1, u, a2, t with
      | _, B.Sort (_, h1), _, B.Sort (_, h2)                       ->
         if h1 = h2 then f () else err () 
      | Some (e1, B.Abst _), _, Some (e2, B.Abst _), _             ->
	 if e1 = e2 then ac_stacks err f m1 m2 else err ()
      | Some (e1, B.Abbr (_, v1)), _, Some (e2, B.Abbr (_, v2)), _ ->
         if e1 = e2 then
	    let err _ = P.add ~gdelta:2 (); ac err f ~si m1 v1 m2 v2 in
	    ac_stacks err f m1 m2
	 else if e1 < e2 then begin 
            P.add ~gdelta:1 ();
	    step (ac_nfs err f ~si m1 a1 u) m2 v2
	 end else begin
	    P.add ~gdelta:1 ();
	    step (ac_nfs_rev err f ~si m2 a2 t) m1 v1
         end
      | _, _, Some (_, B.Abbr (_, v2)), _                          ->
         P.add ~gdelta:1 ();
         step (ac_nfs err f ~si m1 a1 u) m2 v2      
      | Some (_, B.Abbr (_, v1)), _, _, _                          ->
         P.add ~gdelta:1 ();
	 step (ac_nfs_rev err f ~si m2 a2 t) m1 v1            
      | _, B.Bind ((B.Abst (_, w1) as b1), t1), 
        _, B.Bind ((B.Abst (_, w2) as b2), t2)                     ->
	 let f m1 m2 = ac err f ~si m1 t1 m2 t2 in
         let f m1 = push (f m1) m2 b2 in 
	 let f _ = push f m1 b1 in
	 ac err f ~si:false m1 w1 m2 w2      
      | _, B.Sort _, _, B.Bind (b, t) when si                      ->
	 P.add ~si:1 ();
	 let f m1 m2 = ac err f ~si m1 u m2 t in
	 let f m1 = push (f m1) m2 b in
	 push f m1 b
      | _                                                          -> err ()

and ac_nfs_rev err f ~si m2 a2 t m1 a1 u = ac_nfs err f ~si m1 a1 u m2 a2 t

and ac err f ~si m1 t1 m2 t2 =
(*   L.warn "entering R.are_convertible"; *)
   let f m1 a1 t1 = step (ac_nfs err f ~si m1 a1 t1) m2 t2 in 
   step f m1 t1

and ac_stacks err f m1 m2 =
(*   L.warn "entering R.are_convertible_stacks"; *)
   if List.length m1.s <> List.length m2.s then err () else
   let map f (c1, v1) (c2, v2) =
      let m1, m2 = {m1 with c = c1; s = []}, {m2 with c = c2; s = []} in
      ac err f ~si:false m1 v1 m2 v2
   in
   C.list_iter2 f map m1.s m2.s

(* Interface functions ******************************************************)

let empty_kam = { 
   c = B.empty_lenv; s = []; i = 0
}

let get err f m i =
   assert (m.s = []);
   let f c = f in
   get err f m i

let xwhd f m t =
   L.box level; log1 "Now scanning" m.c t;
   let f m _ t = L.unbox level; f m t in
   step f ~delta:true ~rt:true m t

let are_convertible err f ?(si=false) mu u mw w = 
      L.box level; log2 "Now converting" mu.c u mw.c w;
      let f x = L.unbox level; f x in
      let err _ = ac err f ~si mu u mw w in
(*      if S.eq mu mw then are_alpha_convertible err f u w else *) err ()

(* error reporting **********************************************************)

let pp_term m frm t = O.specs.L.pp_term m.c frm t

let pp_lenv frm m = O.specs.L.pp_lenv frm m.c

let specs = {
   L.pp_term = pp_term; L.pp_lenv = pp_lenv
}