(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

module H = Hashtbl

module M = Meta
module A = Aut

type environment = (M.qid, M.pars) H.t

type context_node = M.qid option (* context node: None = root *)

type status = {
   genv: M.environment;      (* global environment *)
   henv: environment;        (* optimized global environment *)
   path: M.id list;          (* current section path *) 
   hcnt: environment;        (* optimized context *)   
   node: context_node;       (* current context node *)
   nodes: context_node list; (* context node list *)
   line: int;                (* line number *)
   explicit: bool            (* need explicit context root? *)
}

type resolver = Local of int
              | Global of M.pars

let hsize = 11 (* hash tables initial size *)

let initial_status size = {
   genv = []; path = []; node = None; nodes = []; line = 1; explicit = true;
   henv = H.create size; hcnt = H.create size
}

let complete_qid f st (id, is_local, qs) =
   let f qs = f (id, qs) in
   let f path = Cps.list_rev_append f path ~tail:qs in
   let rec skip f = function
      | phd :: ptl, qshd :: _ when phd = qshd -> f ptl
      | _ :: ptl, _ :: _                      -> skip f (ptl, qs)
      | _                                     -> f []
   in
   if is_local then f st.path else skip f (st.path, qs)

let relax_qid f (id, path) =
   let f path = f (id, path) in
   let f = function
      | _ :: tl -> Cps.list_rev f tl
      | []      -> assert false
   in
   Cps.list_rev f path

let relax_opt_qid f = function
   | None     -> f None
   | Some qid -> let f qid = f (Some qid) in relax_qid f qid

let resolve_gref f st local lenv gref =
  let rec get_local f i = function
     | []                                      -> f None
     | (name, _) :: _ when fst name = fst gref -> f (Some i)
     | _ :: tl                                 -> get_local f (succ i) tl
  in
  let get_global f =
     try 
        let args = H.find st.henv gref in f (Some args)
     with Not_found -> f None
  in
  let g = function
      | Some args -> f gref (Some (Global args))
      | None      -> f gref None
  in
  let f = function
      | Some i -> f gref (Some (Local i))
      | None   -> get_global g
  in
  if local then get_local f 0 lenv else f None

let resolve_gref_relaxed f st lenv gref =
   let rec g gref = function
      | None          -> relax_qid (resolve_gref g st false lenv) gref
      | Some resolved -> f gref resolved
   in
   resolve_gref g st true lenv gref

let get_pars f st = function
   | None              -> f [] None
   | Some name as node ->
      try let pars = H.find st.hcnt name in f pars None
      with Not_found -> f [] (Some node)

let get_pars_relaxed f st =
   let rec g pars = function
      | None      -> f pars 
      | Some node -> relax_opt_qid (get_pars g st) node
   in
   get_pars g st st.node

let rec xlate_term f st lenv = function
   | A.Sort sort         -> f (M.Sort sort)
   | A.Appl (v, t)       ->
      let f vv tt = f (M.Appl (vv, tt)) in
      let f vv = xlate_term (f vv) st lenv t in
      xlate_term f st lenv v
   | A.Abst (name, w, t) ->
      let add name w lenv = 
         let f name = (name, w) :: lenv in
         complete_qid f st (name, true, []) 
      in
      let f ww tt = f (M.Abst (name, ww, tt)) in
      let f ww = xlate_term (f ww) st (add name ww lenv) t in
      xlate_term f st lenv w
   | A.GRef (name, args) ->
      let f name = function
	 | Local i     -> f (M.LRef i)
         | Global defs -> 
            let l = List.length lenv in
	    let map1 f = xlate_term f st lenv in
	    let map2 f (name, _) = f (M.GRef (l, name, [])) in
            let f tail =  	   
	       let f args = f (M.GRef (l, name, args)) in
               let f defs = Cps.list_rev_map_append f map2 defs ~tail in
	       Cps.list_sub_strict f defs args
	    in
	    Cps.list_map f map1 args
      in
      let f name = resolve_gref_relaxed f st lenv name in
      complete_qid f st name

let xlate_item f st = function
   | A.Section (Some name)     ->
      f {st with path = name :: st.path; nodes = st.node :: st.nodes}
   | A.Section None            ->
      begin match st.path, st.nodes with
	 | _ :: ptl, nhd :: ntl -> 
	    f {st with path = ptl; node = nhd; nodes = ntl}
         | _                    -> assert false
      end
   | A.Context None            ->
      f {st with node = None}
   | A.Context (Some name)     ->
      let f name = f {st with node = Some name} in
      complete_qid f st name
   | A.Block (name, w)         ->
      let f name = 
         let f pars =
	    let f ww = 
	       H.add st.hcnt name ((name, ww) :: pars);
	       f {st with node = Some name}
	    in
            xlate_term f st pars w
	 in
         get_pars_relaxed f st
      in
      complete_qid f st (name, true, [])
   | A.Decl (name, w)          ->
      let f pars = 
         let f name = 
            let f ww =
	       let entry = (st.line, pars, name, ww, None) in
	       H.add st.henv name pars;
	       f {st with genv = entry :: st.genv; line = succ st.line}
	    in
	    xlate_term f st pars w
	 in
         complete_qid f st (name, true, [])
      in
      get_pars_relaxed f st
   | A.Def (name, w, trans, v) ->
      let f pars = 
         let f name = 
            let f ww vv = 
	       let entry = (st.line, pars, name, ww, Some (trans, vv)) in
	       H.add st.henv name pars;
	       f {st with genv = entry :: st.genv; line = succ st.line}
	    in
	    let f ww = xlate_term (f ww) st pars v in
	    xlate_term f st pars w
	 in
         complete_qid f st (name, true, [])
      in
      get_pars_relaxed f st

let meta_of_aut f book =
   let f st = f st.genv in
   Cps.list_fold_left f xlate_item (initial_status hsize) book