+lemma tpr_conf_delta_delta:
+ ∀V0,V1,T0,T1,TT1,V2,T2,TT2. (
+ ∀X0:term. #X0 < #V0 +#T0 + 1→
+ ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
+ ∃∃X. X1 ⇒ X & X2 ⇒ X
+ ) →
+ V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
+ ⋆. 𝕓{Abbr} V1 ⊢ T1 [O, 1] ≫ TT1 →
+ ⋆. 𝕓{Abbr} V2 ⊢ T2 [O, 1] ≫ TT2 →
+ ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & 𝕓{Abbr} V2. TT2 ⇒ X.
+#V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
+elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
+elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
+elim (tpr_ps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
+elim (tpr_ps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
+elim (ps_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
+@ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
+qed.
+
+lemma tpr_conf_delta_zeta:
+ ∀X2,V0,V1,T0,T1,TT1,T2. (
+ ∀X0:term. #X0 < #V0 +#T0 + 1→
+ ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
+ ∃∃X. X1 ⇒ X & X2 ⇒ X
+ ) →
+ V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
+ T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
+ ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
+#X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
+elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
+lapply (ps_inv_lift_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
+lapply (tw_lift … HTT20) -HTT20 #HTT20
+elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
+qed.
+
+lemma tpr_conf_theta_theta:
+ ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
+ ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
+ ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
+ ∃∃X. X1 ⇒ X & X2 ⇒ X
+ ) →
+ V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
+ ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
+ ∃∃X. 𝕓{Abbr} W1. 𝕗{Appl} VV1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} VV2. T2 ⇒ X.
+#VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
+elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
+elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
+elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
+elim (lift_total V 0 1) #VV #HVV
+lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
+lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
+@ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
+qed.
+
+lemma tpr_conf_zeta_zeta:
+ ∀V0:term. ∀X2,TT0,T0,T1,T2. (
+ ∀X0:term. #X0 < #V0 + #TT0 + 1 →
+ ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
+ ∃∃X. X1 ⇒ X & X2 ⇒ X
+ ) →
+ T0 ⇒ T1 → T2 ⇒ X2 →
+ ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
+ ∃∃X. T1 ⇒ X & X2 ⇒ X.
+#V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
+lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
+lapply (tw_lift … HTT20) -HTT20 #HTT20
+elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
+qed.
+
+lemma tpr_conf_tau_tau:
+ ∀V0,T0:term. ∀X2,T1. (
+ ∀X0:term. #X0 < #V0 + #T0 + 1 →
+ ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
+ ∃∃X. X1 ⇒ X & X2 ⇒ X
+ ) →
+ T0 ⇒ T1 → T0 ⇒ X2 →
+ ∃∃X. T1 ⇒ X & X2 ⇒ X.
+#V0 #T0 #X2 #T1 #IH #HT01 #HT02
+elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
+qed.
+