(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

type uri = NUri.uri
type id = Aut.id

type attr = Name of id * bool (* name, real? *)
          | Apix of int       (* additional position index *)
	  | Mark of int       (* node marker *)
	  | Priv              (* private global definition *)

type attrs = attr list (* attributes *)

type 'term bind = Abst of 'term (* declaration: domain *)
                | Abbr of 'term (* definition: body *)

type 'term entity = attrs * uri * 'term bind (* attrs, name, binder *)

type 'a uri_generator = (string -> 'a) -> string -> 'a 

(* helpers ******************************************************************)

let rec name err f = function
   | Name (n, r) :: _ -> f n r
   | _ :: tl          -> name err f tl
   | []               -> err ()

let rec apix err f = function
   | Apix i :: _ -> f i
   | _ :: tl     -> apix err f tl
   | []          -> err ()

let rec mark err f = function
   | Mark i :: _ -> f i
   | _ :: tl     -> mark err f tl
   | []          -> err ()

let rec priv err f = function
   | Priv :: _ -> f ()
   | _ :: tl   -> priv err f tl
   | []        -> err ()

let resolve err f name a =
   let rec aux i = function
      | Name (n, true) :: _ when n = name -> f i
      | _ :: tl                           -> aux (succ i) tl
      | []                                -> err i
   in
   aux 0 a

let xlate f xlate_term = function
   | a, uri, Abst t ->
      let f t = f (a, uri, Abst t) in xlate_term f t
   | a, uri, Abbr t ->
      let f t = f (a, uri, Abbr t) in xlate_term f t