+(* Advanced inversion lemmas ************************************************)
+
+lemma sor_inv_ppn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
+#g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
+elim (sor_inv_ppx … H … H1 H2) -g1 -g2 #x #_ #H destruct
+/2 width=3 by discr_push_next/
+qed-.
+
+lemma sor_inv_nxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f. ↑f1 = g1 → ⫯f = g → ⊥.
+#g1 #g2 #g #H #f1 #f #H1 #H0
+elim (pn_split g2) * #f2 #H2
+[ elim (sor_inv_npx … H … H1 H2)
+| elim (sor_inv_nnx … H … H1 H2)
+] -g1 -g2 #x #_ #H destruct
+/2 width=3 by discr_next_push/
+qed-.
+
+lemma sor_inv_xnp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f2,f. ↑f2 = g2 → ⫯f = g → ⊥.
+#g1 #g2 #g #H #f2 #f #H2 #H0
+elim (pn_split g1) * #f1 #H1
+[ elim (sor_inv_pnx … H … H1 H2)
+| elim (sor_inv_nnx … H … H1 H2)
+] -g1 -g2 #x #_ #H destruct
+/2 width=3 by discr_next_push/
+qed-.
+
+lemma sor_inv_ppp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⋓ f2 ≘ f.
+#g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
+elim (sor_inv_ppx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
+<(injective_push … H) -f //
+qed-.
+
+lemma sor_inv_npn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
+#g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
+elim (sor_inv_npx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
+<(injective_next … H) -f //
+qed-.
+
+lemma sor_inv_pnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
+#g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
+elim (sor_inv_pnx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
+<(injective_next … H) -f //
+qed-.
+
+lemma sor_inv_nnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
+#g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
+elim (sor_inv_nnx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
+<(injective_next … H) -f //
+qed-.
+
+lemma sor_inv_pxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f. ⫯f1 = g1 → ⫯f = g →
+ ∃∃f2. f1 ⋓ f2 ≘ f & ⫯f2 = g2.
+#g1 #g2 #g #H #f1 #f #H1 #H0
+elim (pn_split g2) * #f2 #H2
+[ /3 width=7 by sor_inv_ppp, ex2_intro/
+| elim (sor_inv_xnp … H … H2 H0)
+]
+qed-.
+
+lemma sor_inv_xpp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f2,f. ⫯f2 = g2 → ⫯f = g →
+ ∃∃f1. f1 ⋓ f2 ≘ f & ⫯f1 = g1.
+#g1 #g2 #g #H #f2 #f #H2 #H0
+elim (pn_split g1) * #f1 #H1
+[ /3 width=7 by sor_inv_ppp, ex2_intro/
+| elim (sor_inv_nxp … H … H1 H0)
+]
+qed-.
+
+lemma sor_inv_pxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f. ⫯f1 = g1 → ↑f = g →
+ ∃∃f2. f1 ⋓ f2 ≘ f & ↑f2 = g2.
+#g1 #g2 #g #H #f1 #f #H1 #H0
+elim (pn_split g2) * #f2 #H2
+[ elim (sor_inv_ppn … H … H1 H2 H0)
+| /3 width=7 by sor_inv_pnn, ex2_intro/
+]
+qed-.
+
+lemma sor_inv_xpn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f2,f. ⫯f2 = g2 → ↑f = g →
+ ∃∃f1. f1 ⋓ f2 ≘ f & ↑f1 = g1.
+#g1 #g2 #g #H #f2 #f #H2 #H0
+elim (pn_split g1) * #f1 #H1
+[ elim (sor_inv_ppn … H … H1 H2 H0)
+| /3 width=7 by sor_inv_npn, ex2_intro/
+]
+qed-.
+
+lemma sor_inv_xxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f. ⫯f = g →
+ ∃∃f1,f2. f1 ⋓ f2 ≘ f & ⫯f1 = g1 & ⫯f2 = g2.
+#g1 #g2 #g #H #f #H0
+elim (pn_split g1) * #f1 #H1
+[ elim (sor_inv_pxp … H … H1 H0) -g /2 width=5 by ex3_2_intro/
+| elim (sor_inv_nxp … H … H1 H0)
+]
+qed-.
+
+lemma sor_inv_nxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f1,f. ↑f1 = g1 → ↑f = g →
+ (∃∃f2. f1 ⋓ f2 ≘ f & ⫯f2 = g2) ∨
+ ∃∃f2. f1 ⋓ f2 ≘ f & ↑f2 = g2.
+#g1 #g2 elim (pn_split g2) *
+/4 width=7 by sor_inv_npn, sor_inv_nnn, ex2_intro, or_intror, or_introl/
+qed-.
+
+lemma sor_inv_xnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
+ ∀f2,f. ↑f2 = g2 → ↑f = g →
+ (∃∃f1. f1 ⋓ f2 ≘ f & ⫯f1 = g1) ∨
+ ∃∃f1. f1 ⋓ f2 ≘ f & ↑f1 = g1.
+#g1 elim (pn_split g1) *
+/4 width=7 by sor_inv_pnn, sor_inv_nnn, ex2_intro, or_intror, or_introl/
+qed-.
+
+lemma sor_inv_xxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f. ↑f = g →
+ ∨∨ ∃∃f1,f2. f1 ⋓ f2 ≘ f & ↑f1 = g1 & ⫯f2 = g2
+ | ∃∃f1,f2. f1 ⋓ f2 ≘ f & ⫯f1 = g1 & ↑f2 = g2
+ | ∃∃f1,f2. f1 ⋓ f2 ≘ f & ↑f1 = g1 & ↑f2 = g2.
+#g1 #g2 #g #H #f #H0
+elim (pn_split g1) * #f1 #H1
+[ elim (sor_inv_pxn … H … H1 H0) -g
+ /3 width=5 by or3_intro1, ex3_2_intro/
+| elim (sor_inv_nxn … H … H1 H0) -g *
+ /3 width=5 by or3_intro0, or3_intro2, ex3_2_intro/
+]
+qed-.
+