open Util
open Util.Vars
open Pure

(************ Syntax ************************************)

(* Normal forms*)

(* Var n = n-th De Bruijn index, 0-based *)

(*type nf =
  | Lam of nf
  | Var of int
  | i
and i =
  | I of int * nf listx
;;*)
type 'nf i_var_ = [ `I of int * 'nf Listx.listx | `Var of int ]
type 'nf i_n_var_ = [ `N of int | 'nf i_var_ ]
type 'nf i_num_var_ = [
  | 'nf i_n_var_
  | `Match of 'nf i_num_var_ * (*lift*) int * (*branches*)(int * 'nf) list ref * (*args*)'nf list
]
type 'nf nf_ = [ `Lam of (* was_unpacked *) bool * 'nf nf_ | `Bomb | `Pacman | 'nf i_num_var_ ]
type nf = nf nf_
type i_var = nf i_var_;;
type i_n_var = nf i_n_var_;;
type i_num_var = nf i_num_var_;;

let hd_of_i_var =
 function
   `I (v,_)
 | `Var v -> v

let hd_of =
 function
   `I (v,_)
 | `Var v -> Some v
 | `N _ -> None
 | `Match _ | `Bomb -> assert false

let lift m (t : nf) =
 let rec aux_i_num_var l =
  function
    `I(n,args) -> (`I((if n < l then n else n+m),Listx.map (aux l) args) : i_num_var)
   | `Var n -> `Var (if n < l then n else n+m)
   | `N _ as x -> x
   | `Match(t,lift,bs,args) ->
      `Match(aux_i_num_var l t, lift + m, bs, List.map (aux l) args)
 and aux l =
  function
     #i_num_var as x -> (aux_i_num_var l x :> nf)
   | `Lam(b,nf) -> `Lam (b,aux (l+1) nf)
   | `Bomb -> `Bomb
   | `Pacman -> `Pacman
 in
  (aux 0 t : nf)
;;

(* put t under n lambdas, lifting t accordingtly *)
let rec make_lams t =
 function
   0 -> t
 | n when n > 0 -> `Lam (false,lift 1 (make_lams t (n-1)))
 | _ -> assert false

let free_vars =
 let rec aux n = function
    `N _ -> []
  | `Var x -> if x < n then [] else [x-n]
  | `I(x,args) ->
      (if x < n then [] else [x-n]) @
      List.concat (List.map (aux n) (Listx.to_list args))
  | `Lam(_,t) -> aux (n+1) t
  | `Match(t,liftno,bs,args) ->
      aux n (t :> nf) @
      List.concat (List.map (fun (_,t) -> aux (n-liftno) t) !bs) @
      List.concat (List.map (aux n) args)
  | `Bomb | `Pacman -> []
  in aux 0
;;

module ToScott =
struct

let rec t_of_i_num_var =
 function
  | `N n -> Scott.mk_n n
  | `Var v -> Pure.V v
  | `Match(t,liftno,bs,args) ->
      let bs = List.map (fun (n,t) -> n, t_of_nf (lift liftno t)) !bs in
      let t = t_of_i_num_var t in
      let m = Scott.mk_match t bs in
      List.fold_left (fun acc t -> Pure.A(acc,t_of_nf t)) m args
  | `I(v, args) -> Listx.fold_left (fun acc t -> Pure.A(acc,t_of_nf t)) (Pure.V v) args
and t_of_nf =
 function
  | #i_num_var as x -> t_of_i_num_var x
  | `Lam(b,f) -> Pure.L (t_of_nf f)
  | `Bomb -> let f x = Pure.A (x,x) in f (Pure.L (f (Pure.V 0)))
  | `Pacman -> let f x = Pure.A (x,x) in f (Pure.L (Pure.L (f (Pure.V 0))))

end


(************ Pretty-printing ************************************)

(* let rec print ?(l=[]) =
 function
    `Var n -> print_name l n
  | `N n -> string_of_int n
  | `Match(t,bs_lift,bs,args) ->
     "([" ^ print ~l (t :> nf) ^
     " ? " ^ String.concat " | " (List.map (fun (n,t) -> string_of_int n ^ " => " ^ print ~l (lift bs_lift t)) !bs) ^ "] " ^
     String.concat " " (List.map (print ~l) args) ^ ")"
  | `I(n,args) -> "(" ^ print_name l n ^ " " ^ String.concat " " (Listx.to_list (Listx.map (print ~l) args)) ^ ")"
  | `Lam(_,nf) ->
     let name = string_of_var (List.length l) in
     "λ" ^ name ^ "." ^ print ~l:(name::l) (nf : nf)
;; *)

let rec string_of_term l =
 let rec string_of_term_w_pars l = function
  | `Var n -> print_name l n
  | `N n -> string_of_int n
  | `I _ as t -> "(" ^ string_of_term_no_pars_app l (t :> nf) ^ ")"
  | `Lam _ as t -> "(" ^ string_of_term_no_pars_lam l t ^ ")"
  | `Match(t,bs_lift,bs,args) ->
     "(match " ^ string_of_term_no_pars l (t :> nf) ^
     " with " ^ String.concat " | " (List.map (fun (n,t) -> string_of_int n ^ " => " ^ string_of_term l (lift bs_lift t)) !bs) ^ "] " ^
     String.concat " " (List.map (string_of_term l) args) ^ ")"
  | `Bomb -> "TNT"
  | `Pacman -> "PAC"
 and string_of_term_no_pars_app l = function
  | `I(n, args) -> print_name l n ^ " " ^ String.concat " " (List.map (string_of_term_w_pars l) (Listx.to_list args))
  | #nf as t -> string_of_term_w_pars l t
 and string_of_term_no_pars_lam l  = function
  | `Lam(_,t) -> let name = string_of_var (List.length l) in
   "λ" ^ name ^ ". " ^ (string_of_term_no_pars_lam (name::l) t)
  | _ as t -> string_of_term_no_pars l t
 and string_of_term_no_pars l : nf -> string = function
  | `Lam _ as t -> string_of_term_no_pars_lam l t
  | #nf as t -> string_of_term_no_pars_app l t
 in string_of_term_no_pars l
;;

let rec print ?(l=[]) = string_of_term l;;

(************ Hereditary substitutions ************************************)

let cast_to_i_var =
 function
    #i_var as y -> (y : i_var)
  | t ->
    prerr_endline (print (t :> nf));
    assert false (* algorithm failed *)

let cast_to_i_n_var =
 function
    #i_n_var as y -> (y : i_n_var)
  | t ->
    prerr_endline (print (t :> nf));
    assert false (* algorithm failed *)

let cast_to_i_num_var =
 function
    #i_num_var as y -> (y : i_num_var)
  | t ->
    prerr_endline (print (t :> nf));
    assert false (* algorithm failed *)

let rec mk_app (h : nf) (arg : nf) =
(*let res =*)
 match h with
    `I(n,args) -> `I(n,Listx.append (Listx.Nil arg) args)
  | `Var n -> `I(n, Listx.Nil arg)
  | `Lam(_,nf) -> subst true 0 arg (nf : nf)
  | `Match(t,lift,bs,args) -> `Match(t,lift,bs,List.append args [arg])
  | `N _ -> assert false (* Numbers cannot be applied *)
  | `Bomb | `Pacman -> failwith "mk_app su bomba o pacman"
(*in let l = ["v0";"v1";"v2"] in
prerr_endline ("mk_app h:" ^ print ~l h ^ " arg:" ^ print ~l:l arg ^ " res:" ^ print ~l:l res); res*)

and mk_appl h args =
 (*prerr_endline ("MK_APPL: " ^ print h ^ " " ^ String.concat " " (List.map print args));*)
 List.fold_left mk_app h args

and mk_appx h args = Listx.fold_left mk_app h args

and mk_match t bs_lift bs args =
 (*prerr_endline ("MK_MATCH: ([" ^ print t ^ "] " ^ String.concat " " (Listx.to_list (Listx.map (fun (n,t) -> string_of_int n ^ " => " ^ print t) bs)) ^ ") " ^ String.concat " " (List.map print args));*)
 match t with
    `N m ->
      (try
        let h = List.assoc m !bs in
        let h = lift bs_lift h in
        mk_appl h args
       with Not_found ->
        `Match (t,bs_lift,bs,args))
  | `I _ | `Var _ | `Match _ -> `Match(t,bs_lift,bs,args)

and subst delift_by_one what (with_what : nf) (where : nf) =
 let rec aux_i_num_var l =
  function
     `I(n,args) ->
       if n = what + l then
        mk_appx (lift l with_what) (Listx.map (aux l) args)
       else
        `I ((if delift_by_one && n >= l then n-1 else n), Listx.map (aux l) args)
   | `Var n ->
       if n = what + l then
        lift l with_what
       else
        `Var (if delift_by_one && n >= l then n-1 else n)
   | `N _ as x -> x
   | `Match(t,bs_lift,bs,args) ->
       let bs_lift = bs_lift + if delift_by_one then -1 else 0 in
       let l' = l - bs_lift  in
       let with_what' = lift l' with_what in
       (* The following line should be the identity when delift_by_one = true because we
          are assuming the ts to not contain lambda-bound variables. *)
       bs := List.map (fun (n,t) -> n,subst false what with_what' t) !bs ;
       mk_match (cast_to_i_num_var (aux_i_num_var l t)) bs_lift bs (List.map (aux l) args)
 and aux l(*lift*) =
(*function iii -> let res = match iii with*)
  function
   | #i_num_var as x -> aux_i_num_var l x
   | `Lam(b,nf) -> `Lam(b,aux (l+1) nf)
   | `Bomb -> `Bomb
   | `Pacman -> `Pacman
(*in let ll = ["v0";"v1";"v2"] in
prerr_endline ("subst l:" ^ string_of_int l ^ " delift_by_one:" ^ string_of_bool delift_by_one ^ " what:" ^ (List.nth ll what) ^ " with_what:" ^ print ~l:ll with_what ^ " where:" ^ print ~l:ll iii ^ " res:" ^ print ~l:ll res); res*)
 in
  aux 0 where
;;

(************ Parsing ************************************)

let parse' strs =
  let rec aux = function
  | Parser.Lam t -> `Lam (true,aux t)
  | Parser.App (t1, t2) -> mk_app (aux t1) (aux t2)
  | Parser.Var v -> `Var v
  in let (tms, free) = Parser.parse_many strs
  in (List.map aux tms, free)
;;

(************** Algorithm(s) ************************)

let eta_eq x y =
  let rec aux = function
  | `Var n , `Var m -> n = m
  | `I(n1, l1), `I(n2, l2) ->
    n1 = n2 && Listx.length l1 = Listx.length l2 &&
    List.for_all aux (List.combine (Listx.to_list l1) (Listx.to_list l2))
  | `Lam(_,t1), `Lam(_,t2) -> aux (t1,t2)
  | `Lam(_,t1), t2
  | t2, `Lam(_,t1) -> aux( t1,  (mk_app (lift 1 t2) (`Var 0)) )
  | `N n1, `N n2 -> n1 = n2
  | `Match(u,bs_lift,bs,args), `Match(u',bs_lift',bs',args') ->
    aux ((u :> nf), (u' :> nf)) && List.length !bs = List.length !bs' &&
    let bs = List.sort (fun (n,_) (m,_) -> compare n m) !bs in
    let bs' = List.sort (fun (n,_) (m,_) -> compare n m) !bs' in
    List.for_all (fun ((n,t),(n',t')) -> n = n' && aux (t, t')) (List.combine bs bs') && List.length args = List.length args' &&
    List.for_all aux (List.combine args args')
  | _ -> false
  in aux (x, y)
;;

let eta_compare x y =
  if eta_eq x y then 0 else compare x y
;;

let eta_eq (#nf as x) (#nf as y) = eta_eq x y;;

let rec eta_subterm sub t =
 if eta_eq sub t then true else
  match t with
  | `Lam(_,t') -> eta_subterm (lift 1 sub) t'
  | `Match(u,liftno,bs,args) ->
     eta_subterm sub (u :> nf)
     || List.exists (fun (_, t) -> eta_subterm sub (lift liftno t)) !bs
     || List.exists (eta_subterm sub) args
  | `I(v, args) -> List.exists (eta_subterm sub) (Listx.to_list args) || (match sub with
   | `Var v' -> v = v'
   | `I(v', args') -> v = v'
    && Listx.length args' < Listx.length args
    && List.for_all (fun (x,y) -> eta_eq x y) (List.combine (Util.take (Listx.length args') (Listx.to_list args)) (Listx.to_list args'))
   | _ -> false
   )
  | `N _ | `Var _ | `Bomb | `Pacman -> false
;;

let eta_subterm (#nf as x) (#nf as y) = eta_subterm x y;;