(** This module provides a function to print [ERTL] programs. *)


let n_spaces n = String.make n ' '


let print_global n (x, size) =
  Printf.sprintf "%s\"%s\" [%d]" (n_spaces n) x size

let print_globals eformat n globs =
  Eformat.printf eformat "%sglobals:\n" (n_spaces n) ;
  List.iter
    (fun g -> Eformat.printf eformat "%s\n" (print_global (n+2) g)) globs


let reg_set_to_list rs =
  let f r l = l @ [r] in
  Register.Set.fold f rs []

let print_reg_list first last sep f rl =
  Printf.sprintf "%s%s%s"
    first (MiscPottier.string_of_list sep f rl) last

let print_ptr rl = print_reg_list "[" "]" " ; " Register.print rl

let print_args rl = print_reg_list "(" ")" ", " Register.print rl

let print_return rl = print_reg_list "[" "]" " ; " Register.print rl

let print_params rl = print_reg_list "(" ")" ", " Register.print rl

let print_locals rs =
  let rl = reg_set_to_list rs in
  Printf.sprintf "%s" (print_reg_list "" "" ", " Register.print rl)

let print_result rl = print_reg_list "[" "]" " ; " Register.print rl


let print_statement = function
  | ERTL.St_skip lbl -> "--> " ^ lbl
  | ERTL.St_comment (s, lbl) ->
    Printf.sprintf "*** %s *** --> %s" s lbl
  | ERTL.St_cost (cost_lbl, lbl) ->
    Printf.sprintf "emit %s --> %s" cost_lbl lbl
  | ERTL.St_get_hdw (r1, r2, lbl) ->
    Printf.sprintf "move %s, %s --> %s"
      (Register.print r1) (I8051.print_register r2) lbl
  | ERTL.St_set_hdw (r1, r2, lbl) ->
    Printf.sprintf "move %s, %s --> %s"
      (I8051.print_register r1) (Register.print r2) lbl
  | ERTL.St_hdw_to_hdw (r1, r2, lbl) ->
    Printf.sprintf "move %s, %s --> %s"
      (I8051.print_register r1) (I8051.print_register r2) lbl
  | ERTL.St_newframe lbl ->
    Printf.sprintf "newframe --> %s" lbl
  | ERTL.St_delframe lbl ->
    Printf.sprintf "delframe --> %s" lbl
  | ERTL.St_framesize (r, lbl) ->
    Printf.sprintf "imm %s, FRAMESIZE --> %s" (Register.print r) lbl
  | ERTL.St_pop (r, lbl) ->
    Printf.sprintf "pop %s --> %s" (Register.print r) lbl
  | ERTL.St_push (r, lbl) ->
    Printf.sprintf "push %s --> %s" (Register.print r) lbl
  | ERTL.St_addrH (dstr, id, lbl) ->
    Printf.sprintf "addrH %s, %s --> %s" (Register.print dstr) id lbl
  | ERTL.St_addrL (dstr, id, lbl) ->
    Printf.sprintf "addrL %s, %s --> %s" (Register.print dstr) id lbl
  | ERTL.St_int (dstr, i, lbl) ->
    Printf.sprintf "imm %s, %d --> %s" (Register.print dstr) i lbl
  | ERTL.St_move (dstr, srcr, lbl) ->
    Printf.sprintf "move %s, %s --> %s"
      (Register.print dstr) (Register.print srcr) lbl
  | ERTL.St_opaccsA (opaccs, dstr, srcr1, srcr2, lbl) ->
    Printf.sprintf "%sA %s, %s, %s --> %s"
      (I8051.print_opaccs opaccs)
      (Register.print dstr)
      (Register.print srcr1)
      (Register.print srcr2)
      lbl
  | ERTL.St_opaccsB (opaccs, dstr, srcr1, srcr2, lbl) ->
    Printf.sprintf "%sB %s, %s, %s --> %s"
      (I8051.print_opaccs opaccs)
      (Register.print dstr)
      (Register.print srcr1)
      (Register.print srcr2)
      lbl
  | ERTL.St_op1 (op1, dstr, srcr, lbl) ->
    Printf.sprintf "%s %s, %s --> %s"
      (I8051.print_op1 op1)
      (Register.print dstr)
      (Register.print srcr)
      lbl
  | ERTL.St_op2 (op2, dstr, srcr1, srcr2, lbl) ->
    Printf.sprintf "%s %s, %s, %s --> %s"
      (I8051.print_op2 op2)
      (Register.print dstr)
      (Register.print srcr1)
      (Register.print srcr2)
      lbl
  | ERTL.St_clear_carry lbl ->
    Printf.sprintf "clear CARRY --> %s" lbl
  | ERTL.St_set_carry lbl ->
    Printf.sprintf "set CARRY --> %s" lbl
  | ERTL.St_load (dstr, addr1, addr2, lbl) ->
    Printf.sprintf "load %s, (%s, %s) --> %s"
      (Register.print dstr)
      (Register.print addr1)
      (Register.print addr2)
      lbl
  | ERTL.St_store (addr1, addr2, srcr, lbl) ->
    Printf.sprintf "store (%s, %s), %s --> %s"
      (Register.print addr1)
      (Register.print addr2)
      (Register.print srcr)
      lbl
  | ERTL.St_call_id (f, nb_args, lbl) ->
    Printf.sprintf "call \"%s\", %d --> %s" f nb_args lbl
  | ERTL.St_call_ptr (f1, f2, nb_args, lbl) ->
    Printf.sprintf "call_ptr [%s ; %s], %d --> %s"
      (Register.print f1)
      (Register.print f2)
      nb_args
      lbl
(*
  | ERTL.St_tailcall_id (f, nb_args) ->
    Printf.sprintf "tailcall \"%s\", %d"
      f
      nb_args
  | ERTL.St_tailcall_ptr (f, args) ->
    Printf.sprintf "tailcall_ptr %s, %s"
      (print_ptr f)
      (print_args args)
*)
  | ERTL.St_cond (srcr, lbl_true, lbl_false) ->
    Printf.sprintf "branch %s <> 0 --> %s, %s"
      (Register.print srcr) lbl_true lbl_false
  | ERTL.St_return ret_regs ->
    Printf.sprintf "return %s" (print_return ret_regs)


let print_graph eformat n c =
  let f lbl stmt =
    Eformat.printf eformat "%s%s: %s\n"
      (n_spaces n)
      lbl
      (print_statement stmt) in
  Label.Map.iter f c


let print_internal_decl eformat n f def =
  Eformat.printf eformat
    "%s\"%s\" %d\n%slocals: %s\n%sstacksize: %d\n%sentry: %s\n%sexit: %s\n\n"
    (n_spaces n)
    f
    def.ERTL.f_params
    (n_spaces (n+2))
    (print_locals def.ERTL.f_locals)
    (n_spaces (n+2))
    def.ERTL.f_stacksize
    (n_spaces (n+2))
    def.ERTL.f_entry
    (n_spaces (n+2))
    def.ERTL.f_exit ;
  print_graph eformat (n+2) def.ERTL.f_graph


let print_external_decl eformat n f def =
  Eformat.printf eformat "%sextern \"%s\": %s\n"
    (n_spaces n)
    f
    (Primitive.print_sig def.AST.ef_sig)


let print_fun_decl eformat n (f, def) = match def with
  | ERTL.F_int def -> print_internal_decl eformat n f def
  | ERTL.F_ext def -> print_external_decl eformat n f def

let print_fun_decls eformat n functs =
  List.iter
    (fun f -> print_fun_decl eformat n f ; Eformat.printf eformat "\n\n")
    functs


let print_program p =
  let eformat = Eformat.create () in
  Eformat.printf eformat "program:\n\n\n" ;
  print_globals eformat 2 p.ERTL.vars ;
  Eformat.printf eformat "\n\n" ;
  print_fun_decls eformat 2 p.ERTL.functs ;
  Eformat.get eformat