(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module A = Share
module L = Log
module H = Hierarchy
module B = Brg
module O = BrgOutput
module E = BrgEnvironment
module S = BrgSubstitution
module R = BrgReduction

exception TypeError of B.message

(* Internal functions *******************************************************)

let level = 4

let log1 s m t =
   let s =  s ^ " the term" in
   L.log O.specs level (R.message1 s m t) 

let error1 s m t =
   raise (TypeError (R.message1 s m t))

let message3 m t1 t2 ?mu t3 =   
   let st1, st2 = "the term", "is of type" in
   match mu with
      | Some mu ->
         let smu, st3 = "but in the context", "it must be of type" in
	 R.message3 st1 st2 ~sm3:smu st3 m t1 t2 ~m3:mu t3
      | None    ->
         let st3 = "but it must be of type" in
         R.message3 st1 st2 st3 m t1 t2 t3
   
let error3 m t1 t2 ?mu t3 =
   raise (TypeError (message3 m t1 t2 ?mu t3))

let assert_convertibility f ~si m u w v =
   let err () = error3 m v w u in
   R.are_convertible err f ~si m u m w 

let assert_applicability f ~si m u w v =
   let f mu = function
      | B.Bind (B.Abst (_, u), _) -> 
         let err () = error3 m v w ~mu u in 
         R.are_convertible err f ~si mu u m w
      | _                         -> error1 "not a function type" m u
   in
   R.xwhd f m u 

let rec b_type_of f ~si g m x =
   log1 "Now checking" m x;
   match x with
   | B.Sort (a, h)             ->
      let f h = f x (B.Sort (a, h)) in H.apply f g h
   | B.LRef (_, i)             ->
      let f = function
         | B.Abst (_, w)                ->
	    S.lift (f x) (succ i) (0) w
	 | B.Abbr (_, B.Cast (_, w, _)) -> 
	    S.lift (f x) (succ i) (0) w
	 | B.Abbr _                     -> assert false
	 | B.Void _                     -> 
	    error1 "reference to excluded variable" m x
      in
      R.get f m i
   | B.GRef (_, uri)           ->
      let f = function
         | _, _, B.Abst (_, w)                -> f x w
	 | _, _, B.Abbr (_, B.Cast (_, w, _)) -> f x w
	 | _, _, B.Abbr _                     -> assert false
	 | _, _, B.Void _                     ->
	    error1 "reference to excluded object" m x
      in
      E.get_obj f uri   
   | B.Bind (B.Abbr (a, v), t) ->
      let f xv xt tt =
         f (A.sh2 v xv t xt x (B.bind_abbr a)) (B.bind_abbr a xv tt)
      in
      let f xv m = b_type_of (f xv) ~si g m t in
      let f xv = R.push (f xv) m (B.abbr a xv) in
      let f xv vv = match xv with 
	 | B.Cast _ -> f xv
         | _        -> f (B.Cast ([], vv, xv))
      in
      type_of f ~si g m v
   | B.Bind (B.Abst (a, u), t) ->
      let f xu xt tt =
	 f (A.sh2 u xu t xt x (B.bind_abst a)) (B.bind_abst a xu tt)
      in
      let f xu m = b_type_of (f xu) ~si g m t in
      let f xu _ = R.push (f xu) m (B.abst a xu) in
      type_of f ~si g m u
   | B.Bind (B.Void a as b, t) ->
      let f xt tt = 
         f (A.sh1 t xt x (B.bind b)) (B.bind b tt)
      in
      let f m = b_type_of f ~si g m t in
      R.push f m b   
   | B.Appl (a, v, t)          ->
      let f xv vv xt tt = 
         let f () = f (A.sh2 v xv t xt x (B.appl a)) (B.appl a xv tt) in
         assert_applicability f ~si m tt vv xv
      in
      let f xv vv = b_type_of (f xv vv) ~si g m t in
      type_of f ~si g m v
   | B.Cast (a, u, t)          ->
      let f xu xt tt =  
	 let f () = f (A.sh2 u xu t xt x (B.cast a)) xu in
         assert_convertibility f ~si m xu tt xt
      in
      let f xu _ = b_type_of (f xu) ~si g m t in
      type_of f ~si g m u

(* Interface functions ******************************************************)

and type_of f ?(si=false) g m x =
   let f t u = L.unbox level; f t u in
   L.box level; b_type_of f ~si g m x