+ ≝ λsig,M,q.〈q,bin0,None ?,FS_crd sig〉./2 by lt_S_to_lt/ qed.
+
+lemma lift_halt_binaryTM :
+ ∀sig,M,q.halt sig M q = halt ? (mk_binaryTM sig M) (state_bin_lift ? M q).
+// qed.
+
+lemma binaryTM_bin0_bin1 :
+ ∀sig,M,t,q,ch.
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin0,ch,O〉) t)
+ = mk_config ?? (〈q,bin1,ch,to_initN (FS_crd sig) ??〉) t. //
+qed.
+
+lemma binaryTM_bin0_bin2 :
+ ∀sig,M,t,q,ch,k,qn,mv.
+ current ? t = None ? → S k <S (2*FS_crd sig) →
+ 〈qn,None ?,mv〉 = trans sig M 〈q,None ?〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin0,ch,S k〉) t)
+ = mk_config ?? (〈q,bin2,None ?,to_initN O ??〉) t. [2,3:/2 by transitive_lt/]
+#sig #M #t #q #ch #k #qn #mv #Hcur #Hk #Htrans
+whd in match (step ???); whd in match (trans ???);
+>Hcur <Htrans %
+qed.
+
+lemma binaryTM_bin0_bin4 :
+ ∀sig,M,t,q,ch,k,qn,chn,mv.
+ current ? t = None ? → S k <S (2*FS_crd sig) →
+ 〈qn,Some ? chn,mv〉 = trans sig M 〈q,None ?〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin0,ch,S k〉) t)
+ = mk_config ?? (〈q,bin4,None ?,to_initN 0 ??〉) (tape_move ? t R). [2,3:/2 by transitive_lt/]
+#sig #M #t #q #ch #k #qn #chn #mv #Hcur #Hk #Htrans
+whd in match (step ???); whd in match (trans ???);
+>Hcur <Htrans %
+qed.
+
+lemma binaryTM_bin0_true :
+ ∀sig,M,t,q,ch,k.
+ current ? t = Some ? true → S k <S (2*FS_crd sig) →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin0,ch,S k〉) t)
+ = mk_config ?? (〈q,bin0,FS_nth sig k,to_initN k ??〉) (tape_move ? t R).[2,3:@le_S /2 by lt_S_to_lt/]
+#sig #M #t #q #ch #k #Hcur #Hk
+whd in match (step ???); whd in match (trans ???);
+>Hcur %
+qed.
+
+lemma binaryTM_bin0_false :
+ ∀sig,M,t,q,ch,k.
+ current ? t = Some ? false → S k <S (2*FS_crd sig) →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin0,ch,S k〉) t)
+ = mk_config ?? (〈q,bin0,ch,to_initN k ??〉) (tape_move ? t R).[2,3:@le_S /2 by lt_S_to_lt/]
+#sig #M #t #q #ch #k #Hcur #Hk
+whd in match (step ???); whd in match (trans ???);
+>Hcur %
+qed.
+
+(* to be checked *)
+axiom binary_to_bin_char :∀sig,csl,csr,a.
+ csl@true::csr=bin_char sig a → FS_nth ? (length ? csr) = Some ? a.
+
+lemma binaryTM_phase0_midtape_aux :
+ ∀sig,M,q,ls,a,rs,k.
+ halt sig M q=false →
+ ∀csr,csl,t,ch.length ? csr < S (2*FS_crd sig) →
+ t = mk_tape ? (reverse ? csl@ls) (option_hd ? (csr@rs)) (tail ? (csr@rs)) →
+ csl@csr = bin_char sig a →
+ |csl@csr| = FS_crd sig →
+ (index_of_FS ? a < |csl| → ch = Some ? a) →
+ loopM ? (mk_binaryTM sig M) (S (length ? csr) + k)
+ (mk_config ?? (〈q,bin0,ch,length ? csr〉) t)
+ = loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin1,Some ? a,FS_crd sig〉)
+ (mk_tape ? (reverse ? (bin_char ? a)@ls) (option_hd ? rs) (tail ? rs))). [2,3:@le_S /2 by O/]
+#sig #M #q #ls #a #rs #k #Hhalt #csr elim csr
+[ #csl #t #ch #Hlen #Ht >append_nil #Hcsl #Hlencsl #Hch >loopM_unfold >loop_S_false [|normalize //]
+ >Hch [| >Hlencsl (* lemmatize *) @daemon]
+ <loopM_unfold @eq_f >binaryTM_bin0_bin1 @eq_f >Ht
+ whd in match (step ???); whd in match (trans ???); <Hcsl %
+| #c cases c
+ [ #csr0 #IH #csl #t #ch #Hlen #Ht #Heq #Hcrd #Hch >loopM_unfold >loop_S_false [|normalize //]
+ <loopM_unfold lapply (binary_to_bin_char … Heq) #Ha >binaryTM_bin0_true
+ [| >Ht % ]
+ lapply (IH (csl@[true]) (tape_move FinBool t R) ??????)
+ [ //
+ | >associative_append @Hcrd
+ | >associative_append @Heq
+ | >Ht whd in match (option_hd ??) in ⊢ (??%?); whd in match (tail ??) in ⊢ (??%?);
+ cases csr0
+ [ cases rs
+ [ normalize >rev_append_def >rev_append_def >reverse_append %
+ | #r1 #rs1 normalize >rev_append_def >rev_append_def >reverse_append % ]
+ | #c1 #csr1 normalize >rev_append_def >rev_append_def >reverse_append % ]
+ | /2 by lt_S_to_lt/
+ |]
+ #H whd in match (plus ??); >H @eq_f @eq_f2 %
+ | #csr0 #IH #csl #t #ch #Hlen #Ht #Heq #Hcrd #Hch >loopM_unfold >loop_S_false [|normalize //]
+ <loopM_unfold >binaryTM_bin0_false [| >Ht % ]
+ lapply (IH (csl@[false]) (tape_move FinBool t R) ??????)
+ [6: @ch
+ | (* by cases: if index < |csl|, then Hch, else False *)
+ @daemon
+ | >associative_append @Hcrd
+ | >associative_append @Heq
+ | >Ht whd in match (option_hd ??) in ⊢ (??%?); whd in match (tail ??) in ⊢ (??%?);
+ cases csr0
+ [ cases rs
+ [ normalize >rev_append_def >rev_append_def >reverse_append %
+ | #r1 #rs1 normalize >rev_append_def >rev_append_def >reverse_append % ]
+ | #c1 #csr1 normalize >rev_append_def >rev_append_def >reverse_append % ]
+ | /2 by lt_S_to_lt/
+ |]
+ #H whd in match (plus ??); >H @eq_f @eq_f2 %
+ ]
+]
+qed.
+
+lemma le_to_eq : ∀m,n.m ≤ n → ∃k. n = m + k. /3 by plus_minus, ex_intro/
+qed.
+
+lemma minus_tech : ∀a,b.a + b - a = b. // qed.
+
+lemma binaryTM_phase0_midtape :
+ ∀sig,M,t,q,ls,a,rs,ch,k.
+ halt sig M q=false → S (FS_crd sig) ≤ k →
+ t = mk_tape ? ls (option_hd ? (bin_char ? a)) (tail ? (bin_char sig a)@rs) →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin0,ch,FS_crd sig〉) t)
+ = loopM ? (mk_binaryTM sig M) (k - S (FS_crd sig))
+ (mk_config ?? (〈q,bin1,Some ? a,FS_crd sig〉)
+ (mk_tape ? (reverse ? (bin_char ? a)@ls) (option_hd ? rs) (tail ? rs))). [|*:@le_S //]
+#sig #M #t #q #ls #a #rs #ch #k #Hhalt #Hk #Ht
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+cut (∃c,cl.bin_char sig a = c::cl) [@daemon] * #c * #cl #Ha >Ha
+cut (FS_crd sig = |bin_char sig a|) [@daemon] #Hlen
+@(trans_eq ?? (loopM ? (mk_binaryTM ? M) (S (|c::cl|) + k0)
+ (mk_config ?? 〈q,bin0,〈ch,|c::cl|〉〉 t)))
+[ /2 by O/ | @eq_f2 // @eq_f2 // @eq_f <Ha >Hlen % ]
+>(binaryTM_phase0_midtape_aux ? M q ls a rs ? ? (c::cl) [ ] t ch) //
+[| normalize #Hfalse @False_ind cases (not_le_Sn_O ?) /2/
+| <Ha (* |bin_char sig ?| = FS_crd sig *) @daemon
+| >Ha %
+| >Ht >Ha %
+| <Ha <Hlen // ]
+<Ha %
+qed.
+
+lemma binaryTM_phase0_None_None :
+ ∀sig,M,t,q,ch,k,n,qn,mv.
+ O < n → n < 2*FS_crd sig → O < k →
+ halt sig M q=false →
+ current ? t = None ? →
+ 〈qn,None ?,mv〉 = trans sig M 〈q,None ?〉 →
+ loopM ? (mk_binaryTM sig M) k (mk_config ?? (〈q,bin0,ch,n〉) t)
+ = loopM ? (mk_binaryTM sig M) (k-1)
+ (mk_config ?? (〈q,bin2,None ?,to_initN O ??〉) t). [2,3: /2 by transitive_lt/ ]
+#sig #M #t #q #ch #k #n #qn #mv #HOn #Hn #Hk #Hhalt
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+cases (le_to_eq … HOn) #n0 #Hn0 destruct (Hn0)
+cases t
+[ >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin2 // /2 by refl, transitive_lt/
+| #r0 #rs0 >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin2 // /2 by refl, transitive_lt/
+| #l0 #ls0 >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin2 // /2 by refl, transitive_lt/
+| #ls #cur #rs normalize in ⊢ (%→?); #H destruct (H) ]
+qed.
+
+lemma binaryTM_phase0_None_Some :
+ ∀sig,M,t,q,ch,k,n,qn,chn,mv.
+ O < n → n < 2*FS_crd sig → O < k →
+ halt sig M q=false →
+ current ? t = None ? →
+ 〈qn,Some ? chn,mv〉 = trans sig M 〈q,None ?〉 →
+ loopM ? (mk_binaryTM sig M) k (mk_config ?? (〈q,bin0,ch,n〉) t)
+ = loopM ? (mk_binaryTM sig M) (k-1)
+ (mk_config ?? (〈q,bin4,None ?,to_initN O ??〉) (tape_move ? t R)). [2,3: /2 by transitive_lt/ ]
+#sig #M #t #q #ch #k #n #qn #chn #mv #HOn #Hn #Hk #Hhalt
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+cases (le_to_eq … HOn) #n0 #Hn0 destruct (Hn0)
+cases t
+[ >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin4 // /2 by refl, transitive_lt/
+| #r0 #rs0 >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin4 // /2 by refl, transitive_lt/
+| #l0 #ls0 >loopM_unfold >loop_S_false [|@Hhalt] #Hcur #Htrans >binaryTM_bin0_bin4 // /2 by refl, transitive_lt/
+| #ls #cur #rs normalize in ⊢ (%→?); #H destruct (H) ]
+qed.
+
+lemma binaryTM_bin1_O :
+ ∀sig,M,t,q,ch.
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin1,ch,O〉) t)
+ = mk_config ?? (〈q,bin2,ch,to_initN (FS_crd sig) ??〉) t. [2,3:/2 by lt_S_to_lt/]
+#sig #M #t #q #ch %
+qed.
+
+lemma binaryTM_bin1_S :
+ ∀sig,M,t,q,ch,k. S k <S (2*FS_crd sig) →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin1,ch,S k〉) t)
+ = mk_config ?? (〈q,bin1,ch,to_initN k ??〉) (tape_move ? t L). [2,3:@le_S /2 by lt_S_to_lt/]
+#sig #M #t #q #ch #k #HSk %
+qed.
+
+lemma binaryTM_phase1 :
+ ∀sig,M,q,ls1,ls2,cur,rs,ch,k.
+ S (FS_crd sig) ≤ k → |ls1| = FS_crd sig → (cur = None ? → rs = [ ]) →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin1,ch,FS_crd sig〉) (mk_tape ? (ls1@ls2) cur rs))
+ = loopM ? (mk_binaryTM sig M) (k - S (FS_crd sig))
+ (mk_config ?? (〈q,bin2,ch,FS_crd sig〉)
+ (mk_tape ? ls2 (option_hd ? (reverse ? ls1@option_cons ? cur rs))
+ (tail ? (reverse ? ls1@option_cons ? cur rs)))). [2,3:/2 by O/]
+cut (∀sig,M,q,ls1,ls2,ch,k,n,cur,rs.
+ |ls1| = n → n<S (2*FS_crd sig) → (cur = None ? → rs = [ ]) →
+ loopM ? (mk_binaryTM sig M) (S n + k)
+ (mk_config ?? (〈q,bin1,ch,n〉) (mk_tape ? (ls1@ls2) cur rs))
+ = loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin2,ch,FS_crd sig〉)
+ (mk_tape ? ls2 (option_hd ? (reverse ? ls1@option_cons ? cur rs))
+ (tail ? (reverse ? ls1@option_cons ? cur rs))))) [1,2:@le_S //]
+[ #sig #M #q #ls1 #ls2 #ch #k elim ls1
+ [ #n normalize in ⊢ (%→?); #cur #rs #Hn <Hn #Hcrd #Hcur >loopM_unfold >loop_S_false [| % ]
+ >binaryTM_bin1_O cases cur in Hcur;
+ [ #H >(H (refl ??)) -H %
+ | #cur' #_ % ]
+ | #l0 #ls0 #IH * [ #cur #rs normalize in ⊢ (%→?); #H destruct (H) ]
+ #n #cur #rs normalize in ⊢ (%→?); #H destruct (H) #Hlt #Hcur
+ >loopM_unfold >loop_S_false [|%] >binaryTM_bin1_S
+ <(?:mk_tape ? (ls0@ls2) (Some ? l0) (option_cons ? cur rs) =
+ tape_move FinBool (mk_tape FinBool ((l0::ls0)@ls2) cur rs) L)
+ [| cases cur in Hcur; [ #H >(H ?) // | #cur' #_ % ] ]
+ >(?:loop (config FinBool (states FinBool (mk_binaryTM sig M))) (S (|ls0|)+k)
+ (step FinBool (mk_binaryTM sig M))
+ (λc:config FinBool (states FinBool (mk_binaryTM sig M))
+ .halt FinBool (mk_binaryTM sig M)
+ (cstate FinBool (states FinBool (mk_binaryTM sig M)) c))
+ (mk_config FinBool (states FinBool (mk_binaryTM sig M))
+ 〈q,bin1,ch,to_initN (|ls0|) ?
+ (le_S ?? (lt_S_to_lt (|ls0|) (S (2*FS_crd sig)) Hlt))〉
+ (mk_tape FinBool (ls0@ls2) (Some FinBool l0) (option_cons FinBool cur rs)))
+ = loopM FinBool (mk_binaryTM sig M) k
+ (mk_config FinBool (states FinBool (mk_binaryTM sig M))
+ 〈q,bin2,〈ch,FS_crd sig〉〉
+ (mk_tape FinBool ls2
+ (option_hd FinBool (reverse FinBool ls0@l0::option_cons FinBool cur rs))
+ (tail FinBool (reverse FinBool ls0@l0::option_cons FinBool cur rs)))))
+ [| /2/
+ | >(?: l0::option_cons ? cur rs = option_cons ? (Some ? l0) (option_cons ? cur rs)) [| % ]
+ @trans_eq [|| @(IH ??? (refl ??)) [ /2 by lt_S_to_lt/ | #H destruct (H) ] ]
+ %
+ ]
+ >reverse_cons >associative_append %
+ ]
+| #Hcut #sig #M #q #ls1 #ls2 #cur #rs #ch #k #Hk #Hlen
+ cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech @Hcut // ]
+qed.
+
+lemma binaryTM_bin2_O :
+ ∀sig,M,t,q,qn,ch,chn,mv.
+ 〈qn,chn,mv〉 = trans sig M 〈q,ch〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin2,ch,O〉) t)
+ = mk_config ?? (〈qn,bin3,ch,to_initN (displ_of_move sig mv) ??〉) t.[2,3:/2 by lt_S_to_lt,le_S_S/]
+#sig #M #t #q #qn #ch #chn #mv #Htrans
+whd in match (step ???); whd in match (trans ???); <Htrans %
+qed.
+
+lemma binaryTM_bin2_S_None :
+ ∀sig,M,t,q,qn,ch,mv,k.
+ k < S (2*FS_crd sig) →
+ 〈qn,None ?,mv〉 = trans sig M 〈q,ch〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin2,ch,S k〉) t)
+ = mk_config ?? (〈q,bin2,ch,k〉) (tape_move ? t R).
+[2,3: @le_S_S /2 by lt_to_le/ ]
+#sig #M #t #q #qn #ch #mv #k #Hk #Htrans
+whd in match (step ???); whd in match (trans ???); <Htrans %
+qed.
+
+lemma binaryTM_bin2_S_Some :
+ ∀sig,M,t,q,qn,ch,chn,mv,k.
+ k< S (2*FS_crd sig) →
+ 〈qn,Some ? chn,mv〉 = trans sig M 〈q,ch〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin2,ch,S k〉) t)
+ = mk_config ?? (〈q,bin2,ch,k〉) (tape_move ? (tape_write ? t (Some ? (FS_nth ? k == Some ? chn))) R).
+[2,3: @le_S_S /2 by lt_to_le/ ]
+#sig #M #t #q #qn #ch #chn #mv #k #Hk #Htrans
+whd in match (step ???); whd in match (trans ???); <Htrans %
+qed.
+
+let rec iter (T:Type[0]) f n (t:T) on n ≝
+ match n with [ O ⇒ t | S n0 ⇒ iter T f n0 (f t) ].
+
+lemma binaryTM_phase2_None :∀sig,M,q,ch,qn,mv,k,n. S n ≤ k →
+ ∀t.n≤S (2*FS_crd sig) →
+ 〈qn,None ?,mv〉 = trans sig M 〈q,ch〉 →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin2,ch,n〉) t)
+ = loopM ? (mk_binaryTM sig M) (k - S n)
+ (mk_config ?? (〈qn,bin3,ch,to_initN (displ_of_move sig mv) ??〉)
+ (iter ? (λt0.tape_move ? t0 R) n t)). [2,3: @le_S_S /2 by lt_S_to_lt/]
+#sig #M #q #ch #qn #mv #k #n #Hk
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+elim n
+[ #t #Hle #Htrans >loopM_unfold >loop_S_false //
+ >(binaryTM_bin2_O … Htrans) //
+| #n0 #IH #t #Hn0 #Htrans >loopM_unfold >loop_S_false //
+ >(binaryTM_bin2_S_None … Htrans) @(trans_eq ???? (IH …)) //
+]
+qed.
+
+lemma binaryTM_phase2_Some_of : ∀sig,M,q,ch,qn,chn,mv,ls,k.
+ S (FS_crd sig) ≤ k → 〈qn,Some ? chn,mv〉 = trans sig M 〈q,ch〉 →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin2,ch,FS_crd sig〉) (mk_tape ? ls (None ?) [ ]))
+ = loopM ? (mk_binaryTM sig M) (k - S (FS_crd sig))
+ (mk_config ?? (〈qn,bin3,ch,displ_of_move sig mv〉)
+ (mk_tape ? (reverse ? (bin_char sig chn)@ls) (None ?) [ ])). [2,3:@le_S_S //]
+cut (∀sig,M,q,ch,qn,chn,mv,ls,k,n.
+ S n ≤ k → 〈qn,Some ? chn,mv〉 = trans sig M 〈q,ch〉 →
+ ∀csl. n <S (2*FS_crd sig) →
+ |csl| + n = FS_crd sig →
+ (∃fs.bin_char sig chn = reverse ? csl@fs) →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin2,ch,n〉) (mk_tape ? (csl@ls) (None ?) [ ]))
+ = loopM ? (mk_binaryTM sig M) (k - S n)
+ (mk_config ?? (〈qn,bin3,ch,displ_of_move sig mv〉)
+ (mk_tape ? (reverse ? (bin_char sig chn)@ls) (None ?) [ ]))) [1,2:@le_S_S //]
+[ #sig #M #q #ch #qn #chn #mv #ls #k #n #Hk
+ cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+ #Htrans elim n
+ [ #csl #Hcount #Hcrd * #fs #Hfs >loopM_unfold >loop_S_false // <loopM_unfold
+ cut (fs = [ ])
+ [ cases fs in Hfs; // #f0 #fs0 #H lapply (eq_f ?? (length ?) … H)
+ >length_append >(?:|bin_char sig chn| = FS_crd sig) [|@daemon]
+ <Hcrd >length_reverse #H1 cut (O = |f0::fs0|) [ /2/ ]
+ normalize #H1 destruct (H1) ]
+ #H destruct (H) >append_nil in Hfs; #Hfs
+ >Hfs >reverse_reverse >(binaryTM_bin2_O … Htrans) //
+ | #n0 #IH #csl #Hcount #Hcrd * #fs #Hfs
+ >loopM_unfold >loop_S_false // <loopM_unfold
+ >(?: step FinBool (mk_binaryTM sig M)
+ (mk_config FinBool (states FinBool (mk_binaryTM sig M)) 〈q,bin2,〈ch,S n0〉〉
+ (mk_tape FinBool (csl@ls) (None FinBool) []))
+ = mk_config ?? (〈q,bin2,ch,n0〉)
+ (tape_move ? (tape_write ?
+ (mk_tape ? (csl@ls) (None ?) [ ]) (Some ? (FS_nth ? n0 == Some ? chn))) R))
+ [| /2 by lt_S_to_lt/ | @(binaryTM_bin2_S_Some … Htrans) ]
+ >(?: tape_move ? (tape_write ???) ? =
+ mk_tape ? (((FS_nth ? n0 == Some sig chn)::csl)@ls) (None ?) [ ])
+ [| cases csl // cases ls // ]
+ cases fs in Hfs;
+ [ #Hfalse cut (|bin_char ? chn| = |csl|) [ >Hfalse >length_append >length_reverse // ]
+ -Hfalse >(?:|bin_char sig chn| = FS_crd sig) [|@daemon]
+ <Hcrd in ⊢ (%→?); >(?:|csl| = |csl|+ O) in ⊢ (???%→?); //
+ #Hfalse cut (S n0 = O) /2 by injective_plus_r/ #H destruct (H)
+ | #f0 #fs0 #Hbinchar
+ cut (bin_char ? chn = reverse ? csl@(FS_nth ? n0 == Some ? chn)::fs0) [@daemon]
+ -Hbinchar #Hbinchar >Hbinchar @(trans_eq ???? (IH …)) //
+ [ %{fs0} >reverse_cons >associative_append @Hbinchar
+ | whd in ⊢ (??%?); /2 by / ]
+ @eq_f @eq_f @eq_f3 //
+ ]
+ ]
+| #Hcut #sig #M #q #ch #qn #chn #mv #ls #k #Hk #Htrans
+ @trans_eq
+ [3: @(trans_eq ???? (Hcut ??????? ls ? (FS_crd sig) ? Htrans …)) //
+ [3:@([ ]) | %{(bin_char ? chn)} % | % ]
+ || % ]
+]
+qed.
+
+lemma binaryTM_phase2_Some_ow : ∀sig,M,q,ch,qn,chn,mv,ls,k,cs,rs.
+ S (FS_crd sig) ≤ k → 〈qn,Some ? chn,mv〉 = trans sig M 〈q,ch〉 →
+ |cs| = FS_crd sig →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin2,ch,FS_crd sig〉)
+ (mk_tape ? ls (option_hd ? (cs@rs)) (tail ? (cs@rs))))
+ = loopM ? (mk_binaryTM sig M) (k - S (FS_crd sig))
+ (mk_config ?? (〈qn,bin3,ch,displ_of_move sig mv〉)
+ (mk_tape ? (reverse ? (bin_char sig chn)@ls) (option_hd ? rs) (tail ? rs))). [2,3:@le_S_S /2 by O/]
+cut (∀sig,M,q,ch,qn,chn,mv,ls,rs,k,csr.
+ 〈qn,Some ? chn,mv〉 = trans sig M 〈q,ch〉 →
+ ∀csl.|csr|<S (2*FS_crd sig) →
+ |csl@csr| = FS_crd sig →
+ (∃fs.bin_char sig chn = reverse ? csl@fs) →
+ loopM ? (mk_binaryTM sig M) (S (|csr|) + k)
+ (mk_config ?? (〈q,bin2,ch,|csr|〉)
+ (mk_tape ? (csl@ls) (option_hd ? (csr@rs)) (tail ? (csr@rs))))
+ = loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈qn,bin3,ch,displ_of_move sig mv〉)
+ (mk_tape ? (reverse ? (bin_char sig chn)@ls) (option_hd ? rs) (tail ? rs)))) [1,2: @le_S_S /2 by le_S/]
+[ #sig #M #q #ch #qn #chn #mv #ls #rs #k #csr #Htrans elim csr
+ [ #csl #Hcount #Hcrd * #fs #Hfs >loopM_unfold >loop_S_false // normalize in match (length ? [ ]);
+ >(binaryTM_bin2_O … Htrans) <loopM_unfold @eq_f @eq_f @eq_f3 //
+ cases fs in Hfs; // #f0 #fs0 #H lapply (eq_f ?? (length ?) … H)
+ >length_append >(?:|bin_char sig chn| = FS_crd sig) [|@daemon]
+ <Hcrd >length_reverse #H1 cut (O = |f0::fs0|) [ /2/ ]
+ normalize #H1 destruct (H1)
+ | #b0 #bs0 #IH #csl #Hcount #Hcrd * #fs #Hfs
+ >loopM_unfold >loop_S_false // >(binaryTM_bin2_S_Some … Htrans)
+ >(?: tape_move ? (tape_write ???) ? =
+ mk_tape ? (((FS_nth ? (|bs0|)==Some sig chn)::csl)@ls)
+ (option_hd ? (bs0@rs)) (tail ? (bs0@rs)))
+ in match (tape_move ? (tape_write ???) ?);
+ [| cases bs0 // cases rs // ] @IH
+ [ whd in Hcount:(?%?); /2 by lt_S_to_lt/
+ | <Hcrd >length_append >length_append normalize //
+ | cases fs in Hfs;
+ [ #Hfalse cut (|bin_char ? chn| = |csl|) [ >Hfalse >length_append >length_reverse // ] -Hfalse >(?:|bin_char sig chn| = FS_crd sig) [|@daemon]
+ <Hcrd >length_append normalize >(?:|csl| = |csl|+ O) in ⊢ (???%→?); //
+ #Hfalse cut (S (|bs0|) = O) /2 by injective_plus_r/ #H destruct (H)
+ | #f0 #fs0 #Hbinchar
+ cut (bin_char ? chn = reverse ? csl@(FS_nth ? (|bs0|) == Some ? chn)::fs0) [@daemon]
+ -Hbinchar #Hbinchar >Hbinchar %{fs0} >reverse_cons >associative_append %
+ ]
+ ]
+ ]
+| #Hcut #sig #M #q #ch #qn #chn #mv #ls #k #cs #rs #Hk #Htrans #Hcrd
+ cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech @trans_eq
+ [3: @(trans_eq ???? (Hcut ??????? ls ?? cs Htrans [ ] …)) //
+ [ normalize % // | normalize @Hcrd | >Hcrd // ]
+ || @eq_f2 [ >Hcrd % | @eq_f2 // @eq_f cases Hcrd // ] ] ]
+qed.
+
+lemma binaryTM_bin3_O :
+ ∀sig,M,t,q,ch.
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin3,ch,O〉) t)
+ = mk_config ?? (〈q,bin0,None ?,to_initN (FS_crd sig) ??〉) t. [2,3:@le_S //]
+#sig #M #t #q #ch %
+qed.
+
+lemma binaryTM_bin3_S :
+ ∀sig,M,t,q,ch,k. S k ≤ S (2*FS_crd sig) →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin3,ch,S k〉) t)
+ = mk_config ?? (〈q,bin3,ch,to_initN k ??〉) (tape_move ? t L). [2,3: @le_S_S /2 by lt_to_le/]
+#sig #M #t #q #ch #k #HSk %
+qed.
+
+lemma binaryTM_phase3 :∀sig,M,q,ch,k,n.
+ S n ≤ k → n ≤ S (2*FS_crd sig) →
+ ∀t.loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin3,ch,n〉) t)
+ = loopM ? (mk_binaryTM sig M) (k - S n)
+ (mk_config ?? (〈q,bin0,None ?,FS_crd sig〉)
+ (iter ? (λt0.tape_move ? t0 L) n t)). [2,3: /2 by lt_S_to_lt, le_to_lt_to_lt/]
+#sig #M #q #ch #k #n #Hk
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech elim n
+[ #Hcrd #t >loopM_unfold >loop_S_false [| % ] >binaryTM_bin3_O //
+| #n0 #IH #Hlt #t >loopM_unfold >loop_S_false [|%] >binaryTM_bin3_S [|//]
+ <IH [|/2 by lt_to_le/]
+ <loopM_unfold % ]
+qed.
+
+lemma binaryTM_bin4_None :
+ ∀sig,M,t,q,ch.
+ current ? t = None ? →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin4,ch,O〉) t)
+ = mk_config ?? (〈q,bin2,ch,to_initN (FS_crd sig) ??〉) t. [2,3: @le_S //]
+#sig #M #t #q #ch #Hcur whd in ⊢ (??%?); >Hcur %
+qed.
+
+lemma binaryTM_phase4_write : ∀sig,M,q,ch,k,t.
+ O < k → current ? t = None ? →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin4,ch,O〉) t)
+ = loopM ? (mk_binaryTM sig M) (k-1)
+ (mk_config ?? (〈q,bin2,ch,to_initN (FS_crd sig) ??〉) t). [2,3: @le_S //]
+#sig #M #q #ch #k #t #Hk #Hcur
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+>loopM_unfold >loop_S_false // <loopM_unfold >binaryTM_bin4_None //
+qed.
+
+(* we don't get here any more! *
+lemma binaryTM_bin4_noextend :
+ ∀sig,M,t,q,ch,cur,qn,mv.
+ current ? t = Some ? cur →
+ 〈qn,None ?,mv〉 = trans sig M 〈q,ch〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin4,ch,O〉) t)
+ = mk_config ?? (〈q,bin2,ch,to_initN O ??〉) t. [2,3://]
+#sig #M #t #q #ch #cur #qn #mv #Hcur #Htrans
+whd in ⊢ (??%?); >Hcur whd in ⊢ (??%?);
+whd in match (trans FinBool ??); <Htrans %
+qed.
+*)
+
+lemma binaryTM_bin4_extend :
+ ∀sig,M,t,q,ch,cur,qn,an,mv.
+ current ? t = Some ? cur →
+ 〈qn,Some ? an,mv〉 = trans sig M 〈q,ch〉 →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin4,ch,O〉) t)
+ = mk_config ?? (〈q,bin5,ch,to_initN (FS_crd sig) ??〉) (tape_move ? t L). [2,3:@le_S //]
+#sig #M #t #q #ch #cur #qn #an #mv #Hcur #Htrans
+whd in ⊢ (??%?); >Hcur whd in ⊢ (??%?);
+whd in match (trans FinBool ??); <Htrans %
+qed.
+
+lemma binaryTM_phase4_extend : ∀sig,M,q,ch,k,t,cur,qn,an,mv.
+ O < k → current ? t = Some ? cur →
+ 〈qn,Some ? an,mv〉 = trans sig M 〈q,ch〉 →
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin4,ch,O〉) t)
+ = loopM ? (mk_binaryTM sig M) (k-1)
+ (mk_config ?? (〈q,bin5,ch,to_initN (FS_crd sig) ??〉) (tape_move ? t L)). [2,3: @le_S //]
+#sig #M #q #ch #k #t #cur #qn #an #mv #Hk #Hcur #Htrans
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+>loopM_unfold >loop_S_false // <loopM_unfold >binaryTM_bin4_extend //
+qed.
+
+lemma binaryTM_bin5_O :
+ ∀sig,M,t,q,ch.
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin5,ch,O〉) t)
+ = mk_config ?? (〈q,bin2,ch,to_initN (FS_crd sig) ??〉) (tape_move ? t R). [2,3:@le_S //]
+#sig #M #t #q #ch %
+qed.
+
+lemma binaryTM_bin5_S :
+ ∀sig,M,t,q,ch,k. S k <S (2*FS_crd sig) →
+ step ? (mk_binaryTM sig M) (mk_config ?? (〈q,bin5,ch,S k〉) t)
+ = mk_config ?? (〈q,bin5,ch,to_initN k ??〉) (tape_move ? (tape_write ? t (Some ? false)) L). [2,3:@le_S /2 by lt_S_to_lt/]
+#sig #M #t #q #ch #k #HSk %
+qed.
+
+(* extends the tape towards the left with an unimportant sequence that will be
+ immediately overwritten *)
+lemma binaryTM_phase5 :∀sig,M,q,ch,k,n. S n ≤ k →
+ ∀rs.n<S (2*FS_crd sig) →
+ ∃bs.|bs| = n ∧
+ loopM ? (mk_binaryTM sig M) k
+ (mk_config ?? (〈q,bin5,ch,n〉) (mk_tape ? [] (None ?) rs))
+ = loopM ? (mk_binaryTM sig M) (k - S n)
+ (mk_config ?? (〈q,bin2,ch,FS_crd sig〉)
+ (mk_tape ? [] (option_hd ? (bs@rs)) (tail ? (bs@rs)))). [2,3:@le_S //]
+#sig #M #q #ch #k #n #Hk
+cases (le_to_eq … Hk) #k0 #Hk0 >Hk0 >minus_tech
+elim n
+[ #rs #Hlt %{[]} % // cases rs //
+| #n0 #IH #rs #Hn0 cases (IH (false::rs) ?) [|/2 by lt_S_to_lt/]
+ #bs * #Hbs -IH #IH
+ %{(bs@[false])} % [ <Hbs >length_append /2 by increasing_to_injective/ ]
+ >loopM_unfold >loop_S_false // >binaryTM_bin5_S
+ >associative_append normalize in match ([false]@?); <IH
+ >loopM_unfold @eq_f @eq_f cases rs //
+]
+qed.
+
+lemma current_None_or_midtape :
+ ∀sig,t.current sig t = None sig ∨ ∃ls,c,rs.t = midtape sig ls c rs.
+#sig * normalize /2/ #ls #c #rs %2 /4 by ex_intro/
+qed.
+
+lemma state_bin_lift_unfold :
+ ∀sig.∀M:TM sig.∀q:states sig M.
+ state_bin_lift sig M q = 〈q,bin0,None ?,FS_crd sig〉.// qed.
+
+axiom current_tape_bin_list :
+ ∀sig,t.current sig t = None ? → current ? (tape_bin_lift sig t) = None ?.
+
+lemma tape_bin_lift_unfold :
+ ∀sig,t. tape_bin_lift sig t =
+ mk_tape ? (rev_bin_list ? (left ? t)) (option_hd ? (opt_bin_char sig (current ? t)))
+ (tail ? (opt_bin_char sig (current ? t))@bin_list ? (right ? t)). //
+qed.
+
+lemma reverse_bin_char_list : ∀sig,c,l.
+ reverse ? (bin_char sig c)@rev_bin_list ? l = rev_bin_list ? (c::l). // qed.
+
+lemma left_midtape : ∀sig,ls,c,rs.left ? (midtape sig ls c rs) = ls.// qed.
+lemma current_midtape : ∀sig,ls,c,rs.current ? (midtape sig ls c rs) = Some ? c.// qed.
+lemma right_midtape : ∀sig,ls,c,rs.right ? (midtape sig ls c rs) = rs.// qed.
+lemma opt_bin_char_Some : ∀sig,c.opt_bin_char sig (Some ? c) = bin_char ? c.// qed.
+
+lemma opt_cons_hd_tl : ∀A,l.option_cons A (option_hd ? l) (tail ? l) = l.
+#A * // qed.
+
+lemma le_tech : ∀a,b,c.a ≤ b → a * c ≤ b * c.
+#a #b #c #H /2 by monotonic_le_times_r/
+qed.
+
+lemma iter_split : ∀T,f,m,n,x.
+ iter T f (m+n) x = iter T f m (iter T f n x).
+#T #f #m #n elim n /2/
+#n0 #IH #x <plus_n_Sm whd in ⊢ (??%(????%)); >IH %
+qed.
+
+lemma iter_tape_move_R : ∀T,n,ls,cs,rs.|cs| = n →
+ iter ? (λt0.tape_move T t0 R) n (mk_tape ? ls (option_hd ? (cs@rs)) (tail ? (cs@rs)))
+ = mk_tape ? (reverse ? cs@ls) (option_hd ? rs) (tail ? rs).
+#T #n elim n
+[ #ls * [| #c0 #cs0 #rs #H normalize in H; destruct (H) ] #rs #_ %
+| #n0 #IH #ls * [ #rs #H normalize in H; destruct (H) ] #c #cs #rs #Hlen
+ whd in ⊢ (??%?);
+ >(?: (tape_move T (mk_tape T ls (option_hd T ((c::cs)@rs)) (tail T ((c::cs)@rs))) R)
+ = mk_tape ? (c::ls) (option_hd ? (cs@rs)) (tail ? (cs@rs))) in ⊢ (??(????%)?);
+ [| cases cs // cases rs // ] >IH
+ [ >reverse_cons >associative_append %
+ | normalize in Hlen; destruct (Hlen) % ]
+]
+qed.
+
+lemma tail_tech : ∀T,l1,l2.O < |l1| → tail T (l1@l2) = tail ? l1@l2.
+#T * normalize // #l2 #Hfalse @False_ind cases (not_le_Sn_O O) /2/
+qed.
+
+lemma hd_tech : ∀T,l1,l2.O < |l1| → option_hd T (l1@l2) = option_hd ? l1.
+#T * normalize // #l2 #Hfalse @False_ind cases (not_le_Sn_O O) /2/
+qed.
+
+lemma iter_tape_move_l_nil : ∀T,n,rs.
+ iter ? (λt0.tape_move T t0 L) n (mk_tape ? [ ] (None ?) rs) =
+ mk_tape ? [ ] (None ?) rs.
+#T #n #rs elim n // #n0 #IH <IH in ⊢ (???%); cases rs //
+qed.
+
+lemma iter_tape_move_L_left : ∀T,n,cs,rs. O < n →
+ iter ? (λt0.tape_move T t0 L) n
+ (mk_tape ? [ ] (option_hd ? cs) (tail ? cs@rs)) =
+ mk_tape ? [ ] (None ?) (cs@rs).
+#T #n #cs #rs *
+[ cases cs // cases rs //
+| #m #_ whd in ⊢ (??%?); <(iter_tape_move_l_nil ? m) cases cs // cases rs // ]
+qed.
+
+lemma iter_tape_move_L : ∀T,n,ls,cs,rs.|cs| = n →
+ iter ? (λt0.tape_move T t0 L) n (mk_tape ? (reverse ? cs@ls) (option_hd ? rs) (tail ? rs))
+ = mk_tape ? ls (option_hd ? (cs@rs)) (tail ? (cs@rs)).
+#T #n elim n
+[ #ls * [| #c0 #cs0 #rs #H normalize in H; destruct (H) ] #rs #_ %
+| #n0 #IH #ls #cs #rs @(list_elim_left … cs)
+ [ #H normalize in H; destruct (H) ] -cs
+ #c #cs #_ #Hlen >reverse_append whd in ⊢ (??%?);
+ >(?: tape_move T (mk_tape T ((reverse T [c]@reverse T cs)@ls) (option_hd T rs) (tail T rs)) L
+ = mk_tape ? (reverse T cs@ls) (option_hd ? (c::rs)) (tail ? (c::rs))) in ⊢ (??(????%)?);
+ [| cases rs // ] >IH
+ [ >associative_append %
+ | >length_append in Hlen; normalize // ]
+]
+qed.