--- /dev/null
+<?xml version="1.0"?>
+
+<!--******************************************************************-->
+<!-- XSLT version 0.1 of CIC objects to MathML content: -->
+<!-- First draft: February 14 2000, Andrea Asperti, Irene Schena -->
+<!-- Revised: March 3 2000, Irene Schena -->
+<!-- Revised: March 10 2000, Irene Schena -->
+<!-- Revised: March 15 2000, Claudio Sacerdoti Coen, Irene Schena -->
+<!--******************************************************************-->
+
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:m="http://www.w3.org/1998/Math/MathML"
+ xmlns:helm="http://www.cs.unibo.it/helm">
+
+<xsl:include href="params.xsl"/>
+
+<!--<xsl:output
+ method="xml"
+ version="1.0"
+ encoding="ISO-8859-1"
+ omit-xml-declaration="no"
+ standalone="no"
+ doctype-public="http://www.w3.org/TR/REC-MathML"
+ indent="yes"
+ media-type="text/mathml" /> -->
+
+<!-- DA FARE:
+1)risolvere nella fase di pre-processing le uri relative, settando l'attributo
+definitionURL dell'oggetto corrispondente (alcuni punteranno a nulla! -quelli
+che non hanno il file di definizione corrispondente-); [le uri assolute hanno
+la forma cic:/.../ in definitionURL e questo schema di uri verra' risolto da
+Amaya o da chi di dovere in /really_very_local/helm/PARSER/example/.../]
+2)aggiungere nei file xml gli ID, affinche' nello stylesheet si setti
+l'attributo xref di ogni oggetto per puntare (tramite ID) al suo corrispondente
+della rappresentazione interna.
+-->
+
+<!--******************************************************************-->
+<!-- Variable containing the absolute path of the CIC file -->
+<!--******************************************************************-->
+
+<xsl:variable name="absPath">http://localhost:8081/get?url=</xsl:variable>
+
+<!-- CIC TERMS -->
+
+<xsl:template match="LAMBDA" mode="pure">
+ <m:lambda helm:xref="{@id}">
+ <m:bvar>
+ <m:ci>
+ <xsl:value-of select="target/@binder"/>
+ </m:ci>
+ <m:type>
+ <xsl:apply-templates select="source/*[1]" mode="noannot"/>
+ </m:type>
+ </m:bvar>
+ <xsl:apply-templates select="target/*[1]" mode="noannot"/>
+ </m:lambda>
+</xsl:template>
+
+<xsl:template match="PROD" mode="pure">
+ <m:apply helm:xref="{@id}">
+ <xsl:choose>
+ <xsl:when test="string(target/@binder)= """>
+ <m:csymbol>arrow</m:csymbol>
+ <xsl:apply-templates select="source/*[1]" mode="noannot"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <m:csymbol>prod</m:csymbol>
+ <m:bvar>
+ <m:ci>
+ <xsl:value-of select="target/@binder"/>
+ </m:ci>
+ <m:type>
+ <xsl:apply-templates select="source/*[1]" mode="noannot"/>
+ </m:type>
+ </m:bvar>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:apply-templates select="target/*[1]" mode="noannot"/>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="CAST" mode="pure">
+ <m:apply helm:xref="{@id}">
+ <m:csymbol>cast</m:csymbol>
+ <xsl:apply-templates mode="noannot" select="*/*"/>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="REL" mode="pure">
+ <m:ci helm:xref="{@id}">
+ <xsl:value-of select="@binder"/>
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="SORT" mode="pure">
+ <m:apply helm:xref="{@id}">
+ <m:csymbol>
+ <xsl:value-of select="@value"/>
+ </m:csymbol>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="APPLY" mode="pure">
+ <xsl:choose>
+ <!-- <xsl:when test="//ALLTYPES and boolean(key('typeid',*/@id))"> -->
+ <!-- start looking for subproofs -->
+ <xsl:when test="((*/@id) = (//ALLTYPES/TYPE/@id))">
+ <m:apply helm:xref="{@id}">
+ <m:csymbol>letin</m:csymbol>
+ <!-- <xsl:for-each select="*[boolean(key('typeid',@id))]"> -->
+ <!-- first process all subproofs (let-in) -->
+ <xsl:for-each select="*[@id = (//ALLTYPES/TYPE/@id)]">
+ <m:apply>
+ <m:csymbol>let</m:csymbol>
+ <m:ci><xsl:value-of select="concat('h',position())"/></m:ci>
+ <xsl:apply-templates mode="noannot" select="."/>
+ </m:apply>
+ </xsl:for-each>
+ <!-- now re-process the application in mode appflat -->
+ <xsl:apply-templates mode="appflat" select="."/>
+ </m:apply>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:apply-templates mode="appflat" select="."/>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template match="APPLY" mode="appflat">
+ <m:apply helm:xref="{@id}">
+ <m:csymbol>app</m:csymbol>
+ <!-- mode flat looks for siblings: call with the first child -->
+ <xsl:apply-templates mode="flat" select="*[1]"/>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="*" mode="flat">
+ <xsl:param name="n" select="1"/>
+ <xsl:choose>
+ <xsl:when test="@id">
+ <xsl:variable name="id" select="@id"/>
+ <xsl:choose>
+ <!-- <xsl:when test="key('typeid',@id)"> -->
+ <xsl:when test="//ALLTYPES/TYPE[@id=$id]">
+ <m:ci>
+ <xsl:value-of select="concat('h',$n)"/>
+ </m:ci>
+ <xsl:apply-templates mode="flat" select="following-sibling::*[1]">
+ <xsl:with-param name="n" select="$n+1"/>
+ </xsl:apply-templates>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:apply-templates mode="pure" select="."/>
+ <xsl:apply-templates mode="flat" select="following-sibling::*[1]">
+ <xsl:with-param name="n" select="$n"/>
+ </xsl:apply-templates>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:apply-templates mode="pure" select="."/>
+ <xsl:apply-templates mode="flat" select="following-sibling::*[1]">
+ <xsl:with-param name="n" select="$n"/>
+ </xsl:apply-templates>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template match="VAR" mode="pure">
+ <m:ci helm:xref="{@id}">
+ <xsl:value-of select="substring-after(@relUri,",")"/>
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="META" mode="pure">
+ <m:ci helm:xref="{@id}">
+ <xsl:value-of select="@no"/>
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="CONST" mode="pure">
+ <m:ci definitionURL="{@uri}" helm:xref="{@id}">
+ <xsl:call-template name="name_of_uri">
+ <xsl:with-param name="uri" select="@uri"/>
+ </xsl:call-template>
+ <!-- <xsl:value-of select="document(concat(string($absPath),@uri))/*/@name"/> -->
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="MUTIND" mode="pure">
+ <m:ci definitionURL="{@uri}" helm:xref="{@id}">
+ <xsl:variable name="index"><xsl:value-of select="@noType"/></xsl:variable>
+ <xsl:value-of select="document(concat(string($absPath),@uri))/InductiveDefinition/InductiveType[position()=number($index)+1]/@name"/>
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="MUTCONSTRUCT" mode="pure">
+ <m:ci definitionURL="{@uri}" helm:xref="{@id}">
+ <xsl:variable name="Tindex"><xsl:value-of select="@noType"/></xsl:variable>
+ <xsl:variable name="Cindex"><xsl:value-of select="@noConstr"/></xsl:variable>
+ <xsl:value-of select="document(concat(string($absPath),@uri))/InductiveDefinition/InductiveType[position()=number($Tindex)+1]/Constructor[position()=number($Cindex)]/@name"/>
+ </m:ci>
+</xsl:template>
+
+<xsl:template match="MUTCASE" mode="pure">
+ <xsl:variable name="Tindex"><xsl:value-of select="@noType"/></xsl:variable>
+ <xsl:variable name="Turi"><xsl:value-of select="@uriType"/></xsl:variable>
+ <m:apply helm:xref="{@id}">
+ <m:csymbol>mutcase</m:csymbol>
+ <xsl:apply-templates select="patternsType/*[1]" mode="noannot"/>
+ <xsl:apply-templates select="inductiveTerm/*[1]" mode="noannot"/>
+ <xsl:variable name="nop"><xsl:value-of select="document(concat(string($absPath),$Turi))/InductiveDefinition/@noParams"/></xsl:variable>
+ <xsl:for-each select="pattern">
+ <xsl:variable name="pos" select="position()"/>
+ <xsl:variable name="nopar"><xsl:apply-templates select="document(concat(string($absPath),$Turi))/InductiveDefinition/InductiveType[position()=number($Tindex)+1]/Constructor[position()=number($pos)]/*[1]" mode="counting"><xsl:with-param name="noparams" select="$nop"/></xsl:apply-templates></xsl:variable>
+ <xsl:choose>
+ <xsl:when test="$nopar = 0">
+ <m:ci>
+ <xsl:value-of select="document(concat(string($absPath),$Turi))/InductiveDefinition/InductiveType[position()=number($Tindex)+1]/Constructor[position()=number($pos)]/@name"/>
+ </m:ci>
+ </xsl:when>
+ <xsl:otherwise>
+ <m:apply>
+ <m:csymbol>app</m:csymbol>
+ <m:ci>
+ <xsl:value-of select="document(concat(string($absPath),$Turi))/InductiveDefinition/InductiveType[position()=number($Tindex)+1]/Constructor[position()=number($pos)]/@name"/>
+ </m:ci>
+ <xsl:apply-templates select="./*[1]" mode="abstparams"><xsl:with-param name="noparams" select="$nopar"/><xsl:with-param name="binder">LAMBDA</xsl:with-param></xsl:apply-templates>
+ </m:apply>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:apply-templates select="./*[1]" mode="abstparams"><xsl:with-param name="noparams" select="$nopar"/><xsl:with-param name="target" select="1"/><xsl:with-param name="binder">LAMBDA</xsl:with-param></xsl:apply-templates>
+ </xsl:for-each>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="FIX" mode="pure">
+ <m:apply helm:xref="{@id}">
+ <xsl:variable name="findex"><xsl:value-of select="@noFun"/></xsl:variable>
+ <m:csymbol>fix</m:csymbol>
+ <m:ci><xsl:value-of select="FixFunction[position()=number($findex)+1]/@name"/></m:ci>
+ <xsl:apply-templates mode="noannot" select="*"/>
+ </m:apply>
+</xsl:template>
+
+<xsl:template match="COFIX" mode="pure">
+ <m:apply helm:xref="{@id}">
+ <xsl:variable name="findex"><xsl:value-of select="@noFun"/></xsl:variable>
+ <m:csymbol>cofix</m:csymbol>
+ <m:ci><xsl:value-of select="CofixFunction[position()=number($findex)+1]/@name"/></m:ci>
+ <xsl:apply-templates mode="noannot" select="*"/>
+ </m:apply>
+</xsl:template>
+
+<!-- ELEMENTS OF CIC TERMS -->
+
+<xsl:template match="FixFunction" mode="pure">
+ <m:bvar>
+ <m:ci><xsl:value-of select="@name"/></m:ci>
+ <m:type><xsl:apply-templates select="type/*[1]" mode="noannot"/></m:type>
+ </m:bvar>
+ <xsl:apply-templates select="body/*[1]" mode="noannot"/>
+</xsl:template>
+
+<xsl:template match="CofixFunction" mode="pure">
+ <m:bvar>
+ <m:ci><xsl:value-of select="@name"/></m:ci>
+ <m:type><xsl:apply-templates select="type/*[1]" mode="noannot"/></m:type>
+ </m:bvar>
+ <xsl:apply-templates select="body/*[1]" mode="noannot"/>
+</xsl:template>
+
+</xsl:stylesheet>