+nrecord ext_powerclass (A: setoid) : Type[1] ≝ {
+ ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
+ forse lo si vorrebbe dichiarato con un target più lasco
+ ma la sintassi :> non lo supporta *)
+ ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
+}.
+
+notation > "𝛀 ^ term 90 A" non associative with precedence 70
+for @{ 'ext_powerclass $A }.
+
+notation < "Ω term 90 A \atop ≈" non associative with precedence 90
+for @{ 'ext_powerclass $A }.
+
+interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
+
+ndefinition Full_set: ∀A. 𝛀^A.
+ #A; @[ napply A | #x; #x'; #H; napply refl1]
+nqed.
+ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
+
+ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
+ #A; @ [ napply (λS,S'. S = S') ] /2/.
+nqed.
+
+ndefinition ext_powerclass_setoid: setoid → setoid1.
+ #A; @ (ext_seteq A).
+nqed.
+
+unification hint 0 ≔ A;
+ R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
+ (* ----------------------------------------------------- *) ⊢
+ carr1 R ≡ ext_powerclass A.
+
+nlemma mem_ext_powerclass_setoid_is_morph:
+ ∀A. (setoid1_of_setoid A) ⇒_1 ((𝛀^A) ⇒_1 CPROP).
+#A; napply (mk_binary_morphism1 … (λx:setoid1_of_setoid A.λS: 𝛀^A. x ∈ S));
+#a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H
+[ napply (. (ext_prop … Ha^-1)) | napply (. (ext_prop … Ha)) ] /2/.
+nqed.
+
+unification hint 0 ≔ AA : setoid, S : 𝛀^AA, x : carr AA;
+ A ≟ carr AA,
+ SS ≟ (ext_carr ? S),
+ TT ≟ (mk_unary_morphism1 ??
+ (λx:carr1 (setoid1_of_setoid ?).
+ mk_unary_morphism1 ??
+ (λS:carr1 (ext_powerclass_setoid ?). x ∈ (ext_carr ? S))
+ (prop11 ?? (fun11 ?? (mem_ext_powerclass_setoid_is_morph AA) x)))
+ (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA))),
+ T2 ≟ (ext_powerclass_setoid AA)
+(*---------------------------------------------------------------------------*) ⊢
+ fun11 T2 CPROP (fun11 (setoid1_of_setoid AA) (unary_morphism1_setoid1 T2 CPROP) TT x) S ≡ mem A SS x.
+
+nlemma set_ext : ∀S.∀A,B:Ω^S.A =_1 B → ∀x:S.(x ∈ A) =_1 (x ∈ B).
+#S A B; *; #H1 H2 x; @; ##[ napply H1 | napply H2] nqed.
+
+nlemma ext_set : ∀S.∀A,B:Ω^S.(∀x:S. (x ∈ A) = (x ∈ B)) → A = B.
+#S A B H; @; #x; ncases (H x); #H1 H2; ##[ napply H1 | napply H2] nqed.
+
+nlemma subseteq_is_morph: ∀A. 𝛀^A ⇒_1 𝛀^A ⇒_1 CPROP.
+ #A; napply (mk_binary_morphism1 … (λS,S':𝛀^A. S ⊆ S'));
+ #a; #a'; #b; #b'; *; #H1; #H2; *; /5/ by mk_iff, sym1, subseteq_trans;
+nqed.
+
+(* hints for ∩ *)
+nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
+#S A B; @ (A ∩ B); #x y Exy; @; *; #H1 H2; @;
+##[##1,2: napply (. Exy^-1╪_1#); nassumption;
+##|##3,4: napply (. Exy‡#); nassumption]
+nqed.
+
+alias symbol "hint_decl" = "hint_decl_Type1".
+unification hint 0 ≔ A : setoid, B,C : 𝛀^A;
+ AA ≟ carr A,
+ BB ≟ ext_carr ? B,
+ CC ≟ ext_carr ? C,
+ R ≟ (mk_ext_powerclass ?
+ (ext_carr ? B ∩ ext_carr ? C)
+ (ext_prop ? (intersect_is_ext ? B C)))
+ (* ------------------------------------------*) ⊢
+ ext_carr A R ≡ intersect AA BB CC.
+
+nlemma intersect_is_morph: ∀A. Ω^A ⇒_1 Ω^A ⇒_1 Ω^A.
+#A; napply (mk_binary_morphism1 … (λS,S'. S ∩ S'));
+#a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *;/3/.
+nqed.
+
+alias symbol "hint_decl" = "hint_decl_Type1".
+unification hint 0 ≔ A : Type[0], B,C : Ω^A;
+ T ≟ powerclass_setoid A,
+ R ≟ mk_unary_morphism1 ??
+ (λX. mk_unary_morphism1 ??
+ (λY.X ∩ Y) (prop11 ?? (fun11 ?? (intersect_is_morph A) X)))
+ (prop11 ?? (intersect_is_morph A))
+(*------------------------------------------------------------------------*) ⊢
+ fun11 T T (fun11 T (unary_morphism1_setoid1 T T) R B) C ≡ intersect A B C.
+
+interpretation "prop21 ext" 'prop2 l r =
+ (prop11 (ext_powerclass_setoid ?)
+ (unary_morphism1_setoid1 (ext_powerclass_setoid ?) ?) ? ?? l ?? r).
+
+nlemma intersect_is_ext_morph: ∀A. 𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
+ #A; napply (mk_binary_morphism1 … (intersect_is_ext …));
+ #a; #a'; #b; #b'; #Ha; #Hb; napply (prop11 … (intersect_is_morph A)); nassumption.
+nqed.
+
+unification hint 1 ≔
+ AA : setoid, B,C : 𝛀^AA;
+ A ≟ carr AA,
+ T ≟ ext_powerclass_setoid AA,
+ R ≟ (mk_unary_morphism1 ?? (λX:𝛀^AA.
+ mk_unary_morphism1 ?? (λY:𝛀^AA.
+ mk_ext_powerclass AA
+ (ext_carr ? X ∩ ext_carr ? Y)
+ (ext_prop AA (intersect_is_ext ? X Y)))
+ (prop11 ?? (fun11 ?? (intersect_is_ext_morph AA) X)))
+ (prop11 ?? (intersect_is_ext_morph AA))) ,
+ BB ≟ (ext_carr ? B),
+ CC ≟ (ext_carr ? C)
+ (* ---------------------------------------------------------------------------------------*) ⊢
+ ext_carr AA (fun11 T T (fun11 T (unary_morphism1_setoid1 T T) R B) C) ≡ intersect A BB CC.
+
+
+(* hints for ∪ *)
+nlemma union_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
+#X; napply (mk_binary_morphism1 … (λA,B.A ∪ B));
+#A1 A2 B1 B2 EA EB; napply ext_set; #x;
+nchange in match (x ∈ (A1 ∪ B1)) with (?∨?);
+napply (.= (set_ext ??? EA x)‡#);
+napply (.= #‡(set_ext ??? EB x)); //;
+nqed.
+
+nlemma union_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
+ #S A B; @ (A ∪ B); #x y Exy; @; *; #H1;
+##[##1,3: @; ##|##*: @2 ]
+##[##1,3: napply (. (Exy^-1)╪_1#)
+##|##2,4: napply (. Exy╪_1#)]
+nassumption;
+nqed.
+
+alias symbol "hint_decl" = "hint_decl_Type1".
+unification hint 0 ≔ A : setoid, B,C : 𝛀^A;
+ AA ≟ carr A,
+ BB ≟ ext_carr ? B,
+ CC ≟ ext_carr ? C,
+ R ≟ mk_ext_powerclass ?
+ (ext_carr ? B ∪ ext_carr ? C) (ext_prop ? (union_is_ext ? B C))
+(*-------------------------------------------------------------------------*) ⊢
+ ext_carr A R ≡ union AA BB CC.
+
+unification hint 0 ≔ S:Type[0], A,B:Ω^S;
+ T ≟ powerclass_setoid S,
+ MM ≟ mk_unary_morphism1 ??
+ (λA.mk_unary_morphism1 ??
+ (λB.A ∪ B) (prop11 ?? (fun11 ?? (union_is_morph S) A)))
+ (prop11 ?? (union_is_morph S))
+(*--------------------------------------------------------------------------*) ⊢
+ fun11 T T (fun11 T (unary_morphism1_setoid1 T T) MM A) B ≡ A ∪ B.
+
+nlemma union_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
+#A; napply (mk_binary_morphism1 … (union_is_ext …));
+#x1 x2 y1 y2 Ex Ey; napply (prop11 … (union_is_morph A)); nassumption.
+nqed.
+
+unification hint 1 ≔
+ AA : setoid, B,C : 𝛀^AA;
+ A ≟ carr AA,
+ T ≟ ext_powerclass_setoid AA,
+ R ≟ mk_unary_morphism1 ?? (λX:𝛀^AA.
+ mk_unary_morphism1 ?? (λY:𝛀^AA.
+ mk_ext_powerclass AA
+ (ext_carr ? X ∪ ext_carr ? Y) (ext_prop AA (union_is_ext ? X Y)))
+ (prop11 ?? (fun11 ?? (union_is_ext_morph AA) X)))
+ (prop11 ?? (union_is_ext_morph AA)),
+ BB ≟ (ext_carr ? B),
+ CC ≟ (ext_carr ? C)
+(*------------------------------------------------------*) ⊢
+ ext_carr AA (fun11 T T (fun11 T (unary_morphism1_setoid1 T T) R B) C) ≡ union A BB CC.
+
+
+(* hints for - *)
+nlemma substract_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
+#X; napply (mk_binary_morphism1 … (λA,B.A - B));
+#A1 A2 B1 B2 EA EB; napply ext_set; #x;
+nchange in match (x ∈ (A1 - B1)) with (?∧?);
+napply (.= (set_ext ??? EA x)‡#); @; *; #H H1; @; //; #H2; napply H1;
+##[ napply (. (set_ext ??? EB x)); ##| napply (. (set_ext ??? EB^-1 x)); ##] //;
+nqed.
+
+nlemma substract_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
+ #S A B; @ (A - B); #x y Exy; @; *; #H1 H2; @; ##[##2,4: #H3; napply H2]
+##[##1,4: napply (. Exy╪_1#); // ##|##2,3: napply (. Exy^-1╪_1#); //]
+nqed.
+
+alias symbol "hint_decl" = "hint_decl_Type1".
+unification hint 0 ≔ A : setoid, B,C : 𝛀^A;
+ AA ≟ carr A,
+ BB ≟ ext_carr ? B,
+ CC ≟ ext_carr ? C,
+ R ≟ mk_ext_powerclass ?
+ (ext_carr ? B - ext_carr ? C)
+ (ext_prop ? (substract_is_ext ? B C))
+(*---------------------------------------------------*) ⊢
+ ext_carr A R ≡ substract AA BB CC.
+
+unification hint 0 ≔ S:Type[0], A,B:Ω^S;
+ T ≟ powerclass_setoid S,
+ MM ≟ mk_unary_morphism1 ??
+ (λA.mk_unary_morphism1 ??
+ (λB.A - B) (prop11 ?? (fun11 ?? (substract_is_morph S) A)))
+ (prop11 ?? (substract_is_morph S))
+(*--------------------------------------------------------------------------*) ⊢
+ fun11 T T (fun11 T (unary_morphism1_setoid1 T T) MM A) B ≡ A - B.
+
+nlemma substract_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
+#A; napply (mk_binary_morphism1 … (substract_is_ext …));
+#x1 x2 y1 y2 Ex Ey; napply (prop11 … (substract_is_morph A)); nassumption.
+nqed.
+
+unification hint 1 ≔
+ AA : setoid, B,C : 𝛀^AA;
+ A ≟ carr AA,
+ T ≟ ext_powerclass_setoid AA,
+ R ≟ mk_unary_morphism1 ?? (λX:𝛀^AA.
+ mk_unary_morphism1 ?? (λY:𝛀^AA.
+ mk_ext_powerclass AA
+ (ext_carr ? X - ext_carr ? Y)
+ (ext_prop AA (substract_is_ext ? X Y)))
+ (prop11 ?? (fun11 ?? (substract_is_ext_morph AA) X)))
+ (prop11 ?? (substract_is_ext_morph AA)),
+ BB ≟ (ext_carr ? B),
+ CC ≟ (ext_carr ? C)
+(*------------------------------------------------------*) ⊢
+ ext_carr AA (fun11 T T (fun11 T (unary_morphism1_setoid1 T T) R B) C) ≡ substract A BB CC.
+
+(* hints for {x} *)
+nlemma single_is_morph : ∀A:setoid. (setoid1_of_setoid A) ⇒_1 Ω^A.
+#X; @; ##[ napply (λx.{(x)}); ##]
+#a b E; napply ext_set; #x; @; #H; /3/; nqed.
+
+nlemma single_is_ext: ∀A:setoid. A → 𝛀^A.
+#X a; @; ##[ napply ({(a)}); ##] #x y E; @; #H; /3/; nqed.
+
+alias symbol "hint_decl" = "hint_decl_Type1".
+unification hint 0 ≔ A : setoid, a : carr A;
+ R ≟ (mk_ext_powerclass ? {(a)} (ext_prop ? (single_is_ext ? a)))
+(*-------------------------------------------------------------------------*) ⊢
+ ext_carr A R ≡ singleton A a.
+
+unification hint 0 ≔ A:setoid, a : carr A;
+ T ≟ setoid1_of_setoid A,
+ AA ≟ carr A,
+ MM ≟ mk_unary_morphism1 ??
+ (λa:carr1 (setoid1_of_setoid A).{(a)}) (prop11 ?? (single_is_morph A))
+(*--------------------------------------------------------------------------*) ⊢
+ fun11 T (powerclass_setoid AA) MM a ≡ {(a)}.
+
+nlemma single_is_ext_morph:∀A:setoid.(setoid1_of_setoid A) ⇒_1 𝛀^A.
+#A; @; ##[ #a; napply (single_is_ext ? a); ##] #a b E; @; #x; /3/; nqed.
+
+unification hint 1 ≔ AA : setoid, a: carr AA;
+ T ≟ ext_powerclass_setoid AA,
+ R ≟ mk_unary_morphism1 ??
+ (λa:carr1 (setoid1_of_setoid AA).
+ mk_ext_powerclass AA {(a)} (ext_prop ? (single_is_ext AA a)))
+ (prop11 ?? (single_is_ext_morph AA))
+(*------------------------------------------------------*) ⊢
+ ext_carr AA (fun11 (setoid1_of_setoid AA) T R a) ≡ singleton AA a.