(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module S = Share
module L = Log
module H = Hierarchy
module I = AutItem
module B = Brg
module O = BrgOutput
module E = BrgEnvironment
module R = BrgReduction

exception TypeError of B.message

(* Internal functions *******************************************************)

let level = 4

let error1 s c t =
   raise (TypeError (L.ct_items1 s c t))

let error2 s1 c1 t1 s2 c2 t2 =
   raise (TypeError (L.ct_items2 s1 c1 t1 s2 c2 t2))

let mk_gref u l =
   let map t v = B.Appl (v, t) in
   List.fold_left map (B.GRef u) l

(* Interface functions ******************************************************)

let rec b_type_of f g c x = 
   L.log O.specs level (L.ct_items1 "Now checking" c x);
   match x with
   | B.Sort h                 ->
      let f h = f x (B.Sort h) in H.apply f g h
   | B.LRef i                 ->
      let f = function
         | Some (_, B.Abst w)               -> f x w
	 | Some (_, B.Abbr (B.Cast (w, v))) -> f x w
	 | Some (_, B.Abbr _)               -> assert false
	 | Some (_, B.Void)                 -> 
	    error1 "reference to excluded variable" c x
         | None                             ->
	    error1 "variable not found" c x	 
      in
      B.get f c i
   | B.GRef uri               ->
      let f = function
         | _, _, B.Abst w               -> f x w
	 | _, _, B.Abbr (B.Cast (w, v)) -> f x w
	 | _, _, B.Abbr _               -> assert false
	 | _, _, B.Void                 ->
	    error1 "reference to excluded object" c x
      in
      E.get_obj f uri   
   | B.Bind (id, B.Abbr v, t) ->
      let f xv xt tt =
         f (S.sh2 v xv t xt x (B.bind_abbr id)) (B.bind_abbr id xv tt)
      in
      let f xv cc = b_type_of (f xv) g cc t in
      let f xv = B.push (f xv) c id (B.Abbr xv) in
      let f xv vv = match xv with 
	 | B.Cast _ -> f xv
         | _        -> f (B.Cast (vv, xv))
      in
      type_of f g c v
   | B.Bind (id, B.Abst u, t) ->
      let f xu xt tt =
	 f (S.sh2 u xu t xt x (B.bind_abst id)) (B.bind_abst id xu tt)
      in
      let f xu cc = b_type_of (f xu) g cc t in
      let f xu _ = B.push (f xu) c id (B.Abst xu) in
      type_of f g c u
   | B.Bind (id, B.Void, t)   ->
      let f xt tt = 
         f (S.sh1 t xt x (B.bind id B.Void)) (B.bind id B.Void tt)
      in
      let f cc = b_type_of f g cc t in
      B.push f c id B.Void   
   | B.Appl (v, t)            ->
      let h xv vv xt tt cc = function
         | R.Sort _ -> error1 "not a function" c xt
	 | R.Abst w -> 
            L.log O.specs (succ level) (L.ct_items1 "Just scanned" cc w);
	    let f b =
	       if b then f (S.sh2 v xv t xt x B.appl) (B.appl xv tt) else
	       error2 "the term" cc xv "must be of type" cc w
	    in
	    R.are_convertible f cc w vv	    
      in
      let f xv vv xt = function
(* inserting a missing "modus ponens" *)      
         | B.Appl (y2, B.Appl (y1, B.GRef u)) when U.eq u I.imp ->
            b_type_of f g c (mk_gref I.mp [y1; y2; xv; xt])
         | tt -> R.ho_whd (h xv vv xt tt) c tt
      in
      let f xv vv = b_type_of (f xv vv) g c t in
      type_of f g c v
   | B.Cast (u, t)            ->
      let f xu xt b = 
         if b then f (S.sh2 u xu t xt x B.cast) xu else
	 error2 "the term" c xt "must be of type" c xu
      in
      let f xu xt tt = R.are_convertible (f xu xt) c xu tt in
      let f xu _ = b_type_of (f xu) g c t in
      type_of f g c u

and type_of f g c x =
   let f t u = L.unbox (); f t u in
   L.box (); b_type_of f g c x