+ | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
+ | term -> aux (-1, -1) context term
+
+let domain_of_term ~context ast =
+ (* "aux" keeps domain in reverse order and doesn't care about duplicates.
+ * Domain item more in deep in the list will be processed first.
+ *)
+ let rec aux loc context = function
+ | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
+ | CicAst.AttributedTerm (_, term) -> aux loc context term
+ | CicAst.Appl terms ->
+ List.fold_left (fun dom term -> aux loc context term @ dom) [] terms
+ | CicAst.Binder (kind, (var, typ), body) ->
+ let kind_dom =
+ match kind with
+ | `Exists -> [ Symbol ("exists", 0) ]
+ | _ -> []
+ in
+ let type_dom = aux_option loc context typ in
+ let body_dom = aux loc (var :: context) body in
+ body_dom @ type_dom @ kind_dom
+ | CicAst.Case (term, indty_ident, outtype, branches) ->
+ let term_dom = aux loc context term in
+ let outtype_dom = aux_option loc context outtype in
+ let do_branch ((head, args), term) =
+ let (term_context, args_domain) =
+ List.fold_left
+ (fun (cont, dom) (name, typ) ->
+ (name :: cont,
+ (match typ with
+ | None -> dom
+ | Some typ -> aux loc cont typ @ dom)))
+ (context, []) args
+ in
+ args_domain @ aux loc term_context term
+ in
+ let branches_dom =
+ List.fold_left (fun dom branch -> do_branch branch @ dom) [] branches
+ in
+ branches_dom @ outtype_dom @ term_dom @
+ (match indty_ident with None -> [] | Some ident -> [ Id ident ])
+ | CicAst.LetIn ((var, typ), body, where) ->
+ let body_dom = aux loc context body in
+ let type_dom = aux_option loc context typ in
+ let where_dom = aux loc (var :: context) where in
+ where_dom @ type_dom @ body_dom
+ | CicAst.LetRec (kind, defs, where) ->
+ let context' =
+ List.fold_left (fun acc ((var, typ), _, _) -> var :: acc)
+ context defs
+ in
+ let where_dom = aux loc context' where in
+ let defs_dom =
+ List.fold_left
+ (fun dom ((_, typ), body, _) ->
+ aux loc context' body @ aux_option loc context typ)
+ [] defs
+ in
+ where_dom @ defs_dom
+ | CicAst.Ident (name, subst) ->
+ (try
+ let index = find_in_environment name context in
+ if subst <> None then
+ CicTextualParser2.fail loc
+ "Explicit substitutions not allowed here"
+ else
+ []
+ with Not_found ->
+ (match subst with
+ | None -> [Id name]
+ | Some subst ->
+ List.fold_left
+ (fun dom (_, term) ->
+ let dom' = aux loc context term in
+ dom' @ dom)
+ [Id name] subst))
+ | CicAst.Implicit -> []
+ | CicAst.Num (num, i) -> [ Num i ]
+ | CicAst.Meta (index, local_context) ->
+ List.fold_left (fun dom term -> aux_option loc context term @ dom) []
+ local_context
+ | CicAst.Sort _ -> []
+ | CicAst.Symbol (symbol, instance) -> [ Symbol (symbol, instance) ]
+
+ and aux_option loc context = function
+ | None -> []
+ | Some t -> aux loc context t
+ in
+
+ (* e.g. [5;1;1;1;2;3;4;1;2] -> [2;1;4;3;5] *)
+ let rev_uniq =
+ let module SortedItem =
+ struct
+ type t = DisambiguateTypes.domain_item
+ let compare = Pervasives.compare
+ end
+ in
+ let module Set = Set.Make (SortedItem) in
+ fun l ->
+ let rev_l = List.rev l in
+ let (_, uniq_rev_l) =
+ List.fold_left
+ (fun (members, rev_l) elt ->
+ if Set.mem elt members then
+ (members, rev_l)
+ else
+ Set.add elt members, elt :: rev_l)
+ (Set.empty, []) rev_l
+ in
+ List.rev uniq_rev_l
+ in
+
+ rev_uniq
+ (match ast with
+ | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
+ | term -> aux (-1, -1) context term)
+
+
+ (* dom1 \ dom2 *)
+let domain_diff dom1 dom2 =
+(* let domain_diff = Domain.diff *)
+ let is_in_dom2 =
+ List.fold_left (fun pred elt -> (fun elt' -> elt' = elt || pred elt'))
+ (fun _ -> false) dom2
+ in
+ List.filter (fun elt -> not (is_in_dom2 elt)) dom1
+
+module Make (C: Callbacks) =
+ struct
+ let choices_of_id mqi_handle id =
+ let query = MQueryGenerator.locate id in
+ let result = MQueryInterpreter.execute mqi_handle query in
+ let uris =
+ List.map
+ (function uri,_ ->
+ MQueryMisc.wrong_xpointer_format_from_wrong_xpointer_format' uri
+ ) result in
+ let uris' =
+ match uris with
+ | [] ->
+ [UriManager.string_of_uri (C.input_or_locate_uri
+ ~title:("URI matching \"" ^ id ^ "\" unknown.") ~id)]
+ | [uri] -> [uri]
+ | _ ->
+ C.interactive_user_uri_choice ~selection_mode:`MULTIPLE
+ ~ok:"Try selected." ~enable_button_for_non_vars:true
+ ~title:"Ambiguous input." ~id
+ ~msg: ("Ambiguous input \"" ^ id ^
+ "\". Please, choose one or more interpretations:")
+ uris
+ in
+ List.map
+ (fun uri ->
+ (uri,
+ let term =
+ try
+ HelmLibraryObjects.term_of_uri (UriManager.uri_of_string uri)
+ with _ -> assert false
+ in
+ fun _ _ _ -> term))
+ uris'
+
+ let disambiguate_term mqi_handle context metasenv term ~aliases:current_env
+ =
+ debug_print "NEW DISAMBIGUATE INPUT";
+ let disambiguate_context = (* cic context -> disambiguate context *)
+ List.map
+ (function None -> Cic.Anonymous | Some (name, _) -> name)
+ context
+ in
+ let term_dom = domain_of_term ~context:disambiguate_context term in
+ debug_print (sprintf "DISAMBIGUATION DOMAIN: %s"
+ (string_of_domain term_dom));
+ let current_dom =
+ Environment.fold (fun item _ dom -> item :: dom) current_env []
+ in
+ let todo_dom = domain_diff term_dom current_dom in
+ (* (2) lookup function for any item (Id/Symbol/Num) *)
+ let lookup_choices =
+ let id_choices = Hashtbl.create 1023 in
+ fun item ->
+ let choices =
+ match item with
+ | Id id ->
+ (try
+ Hashtbl.find id_choices id
+ with Not_found ->
+ let choices = choices_of_id mqi_handle id in
+ Hashtbl.add id_choices id choices;
+ choices)
+ | Symbol (symb, _) -> DisambiguateChoices.lookup_symbol_choices symb
+ | Num instance -> DisambiguateChoices.lookup_num_choices ()
+ in
+ if choices = [] then raise (No_choices item);
+ choices
+ in
+ (* (3) test an interpretation filling with meta uninterpreted identifiers
+ *)
+ let test_env current_env todo_dom =
+ let filled_env =
+ List.fold_left
+ (fun env item ->
+ Environment.add item
+ ("Implicit",
+ (match item with
+ | Id _ | Num _ -> (fun _ _ _ -> Cic.Implicit (Some `Closed))
+ | Symbol _ -> (fun _ _ _ -> Cic.Implicit None))) env)
+ current_env todo_dom
+ in
+ try
+ let cic_term =
+ interpretate ~context:disambiguate_context ~env:filled_env term
+ in
+ refine metasenv context cic_term
+ with
+ | Try_again -> Uncertain
+ | DisambiguateChoices.Invalid_choice -> Ko
+ in
+ (* (4) build all possible interpretations *)
+ let rec aux current_env todo_dom =
+ match todo_dom with
+ | [] ->
+ (match test_env current_env [] with
+ | Ok (term, metasenv) -> [ current_env, metasenv, term ]
+ | Ko | Uncertain -> [])
+ | item :: remaining_dom ->
+ debug_print (sprintf "CHOOSED ITEM: %s"
+ (string_of_domain_item item));
+ let choices = lookup_choices item in
+ let rec filter = function
+ | [] -> []
+ | codomain_item :: tl ->
+ debug_print (sprintf "%s CHOSEN" (fst codomain_item)) ;
+ let new_env =
+ Environment.add item codomain_item current_env
+ in
+ (match test_env new_env remaining_dom with
+ | Ok (term, metasenv) ->
+ (match remaining_dom with
+ | [] -> [ new_env, metasenv, term ]
+ | _ -> aux new_env remaining_dom) @ filter tl
+ | Uncertain ->
+ (match remaining_dom with
+ | [] -> []
+ | _ -> aux new_env remaining_dom) @ filter tl
+ | Ko -> filter tl)
+ in
+ filter choices
+ in
+ match aux current_env todo_dom with
+ | [] -> raise NoWellTypedInterpretation
+ | [ _ ] as l ->
+ debug_print "UNA SOLA SCELTA";
+ l
+ | l ->
+ debug_print (sprintf "PIU' SCELTE (%d)" (List.length l));
+ let choices =
+ List.map
+ (fun (env, _, _) ->
+ List.map
+ (fun domain_item ->
+ let description =
+ fst (Environment.find domain_item env)
+ in
+ (descr_of_domain_item domain_item, description))
+ term_dom)
+ l
+ in
+ let choosed = C.interactive_interpretation_choice choices in
+ List.map (List.nth l) choosed
+
+ end