+<?xml version="1.0"?>
+
+<xsl:stylesheet version="1.0"
+ xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+<xsl:import href="common.xsl"/>
+
+<xsl:output method="xml"/>
+
+<xsl:template match="/">
+ <html>
+ <head>
+ <title>
+ <xsl:text>Summary of </xsl:text>
+ <xsl:value-of select="minutes/about"/>
+ </title>
+ </head>
+ <body>
+ <h1>Summary of <xsl:value-of select="minutes/about"/></h1>
+ <h2>Participants:</h2>
+ <ul>
+ <xsl:apply-templates select="minutes/participant">
+ <xsl:sort select="document(concat('../xml/people/',@site,'/',@file,'.xml'))/*/surname"/>
+ </xsl:apply-templates>
+ </ul>
+ <h2>Presentations:</h2>
+ <dl>
+ <xsl:apply-templates select="minutes/presentation"/>
+ </dl>
+ <h2>Minutes:</h2>
+ <p>
+ <span style="font-weight: bold">Note:</span>
+ The following entries reports only the important observations raised during
+ the meeting and the decisions taken.
+ </p>
+ <ul>
+ <xsl:apply-templates select="minutes/entry"/>
+ </ul>
+ </body>
+ </html>
+</xsl:template>
+
+<xsl:template match="entry">
+ <li>
+ <xsl:if test="@author">
+ <xsl:text>[</xsl:text>
+ <a href="../people/{@author}.html">
+ <xsl:call-template name="person-name">
+ <xsl:with-param name="file" select="@author"/>
+ </xsl:call-template>
+ </a>
+ <xsl:text>]</xsl:text>
+ </xsl:if>
+ <xsl:apply-templates/>
+ </li>
+</xsl:template>
+
+<xsl:template match="participant">
+ <li>
+ <a href="../people/{@site}/{@file}.html">
+ <xsl:call-template name="person-name">
+ <xsl:with-param name="file" select="concat(@site,'/',@file)"/>
+ </xsl:call-template>
+ </a>
+ <xsl:text>  (</xsl:text>
+ <a href="../sites/{@site}.html">
+ <xsl:value-of select="@site"/>
+ </a>
+ <xsl:text>)</xsl:text>
+ </li>
+</xsl:template>
+
+<xsl:template match="presentation">
+ <dt>
+ <a href="../people/{@site}/{@author}.html">
+ <xsl:call-template name="person-name">
+ <xsl:with-param name="file" select="concat(@site,'/',@author)"/>
+ </xsl:call-template>
+ </a>
+ <xsl:text> (</xsl:text>
+ <a href="../sites/{@site}.html">
+ <xsl:value-of select="@site"/>
+ </a>
+ <xsl:text>): </xsl:text>
+ <xsl:if test="@media = 'slides'">
+ <xsl:choose>
+ <xsl:when test="slides">
+ <xsl:for-each select="slides">
+ <xsl:text>[</xsl:text>
+ <xsl:variable name="location">
+ <xsl:choose>
+ <xsl:when test="@format = 'HTML'">
+ <xsl:value-of select="concat('../slides/',@file)"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="concat('../../misc/',@file)"/>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:variable>
+ <a href="{$location}">
+ <xsl:text>Get the slides</xsl:text>
+ <xsl:if test="text()">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="text()"/>
+ </xsl:if>
+ </a>
+ <xsl:text>]</xsl:text>
+ </xsl:for-each>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>[slides unavailable]</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:if>
+ </dt>
+ <dd>
+ <xsl:copy-of select="description/*|description/text()"/>
+ </dd>
+</xsl:template>
+
+</xsl:stylesheet>