(**************************************************************************)
(*       ___                                                              *)
(*      ||M||                                                             *)
(*      ||A||       A project by Andrea Asperti                           *)
(*      ||T||                                                             *)
(*      ||I||       Developers:                                           *)
(*      ||T||         The HELM team.                                      *)
(*      ||A||         http://helm.cs.unibo.it                             *)
(*      \   /                                                             *)
(*       \ /        This file is distributed under the terms of the       *)
(*        v         GNU General Public License Version 2                  *)
(*                                                                        *)
(**************************************************************************)

include "basic_2/substitution/cpys_lift.ma".
include "basic_2/substitution/cofrees.ma".

(* CONTEXT-SENSITIVE EXCLUSION FROM FREE VARIABLES **************************)

(* Advanced inversion lemmas ************************************************)

lemma cofrees_inv_lref_lt: ∀L,i,j. L ⊢ i ~ϵ 𝐅*⦃#j⦄ → j < i →
                           ∀I,K,W. ⇩[j]L ≡ K.ⓑ{I}W → K ⊢ i-j-1 ~ϵ 𝐅*⦃W⦄.
#L #i #j #Hj #Hji #I #K #W1 #HLK #W2 #HW12 elim (lift_total W2 0 (j+1))
#X2 #HWX2 elim (Hj X2) /2 width=7 by cpys_delta/ -I -L -K -W1
#Z2 #HZX2 elim (lift_div_le … HWX2 (i-j-1) 1 Z2) -HWX2 /2 width=2 by ex_intro/
>minus_plus <plus_minus_m_m //
qed-.

lemma cofrees_inv_lt: ∀L,U,i. L ⊢ i ~ϵ 𝐅*⦃U⦄ → ∀j. (∀T. ⇧[j, 1] T ≡ U → ⊥) →
                      ∀I,K,W. ⇩[j]L ≡ K.ⓑ{I}W → j < i → K ⊢ i-j-1 ~ϵ 𝐅*⦃W⦄.
#L #U @(f2_ind … rfw … L U) -L -U
#n #IH #L * *
[ -IH #k #_ #i #_ #j #H elim (H (⋆k)) -H //
| -IH #j #_ #i #Hi0 #j0 #H <(nlift_inv_lref_be_SO … H) -j0
  /2 width=7 by cofrees_inv_lref_lt/
| -IH #p #_ #i #_ #j #H elim (H (§p)) -H //
| #a #J #W #U #Hn #i #H1 #j #H2 #I #K #V #HLK #Hji destruct
  elim (cofrees_inv_bind … H1) -H1 #HW #HU
  elim (nlift_inv_bind … H2) -H2 [ -HU /3 width=7 by/ ]
  -HW #HnU lapply (IH … HU … HnU I K V ? ?)
  /2 width=1 by ldrop_drop, lt_minus_to_plus/ -a -I -J -L -W -U
  >minus_plus_plus_l //
| #J #W #U #Hn #i #H1 #j #H2 #I #K #V #HLK #Hji destruct
  elim (cofrees_inv_flat … H1) -H1 #HW #HU
  elim (nlift_inv_flat … H2) -H2 [ /3 width=7 by/ ]
  #HnU @(IH … HU … HnU … HLK) // (**) (* full auto fails *)
]
qed-.

(* Advanced properties ******************************************************)

lemma cofrees_lref_gt: ∀L,i,j. i < j → L ⊢ i ~ϵ 𝐅*⦃#j⦄.
#L #i #j #Hij #X #H elim (cpys_inv_lref1 … H) -H
[ #H destruct /3 width=2 by lift_lref_ge_minus, ex_intro/
| * #I #K #V1 #V2 #_ #_ #H -I -L -K -V1
  elim (lift_split … H i j) /2 width=2 by lt_to_le, ex_intro/
]
qed.

lemma cofrees_lref_lt: ∀I,L,K,W,i,j. j < i → ⇩[j] L ≡ K.ⓑ{I}W →
                       K ⊢ (i-j-1) ~ϵ 𝐅*⦃W⦄ → L ⊢ i ~ϵ 𝐅*⦃#j⦄.
#I #L #K #W1 #i #j #Hji #HLK #HW1 #X #H elim (cpys_inv_lref1 … H) -H
[ #H destruct /3 width=2 by lift_lref_lt, ex_intro/
| * #I0 #K0 #W0 #W2 #HLK0 #HW12 #HW2 lapply (ldrop_mono … HLK0 … HLK) -L
  #H destruct elim (HW1 … HW12) -I -K -W1
  #V2 #HVW2 elim (lift_trans_le … HVW2 … HW2) -W2 //
  >minus_plus <plus_minus_m_m /2 width=2 by ex_intro/
]
qed.

lemma cofrees_lref_free: ∀L,i,j. |L| ≤ j → j < i → L ⊢ i ~ϵ 𝐅*⦃#j⦄.
#L #i #j #Hj #Hji #X #H elim (cpys_inv_lref1 … H) -H
[ #H destruct /3 width=2 by lift_lref_lt, ex_intro/
| * #I #K #W1 #W2 #HLK lapply (ldrop_fwd_length_lt2 … HLK) -I
  #H elim (lt_refl_false j) -K -W1 -W2 -X -i /2 width=3 by lt_to_le_to_lt/
]
qed.

(* Advanced negated inversion lemmas ****************************************)

lemma frees_inv_lref_lt: ∀L,i,j. j < i → (L ⊢ i ~ϵ 𝐅*⦃#j⦄ → ⊥) →
                         ∃∃I,K,W. ⇩[j] L ≡ K.ⓑ{I}W & (K ⊢ (i-j-1) ~ϵ 𝐅*⦃W⦄ → ⊥).
#L #i #j #Hji #H elim (lt_or_ge j (|L|)) #Hj
[ elim (ldrop_O1_lt (Ⓕ) … Hj) -Hj /4 width=9 by cofrees_lref_lt, ex2_3_intro/
| elim H -H /2 width=5 by cofrees_lref_free/
]
qed-.

lemma frees_inv_lref_free: ∀L,i,j. (L ⊢ i ~ϵ 𝐅*⦃#j⦄  → ⊥) → |L| ≤ j → j = i.
#L #i #j #H #Hj elim (lt_or_eq_or_gt i j) //
#Hij elim H -H /2 width=5 by cofrees_lref_gt, cofrees_lref_free/
qed-.

lemma frees_inv_gen: ∀L,U,i. (L ⊢ i ~ϵ 𝐅*⦃U⦄ → ⊥) →
                     ∃∃U0.  ⦃⋆, L⦄ ⊢ U ▶* U0 & (∀T. ⇧[i, 1] T ≡ U0 → ⊥).
#L #U @(f2_ind … rfw … L U) -L -U
#n #IH #L * *
[ -IH #k #_ #i #H elim H -H //
| #j #Hn #i #H elim (lt_or_eq_or_gt i j)
  [ -n #Hij elim H -H /2 width=4 by cofrees_lref_gt/
  | -H -n #H destruct /3 width=7 by lift_inv_lref2_be, ex2_intro/
  | #Hji elim (frees_inv_lref_lt … H) // -H
    #I #K #W1 #HLK #H elim (IH … H) /2 width=3 by ldrop_fwd_rfw/ -H -n
    #W2 #HW12 #HnW2 elim (lift_total W2 0 (j+1))
    #U2 #HWU2 @(ex2_intro … U2) /2 width=7 by cpys_delta/ -I -L -K -W1
    #T2 #HTU2 elim (lift_div_le … HWU2 (i-j-1) 1 T2) /2 width=2 by/ -W2
    >minus_plus <plus_minus_m_m //
  ]
| -IH #p #_ #i #H elim H -H //
| #a #I #W #U #Hn #i #H elim (frees_inv_bind … H) -H
  #H elim (IH … H) // -H -n
  #X #HX #HnX [ @(ex2_intro … (ⓑ{a,I}X.U)) | @(ex2_intro … (ⓑ{a,I}W.X)) ] (**) (* explicit constructor *)
  /3 width=9 by cpys_bind, nlift_bind_dx, nlift_bind_sn/
| #I #W #U #Hn #i #H elim (frees_inv_flat … H) -H
  #H elim (IH … H) // -H -n
  #X #HX #HnX [ @(ex2_intro … (ⓕ{I}X.U)) | @(ex2_intro … (ⓕ{I}W.X)) ] (**) (* explicit constructor *)
  /3 width=8 by cpys_flat, nlift_flat_dx, nlift_flat_sn/
]
qed-.

(* Advanced negated properties **********************************************)

lemma frees_lt: ∀I,L,K,W,j. ⇩[j]L ≡ K.ⓑ{I}W →
                ∀i. j < i → (K ⊢ i-j-1 ~ϵ 𝐅*⦃W⦄ → ⊥) →
                ∀U. (∀T. ⇧[j, 1] T ≡ U → ⊥) →
                (L ⊢ i ~ϵ 𝐅*⦃U⦄ → ⊥).
/4 width=9 by cofrees_inv_lt/ qed-.

(* Relocation properties ****************************************************)

lemma cofrees_lift_be: ∀d,e,i. d ≤ i → i ≤ d + e →
                       ∀L,K,s. ⇩[s, d, e+1] L ≡ K → ∀T,U. ⇧[d, e+1] T ≡ U →
                       L ⊢ i ~ϵ 𝐅*⦃U⦄.
#d #e #i #Hdi #Hide #L #K #s #HLK #T1 #U1 #HTU1 #U2 #HU12
elim (cpys_inv_lift1 … HU12 … HLK … HTU1) #T2 #HTU2 #_ -s -L -K -U1 -T1
elim (lift_split … HTU2 i e) /2 width=2 by ex_intro/
qed.

lemma cofrees_lift_ge: ∀d,e,i. d + e ≤ i →
                       ∀L,K,s. ⇩[s, d, e] L ≡ K → ∀T,U. ⇧[d, e] T ≡ U →
                       K ⊢ i-e ~ϵ 𝐅*⦃T⦄ → L ⊢ i ~ϵ 𝐅*⦃U⦄.
#d #e #i #Hdei #L #K #s #HLK #T1 #U1 #HTU1 #HT1 #U2 #HU12
elim (le_inv_plus_l … Hdei) -Hdei #Hdie #Hei
elim (cpys_inv_lift1 … HU12 … HLK … HTU1) -s -L #T2 #HTU2 #HT12
elim (HT1 … HT12) -T1 #V2 #HVT2
elim (lift_trans_le … HVT2 … HTU2 ?) // <plus_minus_m_m /2 width=2 by ex_intro/
qed.