(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module S = Share
module L = Log
module H = Hierarchy
module B = Brg
module O = BrgOutput
module E = BrgEnvironment
module R = BrgReduction

exception TypeError of B.message

(* Internal functions *******************************************************)

let level = 4

let log1 s c t =
   let sc, st = s ^ " in the context", "the term" in
   L.log O.specs level (L.ct_items1 sc c st t)

let error1 st c t =
   let sc = "In the context" in
   raise (TypeError (L.ct_items1 sc c st t))

let error3 c t1 t2 t3 =
   let sc, st1, st2, st3 = 
      "In the context", "the term", "is of type", "but must be of type"
   in
   raise (TypeError (L.ct_items3 sc c st1 t1 st2 t2 st3 t3))

(* Interface functions ******************************************************)

let si = ref false

let rec b_type_of f g c x = 
(*   L.warn "Entering T.b_type_of"; *)
   log1 "Now checking" c x;
   match x with
   | B.Sort (a, h)           ->
      let f h = f x (B.Sort (a, h)) in H.apply f g h
   | B.LRef (_, i)           ->
      let f _ = function
         | Some (_, B.Abst w)                  -> f x w
	 | Some (_, B.Abbr (B.Cast (_, w, _))) -> f x w
	 | Some (_, B.Abbr _)                  -> assert false
	 | Some (_, B.Void)                    -> 
	    error1 "reference to excluded variable" c x
         | None                             ->
	    error1 "variable not found" c x	 
      in
      B.get f c i
   | B.GRef (_, uri)         ->
      let f = function
         | _, _, B.Abst w                  -> f x w
	 | _, _, B.Abbr (B.Cast (_, w, _)) -> f x w
	 | _, _, B.Abbr _                  -> assert false
	 | _, _, B.Void                    ->
	    error1 "reference to excluded object" c x
      in
      E.get_obj f uri   
   | B.Bind (a, B.Abbr v, t) ->
      let f xv xt tt =
         f (S.sh2 v xv t xt x (B.bind_abbr a)) (B.bind_abbr a xv tt)
      in
      let f xv cc = b_type_of (f xv) g cc t in
      let f xv = B.push (f xv) c a (B.Abbr xv) in
      let f xv vv = match xv with 
	 | B.Cast _ -> f xv
         | _        -> f (B.Cast ([], vv, xv))
      in
      type_of f g c v
   | B.Bind (a, B.Abst u, t) ->
      let f xu xt tt =
	 f (S.sh2 u xu t xt x (B.bind_abst a)) (B.bind_abst a xu tt)
      in
      let f xu cc = b_type_of (f xu) g cc t in
      let f xu _ = B.push (f xu) c a (B.Abst xu) in
      type_of f g c u
   | B.Bind (a, B.Void, t)   ->
      let f xt tt = 
         f (S.sh1 t xt x (B.bind a B.Void)) (B.bind a B.Void tt)
      in
      let f cc = b_type_of f g cc t in
      B.push f c a B.Void   
   | B.Appl (a, v, t)        ->
      let f xv vv xt tt = function
	 | Some w -> 
            L.box (succ level);
	    L.log O.specs (succ level) (L.t_items1 "Just scanned" c w);
	    L.unbox (succ level);
	    let f r =
(*	       L.warn (Printf.sprintf "Convertible: %b" a); *)
	       if r then f (S.sh2 v xv t xt x (B.appl a)) (B.appl a xv tt)
	       else error3 c xv vv w
	    in
	    R.are_convertible f ~si:!si c w vv
	 | None   -> 
	    error1 "not a function" c xt
      in
      let f xv vv xt tt = R.domain (f xv vv xt tt) c tt in
      let f xv vv = b_type_of (f xv vv) g c t in
      type_of f g c v
   | B.Cast (a, u, t)        ->
      let f xu xt tt r =  
         (* L.warn (Printf.sprintf "Convertible: %b" a); *)
	 if r then f (S.sh2 u xu t xt x (B.cast a)) xu else error3 c xt tt xu
      in
      let f xu xt tt = R.are_convertible ~si:!si (f xu xt tt) c xu tt in
      let f xu _ = b_type_of (f xu) g c t in
      type_of f g c u

and type_of f g c x =
   let f t u = L.unbox level; f t u in
   L.box level; b_type_of f g c x