(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P    = Printf
module U    = NUri
module C    = Cps
module L    = Log
module T    = Time
module H    = Hierarchy
module O    = Output
module AP   = AutProcess
module AO   = AutOutput
module MA   = MetaAut
module MO   = MetaOutput
module ML   = MetaLibrary
module MBrg = MetaBrg
module G    = Library
module BrgO = BrgOutput
module BrgT = BrgType
module BrgU = BrgUntrusted
module MBag = MetaBag
module BagO = BagOutput
module BagT = BagType
module BagU = BagUntrusted

type status = {
   ast : AP.status;
   mst : MA.status;
   ac  : AO.counters;
   mc  : MO.counters;
   brgc: BrgO.counters;
   bagc: BagO.counters
}

let initial_status cover = {
   ac   = AO.initial_counters;
   mc   = MO.initial_counters;
   brgc = BrgO.initial_counters;
   bagc = BagO.initial_counters;
   mst  = MA.initial_status ~cover ();
   ast  = AP.initial_status
}

let count count_fun c item =
   if !L.level > 2 then count_fun C.start c item else c

let flush () = L.flush 0; L.flush_err ()

let bag_error s msg =
   L.error BagO.specs (L.Warn s :: L.Loc :: msg); flush () 

let brg_error s msg =
   L.error BrgO.specs (L.Warn s :: L.Loc :: msg); flush () 

let process_item f st =
   let f ast = f {st with ast = ast} in
   AP.process_item f st.ast

(* kernel related ***********************************************************)

type kernel = Brg | Bag

type kernel_item = BrgItem of Brg.item
                 | BagItem of Bag.item

let kernel = ref Brg

let print_counters st = match !kernel with
   | Brg -> BrgO.print_counters C.start st.brgc
   | Bag -> BagO.print_counters C.start st.bagc

let kernel_of_meta f st item = match !kernel with
   | Brg -> 
      let f item = f st (BrgItem item) in
      MBrg.brg_of_meta f item
   | Bag -> 
      let f item = f st (BagItem item) in
      MBag.bag_of_meta f item  

let count_item st = function
   | BrgItem item -> {st with brgc = count BrgO.count_item st.brgc item}
   | BagItem item -> {st with bagc = count BagO.count_item st.bagc item}

let export_item si g = function
   | BrgItem item -> G.export_item BrgO.export_obj si g item
   | BagItem _    -> ()

let type_check f st si g k =
   let f _ = function
      | None           -> f st None
      | Some (i, u, _) -> f st (Some (i, u))
   in
   match k with
      | BrgItem item -> BrgU.type_check f ~si g item
      | BagItem item -> BagU.type_check f ~si g item

(****************************************************************************)

let main =
try 
   let version_string = "Helena 0.8.0 M - September 2009" in
   let stage = ref 3 in
   let moch = ref None in
   let meta = ref false in
   let progress = ref false in
   let process = ref false in
   let use_cover = ref true in
   let si = ref false in
   let export = ref false in
   let graph = ref (H.graph_of_string C.err C.start "Z2") in
   let set_hierarchy s = 
      let err () = L.warn (P.sprintf "Unknown type hierarchy: %s" s) in
      let f g = graph := g in
      H.graph_of_string err f s
   in
   let set_kernel = function
      | "brg" -> kernel := Brg
      | "bag" -> kernel := Bag
      | s     -> L.warn (P.sprintf "Unknown kernel version: %s" s)
   in
   let set_summary i = L.level := i in
   let print_version () = L.warn (version_string ^ "\n"); exit 0 in
   let set_stage i = stage := i in
   let set_meta_file name =
      let f och = moch := Some och in
      ML.open_out f name
   in
   let close = function
      | None     -> ()
      | Some och -> ML.close_out C.start och
   in
   let read_file name =
      if !L.level > 0 then T.gmtime version_string;      
      if !L.level > 1 then
         L.warn (P.sprintf "Processing file: %s" name);
      if !L.level > 0 then T.utime_stamp "started";
      let base_name = Filename.chop_extension (Filename.basename name) in
      if !meta then set_meta_file base_name;
      let ich = open_in name in
      let lexbuf = Lexing.from_channel ich in
      let book = AutParser.book AutLexer.token lexbuf in
      close_in ich;
      if !L.level > 0 then T.utime_stamp "parsed";
      let rec aux st = function
         | []         -> st
	 | item :: tl ->
(* stage 3 *)
	    let f st = function
	       | None        -> st
	       | Some (i, u) -> 
	          if !progress then 
		     L.warn (P.sprintf "[%u] %s" i (U.string_of_uri u)); 
		  st
	    in
(* stage 2 *)	    
	    let f st item =
	       let st = count_item st item in
	       if !export then export_item !si !graph item;
	       if !stage > 2 then type_check f st !si !graph item else st
	    in
(* stage 1 *)	    
	    let f st mst item = 
	       let st = {st with
	          mst = mst; mc = count MO.count_item st.mc item
	       } in
	       begin match !moch with
	          | None     -> ()
		  | Some och -> ML.write_item C.start och item
	       end;
	       if !stage > 1 then kernel_of_meta f st item else st 
	    in  
(* stage 0 *)	    
            let st = {st with ac = count AO.count_item st.ac item} in
	    let f st item =
	       let st = 
	          if !stage > 0 then MA.meta_of_aut (f st) st.mst item else st
	       in
	       aux st tl
	    in
	    if !process then process_item f st item else f st item
      in
      O.clear_reductions ();
      let cover = if !use_cover then base_name else "" in
      let st = aux (initial_status cover) book in
      if !L.level > 0 then T.utime_stamp "processed";
      if !L.level > 2 then AO.print_counters C.start st.ac;
      if !L.level > 2 && !process then AO.print_process_counters C.start st.ast;
      if !L.level > 2 && !stage > 0 then MO.print_counters C.start st.mc;
      if !L.level > 2 && !stage > 1 then print_counters st;
      if !L.level > 2 && !stage > 1 then O.print_reductions ()
   in
   let exit () =
      close !moch;
      if !L.level > 0 then T.utime_stamp "at exit";
      flush ()
   in
   let help = 
      "Usage: helena [ -Vcijmpux | -Ss <number> | -hk <string> ] <file> ...\n\n" ^
      "Summary levels: 0 just errors (default), 1 time stamps, 2 processed file names, \
       3 data information, 4 typing information, 5 reduction information\n\n" ^
       "Stages: 0 parsing, 1 to intermediate, 2 to untrusted, 3 to trusted (default)\n"
   in
   let help_S = "<number>  set summary level (see above)" in
   let help_V = " show version information" in   

   let help_c = " disable initial segment of URI hierarchy" in
   let help_h = "<string>  set type hierarchy (default: Z2)" in
   let help_i = " show local references by index" in
   let help_j = " show URI of processed kernel objects" in
   let help_k = "<string>  set kernel version (default: brg)" in
   let help_m = " output intermediate representation (HAL)" in
   let help_p = " preprocess Automath source" in
   let help_u = " activate sort inclusion" in
   let help_s = "<number>  set translation stage (see above)" in
   let help_x = " export kernel objects (XML)" in
   L.box 0; L.box_err ();
   H.set_new_sorts ignore ["Set"; "Prop"];
   at_exit exit;
   Arg.parse [
      ("-S", Arg.Int set_summary, help_S);
      ("-V", Arg.Unit print_version, help_V);
      ("-c", Arg.Clear use_cover, help_c);
      ("-h", Arg.String set_hierarchy, help_h);
      ("-i", Arg.Set O.indexes, help_i);
      ("-j", Arg.Set progress, help_j);      
      ("-k", Arg.String set_kernel, help_k);
      ("-m", Arg.Set meta, help_m); 
      ("-p", Arg.Set process, help_p);      
      ("-u", Arg.Set si, help_u);
      ("-s", Arg.Int set_stage, help_s);
      ("-x", Arg.Set export, help_x)
   ] read_file help;
with BagT.TypeError msg -> bag_error "Type Error" msg
   | BrgT.TypeError msg -> brg_error "Type Error" msg