+record category2 : Type3 ≝
+ { objs2:> Type2;
+ arrows2: objs2 → objs2 → setoid2;
+ id2: ∀o:objs2. arrows2 o o;
+ comp2: ∀o1,o2,o3. binary_morphism2 (arrows2 o1 o2) (arrows2 o2 o3) (arrows2 o1 o3);
+ comp_assoc2: ∀o1,o2,o3,o4. ∀a12,a23,a34.
+ comp2 o1 o3 o4 (comp2 o1 o2 o3 a12 a23) a34 =_2 comp2 o1 o2 o4 a12 (comp2 o2 o3 o4 a23 a34);
+ id_neutral_right2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? (id2 o1) a =_2 a;
+ id_neutral_left2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? a (id2 o2) =_2 a
+ }.
+
+record category3 : Type4 ≝
+ { objs3:> Type3;
+ arrows3: objs3 → objs3 → setoid3;
+ id3: ∀o:objs3. arrows3 o o;
+ comp3: ∀o1,o2,o3. binary_morphism3 (arrows3 o1 o2) (arrows3 o2 o3) (arrows3 o1 o3);
+ comp_assoc3: ∀o1,o2,o3,o4. ∀a12,a23,a34.
+ comp3 o1 o3 o4 (comp3 o1 o2 o3 a12 a23) a34 =_3 comp3 o1 o2 o4 a12 (comp3 o2 o3 o4 a23 a34);
+ id_neutral_right3: ∀o1,o2. ∀a: arrows3 o1 o2. comp3 ??? (id3 o1) a =_3 a;
+ id_neutral_left3: ∀o1,o2. ∀a: arrows3 o1 o2. comp3 ??? a (id3 o2) =_3 a
+ }.
+
+notation "'ASSOC'" with precedence 90 for @{'assoc}.
+
+interpretation "category2 composition" 'compose x y = (fun22 ??? (comp2 ????) y x).
+interpretation "category2 assoc" 'assoc = (comp_assoc2 ????????).
+interpretation "category1 composition" 'compose x y = (fun21 ??? (comp1 ????) y x).
+interpretation "category1 assoc" 'assoc = (comp_assoc1 ????????).
+interpretation "category composition" 'compose x y = (fun2 ??? (comp ????) y x).
+interpretation "category assoc" 'assoc = (comp_assoc ????????).
+
+definition category2_of_category1: category1 → category2.
+ intro;
+ constructor 1;
+ [ apply (objs1 c);
+ | intros; apply (setoid2_of_setoid1 (arrows1 c o o1));
+ | apply (id1 c);
+ | intros;
+ constructor 1;
+ [ intros; apply (comp1 c o1 o2 o3 c1 c2);
+ | intros; unfold setoid2_of_setoid1 in e e1 a a' b b'; simplify in e e1 a a' b b';
+ change with ((b∘a) =_1 (b'∘a')); apply (e‡e1); ]
+ | intros; simplify; whd in a12 a23 a34; whd; apply rule (ASSOC);
+ | intros; simplify; whd in a; whd; apply id_neutral_right1;
+ | intros; simplify; whd in a; whd; apply id_neutral_left1; ]
+qed.
+(*coercion category2_of_category1.*)
+
+record functor2 (C1: category2) (C2: category2) : Type3 ≝
+ { map_objs2:1> C1 → C2;
+ map_arrows2: ∀S,T. unary_morphism2 (arrows2 ? S T) (arrows2 ? (map_objs2 S) (map_objs2 T));
+ respects_id2: ∀o:C1. map_arrows2 ?? (id2 ? o) = id2 ? (map_objs2 o);
+ respects_comp2:
+ ∀o1,o2,o3.∀f1:arrows2 ? o1 o2.∀f2:arrows2 ? o2 o3.
+ map_arrows2 ?? (f2 ∘ f1) = map_arrows2 ?? f2 ∘ map_arrows2 ?? f1}.
+
+notation > "F⎽⇒ x" left associative with precedence 60 for @{'map_arrows2 $F $x}.
+notation "F\sub⇒ x" left associative with precedence 60 for @{'map_arrows2 $F $x}.
+interpretation "map_arrows2" 'map_arrows2 F x = (fun12 ?? (map_arrows2 ?? F ??) x).
+
+definition functor2_setoid: category2 → category2 → setoid3.
+ intros (C1 C2);
+ constructor 1;
+ [ apply (functor2 C1 C2);
+ | constructor 1;
+ [ intros (f g);
+ apply (∀c:C1. cic:/matita/logic/equality/eq.ind#xpointer(1/1) ? (f c) (g c));
+ | simplify; intros; apply cic:/matita/logic/equality/eq.ind#xpointer(1/1/1);
+ | simplify; intros; apply cic:/matita/logic/equality/sym_eq.con; apply H;
+ | simplify; intros; apply cic:/matita/logic/equality/trans_eq.con;
+ [2: apply H; | skip | apply H1;]]]
+qed.
+
+definition functor2_of_functor2_setoid: ∀S,T. functor2_setoid S T → functor2 S T ≝ λS,T,x.x.
+coercion functor2_of_functor2_setoid.
+
+definition CAT2: category3.
+ constructor 1;
+ [ apply category2;
+ | apply functor2_setoid;
+ | intros; constructor 1;
+ [ apply (λx.x);
+ | intros; constructor 1;
+ [ apply (λx.x);
+ | intros; assumption;]
+ | intros; apply rule #;
+ | intros; apply rule #; ]
+ | intros; constructor 1;
+ [ intros; constructor 1;
+ [ intros; apply (c1 (c o));
+ | intros; constructor 1;
+ [ intro; apply (map_arrows2 ?? c1 ?? (map_arrows2 ?? c ?? c2));
+ | intros; apply (††e); ]
+ | intros; simplify;
+ apply (.= †(respects_id2 : ?));
+ apply (respects_id2 : ?);
+ | intros; simplify;
+ apply (.= †(respects_comp2 : ?));
+ apply (respects_comp2 : ?); ]
+ | intros; intro; simplify;
+ apply (cic:/matita/logic/equality/eq_ind.con ????? (e ?));
+ apply (cic:/matita/logic/equality/eq_ind.con ????? (e1 ?));
+ constructor 1; ]
+ | intros; intro; simplify; constructor 1;
+ | intros; intro; simplify; constructor 1;
+ | intros; intro; simplify; constructor 1; ]
+qed.
+
+definition category2_of_objs3_CAT2: objs3 CAT2 → category2 ≝ λx.x.
+coercion category2_of_objs3_CAT2.
+
+definition functor2_setoid_of_arrows3_CAT2: ∀S,T. arrows3 CAT2 S T → functor2_setoid S T ≝ λS,T,x.x.
+coercion functor2_setoid_of_arrows3_CAT2.
+
+notation > "B ⇒_\c3 C" right associative with precedence 72 for @{'arrows3_CAT $B $C}.
+notation "B ⇒\sub (\c 3) C" right associative with precedence 72 for @{'arrows3_CAT $B $C}.
+interpretation "'arrows3_CAT" 'arrows3_CAT A B = (arrows3 CAT2 A B).
+
+definition unary_morphism_setoid: setoid → setoid → setoid.
+ intros;
+ constructor 1;
+ [ apply (unary_morphism s s1);
+ | constructor 1;
+ [ intros (f g); apply (∀a:s. eq ? (f a) (g a));
+ | intros 1; simplify; intros; apply refl;
+ | simplify; intros; apply sym; apply f;
+ | simplify; intros; apply trans; [2: apply f; | skip | apply f1]]]
+qed.
+
+definition SET: category1.
+ constructor 1;
+ [ apply setoid;
+ | apply rule (λS,T:setoid.setoid1_of_setoid (unary_morphism_setoid S T));
+ | intros; constructor 1; [ apply (λx:carr o.x); | intros; assumption ]
+ | intros; constructor 1; [ intros; constructor 1; [ apply (λx. c1 (c x)); | intros;
+ apply († (†e));]
+ | intros; whd; intros; simplify; whd in H1; whd in H;
+ apply trans; [ apply (b (a' a1)); | lapply (prop1 ?? b (a a1) (a' a1));
+ [ apply Hletin | apply (e a1); ] | apply e1; ]]
+ | intros; whd; intros; simplify; apply refl;
+ | intros; simplify; whd; intros; simplify; apply refl;
+ | intros; simplify; whd; intros; simplify; apply refl;
+ ]
+qed.
+
+definition setoid_of_SET: objs1 SET → setoid ≝ λx.x.
+coercion setoid_of_SET.
+
+definition unary_morphism_setoid_of_arrows1_SET:
+ ∀P,Q.arrows1 SET P Q → unary_morphism_setoid P Q ≝ λP,Q,x.x.
+coercion unary_morphism_setoid_of_arrows1_SET.
+
+interpretation "'arrows1_SET" 'arrows1_SET A B = (arrows1 SET A B).
+
+definition unary_morphism1_setoid1: setoid1 → setoid1 → setoid1.
+ intros;
+ constructor 1;
+ [ apply (unary_morphism1 s s1);
+ | constructor 1;
+ [ intros (f g);
+ alias symbol "eq" = "setoid1 eq".
+ apply (∀a: carr1 s. f a = g a);
+ | intros 1; simplify; intros; apply refl1;
+ | simplify; intros; apply sym1; apply f;
+ | simplify; intros; apply trans1; [2: apply f; | skip | apply f1]]]
+qed.
+
+definition unary_morphism1_of_unary_morphism1_setoid1 :
+ ∀S,T. unary_morphism1_setoid1 S T → unary_morphism1 S T ≝ λP,Q,x.x.
+coercion unary_morphism1_of_unary_morphism1_setoid1.
+
+definition SET1: objs3 CAT2.
+ constructor 1;
+ [ apply setoid1;
+ | apply rule (λS,T.setoid2_of_setoid1 (unary_morphism1_setoid1 S T));
+ | intros; constructor 1; [ apply (λx.x); | intros; assumption ]
+ | intros; constructor 1; [ intros; constructor 1; [ apply (λx. c1 (c x)); | intros;
+ apply († (†e));]
+ | intros; whd; intros; simplify; whd in H1; whd in H;
+ apply trans1; [ apply (b (a' a1)); | lapply (prop11 ?? b (a a1) (a' a1));
+ [ apply Hletin | apply (e a1); ] | apply e1; ]]
+ | intros; whd; intros; simplify; apply refl1;
+ | intros; simplify; whd; intros; simplify; apply refl1;
+ | intros; simplify; whd; intros; simplify; apply refl1;
+ ]
+qed.
+
+interpretation "'arrows2_SET1" 'arrows2_SET1 A B = (arrows2 SET1 A B).
+
+definition setoid1_of_SET1: objs2 SET1 → setoid1 ≝ λx.x.
+coercion setoid1_of_SET1.
+
+definition unary_morphism1_setoid1_of_arrows2_SET1:
+ ∀P,Q.arrows2 SET1 P Q → unary_morphism1_setoid1 P Q ≝ λP,Q,x.x.
+coercion unary_morphism1_setoid1_of_arrows2_SET1.
+
+variant objs2_of_category1: objs1 SET → objs2 SET1 ≝ setoid1_of_setoid.
+coercion objs2_of_category1.
+
+prefer coercion Type_OF_setoid. (* we prefer the lower carrier projection *)
+prefer coercion Type_OF_objs1.
+
+alias symbol "exists" (instance 1) = "CProp2 exists".
+definition full2 ≝
+ λA,B:CAT2.λF:carr3 (arrows3 CAT2 A B).
+ ∀o1,o2:A.∀f.∃g:arrows2 A o1 o2.F⎽⇒ g =_2 f.
+alias symbol "exists" (instance 1) = "CProp exists".
+
+definition faithful2 ≝
+ λA,B:CAT2.λF:carr3 (arrows3 CAT2 A B).
+ ∀o1,o2:A.∀f,g:arrows2 A o1 o2.F⎽⇒ f =_2 F⎽⇒ g → f =_2 g.
+
+
+notation "r \sup *" non associative with precedence 90 for @{'OR_f_star $r}.
+notation > "r *" non associative with precedence 90 for @{'OR_f_star $r}.
+
+notation "r \sup (⎻* )" non associative with precedence 90 for @{'OR_f_minus_star $r}.
+notation > "r⎻*" non associative with precedence 90 for @{'OR_f_minus_star $r}.
+
+notation "r \sup ⎻" non associative with precedence 90 for @{'OR_f_minus $r}.
+notation > "r⎻" non associative with precedence 90 for @{'OR_f_minus $r}.