(** This module provides a function to print [RTL] programs. *)


let n_spaces n = String.make n ' '


let print_global n (x, size) =
  Printf.sprintf "%s\"%s\" [%d]" (n_spaces n) x size

let print_globals eformat n globs =
  Eformat.printf eformat "%sglobals:\n" (n_spaces n) ;
  List.iter
    (fun g -> Eformat.printf eformat "%s\n" (print_global (n+2) g)) globs

let print_reg = Register.print

let reg_set_to_list rs =
  let e = ref [] in
  Register.Set.iter (fun r -> e := r :: !e) rs;
  List.rev !e

let print_reg_list first last sep f rl =
  Printf.sprintf "%s%s%s"
    first (MiscPottier.string_of_list sep f rl) last

let print_ptr rl = print_reg_list "[" "]" " ; " print_reg rl

let print_args rl = print_reg_list "(" ")" ", " print_reg rl

let print_return rl = print_reg_list "[" "]" " ; " print_reg rl

let print_params rl = print_reg_list "(" ")" ", " Register.print rl

let print_locals rs =  
  let rl = reg_set_to_list rs in
  Printf.sprintf "%s" (print_reg_list "" "" ", " Register.print rl) 

let print_result rl = print_reg_list "[" "]" " ; " Register.print rl


let print_statement = function
  | RTL.St_skip lbl -> "--> " ^ lbl
  | RTL.St_cost (cost_lbl, lbl) ->
    Printf.sprintf "emit %s --> %s" cost_lbl lbl
  | RTL.St_addr (dstr1, dstr2, id, lbl) ->
    Printf.sprintf "imm (%s, %s), %s --> %s"
      (print_reg dstr1) (print_reg dstr2) id lbl
  | RTL.St_stackaddr (dstr1, dstr2, lbl) ->
    Printf.sprintf "imm (%s, %s), STACK --> %s"
      (print_reg dstr1) (print_reg dstr2) lbl
  | RTL.St_int (dstr, i, lbl) ->
    Printf.sprintf "imm %s, %d --> %s" (print_reg dstr) i lbl
  | RTL.St_move (dstr, srcr, lbl) ->
    Printf.sprintf "move %s, %s --> %s"
      (print_reg dstr) (print_reg srcr) lbl
  | RTL.St_opaccs (opaccs, dstr1, dstr2, srcr1, srcr2, lbl) ->
    Printf.sprintf "%s (%s, %s) %s, %s --> %s"
      (I8051.print_opaccs opaccs)
      (print_reg dstr1)
      (print_reg dstr2)
      (print_reg srcr1)
      (print_reg srcr2)
      lbl
  | RTL.St_op1 (op1, dstr, srcr, lbl) ->
    Printf.sprintf "%s %s, %s --> %s"
      (I8051.print_op1 op1) (print_reg dstr) (print_reg srcr) lbl
  | RTL.St_op2 (op2, dstr, srcr1, srcr2, lbl) ->
    Printf.sprintf "%s %s, %s, %s --> %s"
      (I8051.print_op2 op2)
      (print_reg dstr)
      (print_reg srcr1)
      (print_reg srcr2)
      lbl
  | RTL.St_clear_carry lbl ->
    Printf.sprintf "clear CARRY --> %s" lbl
  | RTL.St_set_carry lbl ->
    Printf.sprintf "set CARRY --> %s" lbl
  | RTL.St_load (dstr, addr1, addr2, lbl) ->
    Printf.sprintf "load %s, (%s, %s) --> %s"
      (print_reg dstr)
      (print_reg addr1)
      (print_reg addr2)
      lbl
  | RTL.St_store (addr1, addr2, srcr, lbl) ->
    Printf.sprintf "store (%s, %s), %s --> %s"
      (print_reg addr1)
      (print_reg addr2)
      (print_reg srcr)
      lbl
  | RTL.St_call_id (f, args, dstrs, lbl) ->
    Printf.sprintf "call \"%s\", %s, %s --> %s"
      f
      (print_args args)
      (print_return dstrs)
      lbl
  | RTL.St_call_ptr (f1, f2, args, dstrs, lbl) ->
    Printf.sprintf "call_ptr [%s ; %s], %s, %s --> %s"
      (print_reg f1)
      (print_reg f2)
      (print_args args)
      (print_return dstrs)
      lbl
  | RTL.St_tailcall_id (f, args) ->
    Printf.sprintf "tailcall \"%s\", %s"
      f
      (print_args args)
  | RTL.St_tailcall_ptr (f1, f2, args) ->
    Printf.sprintf "tailcall_ptr [%s ; %s], %s"
      (print_reg f1)
      (print_reg f2)
      (print_args args)
  | RTL.St_cond (srcr, lbl_true, lbl_false) ->
    Printf.sprintf "branch %s <> 0 --> %s, %s"
      (print_reg srcr) lbl_true lbl_false
  | RTL.St_return regs ->
    Printf.sprintf "return %s" (print_return regs)


let print_graph eformat n c =
  let f lbl stmt =
    Eformat.printf eformat "%s%s: %s\n"
      (n_spaces n)
      lbl
      (print_statement stmt) in
  Label.Map.iter f c


let print_internal_decl eformat n f def =
  Eformat.printf eformat
    "%s\"%s\"%s\n%slocals: %s\n%sresult: %s\n%sstacksize: %d\n%sentry: %s\n%sexit: %s\n\n"
    (n_spaces n)
    f
    (print_params def.RTL.f_params)
    (n_spaces (n+2))
    (print_locals def.RTL.f_locals)
    (n_spaces (n+2))
    (print_result def.RTL.f_result)
    (n_spaces (n+2))
    def.RTL.f_stacksize
    (n_spaces (n+2))
    def.RTL.f_entry
    (n_spaces (n+2))
    def.RTL.f_exit ;
  print_graph eformat (n+2) def.RTL.f_graph


let print_external_decl eformat n f def =
  Eformat.printf eformat "%sextern \"%s\": %s\n"
    (n_spaces n)
    f
    (Primitive.print_sig def.AST.ef_sig)


let print_fun_decl eformat n (f, def) = match def with
  | RTL.F_int def -> print_internal_decl eformat n f def
  | RTL.F_ext def -> print_external_decl eformat n f def

let print_fun_decls eformat n functs =
  List.iter
    (fun f -> print_fun_decl eformat n f ; Eformat.printf eformat "\n\n")
    functs


let print_program p =
  let eformat = Eformat.create () in
  Eformat.printf eformat "program:\n\n\n" ;
  print_globals eformat 2 p.RTL.vars ;
  Eformat.printf eformat "\n\n" ;
  print_fun_decls eformat 2 p.RTL.functs ;
  Eformat.get eformat