(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P    = Printf
module U    = NUri
module C    = Cps
module L    = Log
module H    = Hierarchy
module AO   = AutOutput
module MA   = MetaAut
module MO   = MetaOutput
module MBag = MetaBag
module BagO = BagOutput
module BagR = BagReduction
module BagU = BagUntrusted

type status = {
   mst : MA.status;
   ac  : AO.counters;
   mc  : MO.counters;
   bagc: BagO.counters
}

let initial_status = {
   ac   = AO.initial_counters;
   mc   = MO.initial_counters;
   bagc = BagO.initial_counters;
   mst  = MA.initial_status
}

let count count_fun c item =
   if !L.level > 2 then count_fun C.start c item else c

let flush () = L.flush 0; L.flush_err ()

let bag_error s msg =
   L.error BagO.specs (L.Warn s :: L.Loc :: msg); flush () 

let main =
try 
   let version_string = "Helena Checker 0.8.0 M - December 2008" in
   let stage = ref 3 in
   let meta_file = ref None in
   let set_hierarchy s = 
      let f = function
         | Some g -> H.graph := g
	 | None   -> L.warn (P.sprintf "Unknown type hierarchy: %s" s)
      in
      H.graph_of_string f s
   in
   let set_summary i = L.level := i in
   let print_version () = L.warn version_string; exit 0 in
   let set_stage i = stage := i in
   let close = function
      | None          -> ()
      | Some (och, _) -> close_out och
   in
   let set_meta_file name =
      close !meta_file;
      let och = open_out name in
      let frm = Format.formatter_of_out_channel och in
      Format.pp_set_margin frm max_int;
      meta_file := Some (och, frm)
   in
   let read_file name =
      if !L.level > 0 then Time.gmtime version_string;      
      if !L.level > 1 then
         L.warn (P.sprintf "Processing file: %s" name);
      if !L.level > 0 then Time.utime_stamp "started";
      let ich = open_in name in
      let lexbuf = Lexing.from_channel ich in
      let book = AutParser.book AutLexer.token lexbuf in
      close_in ich;
      if !L.level > 0 then Time.utime_stamp "parsed";
      let rec aux st = function
         | []         -> st
	 | item :: tl ->
(* stage 3 *)
	    let f st _ = function
	       | None           -> st
	       | Some (i, u, _) -> 
(*	          Log.warn (P.sprintf "[%u] %s" i (U.string_of_uri u)); *)
		  st
	    in
(* stage 2 *)	    
	    let f st item =
	       let st = {st with bagc = count BagO.count_item st.bagc item} in
	       if !stage > 2 then BagU.type_check (f st) !H.graph item else st
	    in
(* stage 1 *)	    
	    let f st mst item = 
	       let st = {st with
	          mst = mst; mc = count MO.count_item st.mc item
	       } in
	       begin match !meta_file with
	          | None          -> ()
		  | Some (_, frm) -> MO.pp_item C.start frm item
	       end;
	       if !stage > 1 then MBag.bag_of_meta (f st) item else st 
	    in  
(* stage 0 *)	    
            let st = {st with ac = count AO.count_item st.ac item} in
	    let st =
	       if !stage > 0 then MA.meta_of_aut (f st) st.mst item else st
	    in
	    aux st tl
      in 
      let st = aux initial_status book in
      if !L.level > 0 then Time.utime_stamp "processed";
      if !L.level > 2 then AO.print_counters C.start st.ac;
      if !L.level > 2 && !stage > 0 then MO.print_counters C.start st.mc;
      if !L.level > 2 && !stage > 1 then BagO.print_counters C.start st.bagc;
   in
   let help = 
      "Usage: helena [ -Vin | -Ss <number> | -m <file> | -h <string> ] <file> ...\n\n" ^
      "Summary levels: 0 just errors, 1 time stamps, 2 processed file names, \
       3 data information, 4 typing information, 5 reduction information\n\n" ^
       "Stages: 0 parsing, 1 to intermediate, 2 to untrusted, 3 to trusted\n"
   in
   let help_S = "<number>  set summary level" in
   let help_V = " show version information" in   
   let help_h = "<string>  set type hierarchy" in
   let help_i = " show local references by index" in
   let help_m = "<file>  output intermediate representation" in
   let help_n = " activate naive sort inclusion" in
   let help_s = "<number>  Set translation stage" in
   L.box 0; L.box_err ();
   H.set_new_sorts ignore ["Set"; "Prop"];
   Arg.parse [
      ("-S", Arg.Int set_summary, help_S);
      ("-V", Arg.Unit print_version, help_V);
      ("-h", Arg.String set_hierarchy, help_h);
      ("-i", Arg.Set BagO.indexes, help_i);
      ("-m", Arg.String set_meta_file, help_m); 
      ("-n", Arg.Set BagR.nsi, help_n);
      ("-s", Arg.Int set_stage, help_s)
   ] read_file help;
   if !L.level > 0 then Time.utime_stamp "at exit";
   flush ()
with BagType.TypeError msg -> bag_error "Type Error" msg