update for the article

[helm.git] / matita / matita / contribs / lambdadelta / basic_2 / rt_computation / cpxs_teqx.ma

diff --git a/matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_teqx.ma b/matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_teqx.ma
new file mode 100644 (file)
index 0000000..7af7b41
--- /dev/null
+++ b/matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_teqx.ma
@@ -0,0 +1,45 @@
+(**************************************************************************)
+(*       ___                                                              *)
+(*      ||M||                                                             *)
+(*      ||A||       A project by Andrea Asperti                           *)
+(*      ||T||                                                             *)
+(*      ||I||       Developers:                                           *)
+(*      ||T||         The HELM team.                                      *)
+(*      ||A||         http://helm.cs.unibo.it                             *)
+(*      \   /                                                             *)
+(*       \ /        This file is distributed under the terms of the       *)
+(*        v         GNU General Public License Version 2                  *)
+(*                                                                        *)
+(**************************************************************************)
+
+include "basic_2/rt_transition/rpx_reqx.ma".
+include "basic_2/rt_computation/cpxs.ma".
+
+(* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
+
+(* Properties with sort-irrelevant equivalence for terms ********************)
+
+lemma teqx_cpxs_trans: ∀h,U1,T1. U1 ≛ T1 → ∀G,L,T2. ⦃G,L⦄ ⊢ T1 ⬈*[h] T2 → 
+                       ∃∃U2. ⦃G,L⦄ ⊢ U1 ⬈*[h] U2 & U2 ≛ T2.
+#h #U1 #T1 #HUT1 #G #L #T2 #HT12 @(cpxs_ind … HT12) -T2 /2 width=3 by ex2_intro/
+#T #T2 #_ #HT2 * #U #HU1 #HUT elim (teqx_cpx_trans … HUT … HT2) -T -T1
+/3 width=3 by ex2_intro, cpxs_strap1/
+qed-.
+
+(* Note: this requires teqx to be symmetric *)
+(* Nasic_2A1: uses: cpxs_neq_inv_step_sn *)
+lemma cpxs_tneqx_fwd_step_sn: ∀h,G,L,T1,T2. ⦃G,L⦄ ⊢ T1 ⬈*[h] T2 → (T1 ≛ T2 → ⊥) →
+                              ∃∃T,T0. ⦃G,L⦄ ⊢ T1 ⬈[h] T & T1 ≛ T → ⊥ & ⦃G,L⦄ ⊢ T ⬈*[h] T0 & T0 ≛ T2.
+#h #G #L #T1 #T2 #H @(cpxs_ind_dx … H) -T1
+[ #H elim H -H //
+| #T1 #T0 #HT10 #HT02 #IH #Hn12
+  elim (teqx_dec T1 T0) [ -HT10 -HT02 #H10 | -IH #Hn10 ]
+  [ elim IH -IH /3 width=3 by teqx_trans/ -Hn12
+    #T3 #T4 #HT03 #Hn03 #HT34 #H42
+    elim (teqx_cpx_trans … H10 … HT03) -HT03 #T5 #HT15 #H53
+    elim (teqx_cpxs_trans … H53 … HT34) -HT34 #T6 #HT56 #H64
+    /5 width=8 by teqx_canc_sn, (* 2x *) teqx_trans, ex4_2_intro/
+  | /3 width=6 by ex4_2_intro/
+  ]
+]
+qed-.