+theorem cotransitivity:
+ ∀A:axiom_set.∀a:A.∀U,V. a ⋉ U → (∀b:A. b ⋉ U → b ∈ V) → a ⋉ V.
+ intros;
+ apply (fish_rec ?? {a|a ⋉ U} ??? H); simplify; intros;
+ [ apply H1; apply H2;
+ | cases H2 in j; clear H2; intro i;
+ cases (H4 i); clear H4; exists[apply a3] assumption]
+qed.
+
+theorem compatibility: ∀A:axiom_set.∀a:A.∀U,V. a ⋉ V → a ◃ U → U ⋉ V.
+ intros;
+ generalize in match H; clear H;
+ apply (covers_elim ?? {a|a ⋉ V → U ⋉ V} ??? H1);
+ clear H1; simplify; intros;
+ [ exists [apply a1] assumption
+ | cases H2 in j H H1; clear H2 a1; intros;
+ cases (H1 i); clear H1; apply (H3 a1); assumption]
+qed.
+
+definition singleton ≝ λA:axiom_set.λa:A.{b | a=b}.
+
+notation "hvbox({ term 19 a })" with precedence 90 for @{ 'singl $a}.
+
+interpretation "singleton" 'singl a = (singleton _ a).
+
+definition leq ≝ λA:axiom_set.λa,b:A. a ◃ {b}.
+
+interpretation "covered by one" 'leq a b = (leq _ a b).
+
+theorem leq_refl: ∀A:axiom_set.∀a:A. a ≤ a.
+ intros;
+ apply refl;
+ normalize;
+ reflexivity.
+qed.
+
+theorem leq_trans: ∀A:axiom_set.∀a,b,c:A. a ≤ b → b ≤ c → a ≤ c.
+ intros;
+ unfold in H H1 ⊢ %;
+ apply (transitivity ???? H);
+ constructor 1;
+ intros;
+ normalize in H2;
+ rewrite < H2;
+ assumption.
+qed.
+
+definition uparrow ≝ λA:axiom_set.λa:A.mk_powerset ? (λb:A. a ≤ b).
+
+notation "↑a" with precedence 80 for @{ 'uparrow $a }.
+
+interpretation "uparrow" 'uparrow a = (uparrow _ a).
+
+definition downarrow ≝ λA:axiom_set.λU:2 \sup A.mk_powerset ? (λa:A. ↑a ≬ U).
+
+notation "↓a" with precedence 80 for @{ 'downarrow $a }.
+
+interpretation "downarrow" 'downarrow a = (downarrow _ a).
+
+definition fintersects ≝ λA:axiom_set.λU,V:2 \sup A.↓U ∩ ↓V.
+
+notation "hvbox(U break ↓ V)" non associative with precedence 80 for @{ 'fintersects $U $V }.
+
+interpretation "fintersects" 'fintersects U V = (fintersects _ U V).
+
+record convergent_generated_topology : Type ≝
+ { AA:> axiom_set;
+ convergence: ∀a:AA.∀U,V:2 \sup AA. a ◃ U → a ◃ V → a ◃ U ↓ V
+ }.
+