ground_2 released and permanently renamed as ground

[helm.git] / matita / matita / contribs / lambdadelta / ground / lib / list_length.ma

diff --git a/matita/matita/contribs/lambdadelta/ground/lib/list_length.ma b/matita/matita/contribs/lambdadelta/ground/lib/list_length.ma
new file mode 100644 (file)
index 0000000..ab736bd
--- /dev/null
+++ b/matita/matita/contribs/lambdadelta/ground/lib/list_length.ma
@@ -0,0 +1,55 @@
+(**************************************************************************)
+(*       ___                                                              *)
+(*      ||M||                                                             *)
+(*      ||A||       A project by Andrea Asperti                           *)
+(*      ||T||                                                             *)
+(*      ||I||       Developers:                                           *)
+(*      ||T||         The HELM team.                                      *)
+(*      ||A||         http://helm.cs.unibo.it                             *)
+(*      \   /                                                             *)
+(*       \ /        This file is distributed under the terms of the       *)
+(*        v         GNU General Public License Version 2                  *)
+(*                                                                        *)
+(**************************************************************************)
+
+include "ground/lib/arith.ma".
+include "ground/lib/list.ma".
+
+(* LENGTH OF A LIST *********************************************************)
+
+rec definition length A (l:list A) on l ≝ match l with
+[ nil      ⇒ 0
+| cons _ l ⇒ ↑(length A l)
+].
+
+interpretation "length (list)"
+   'card l = (length ? l).
+
+(* Basic properties *********************************************************)
+
+lemma length_nil (A:Type[0]): |nil A| = 0.
+// qed.
+
+lemma length_cons (A:Type[0]) (l:list A) (a:A): |a⨮l| = ↑|l|.
+// qed.
+
+(* Basic inversion lemmas ***************************************************)
+
+lemma length_inv_zero_dx (A:Type[0]) (l:list A): |l| = 0 → l = Ⓔ.
+#A * // #a #l >length_cons #H destruct
+qed-.
+
+lemma length_inv_zero_sn (A:Type[0]) (l:list A): 0 = |l| → l = Ⓔ.
+/2 width=1 by length_inv_zero_dx/ qed-.
+
+lemma length_inv_succ_dx (A:Type[0]) (l:list A) (x): |l| = ↑x →
+                         ∃∃tl,a. x = |tl| & l = a ⨮ tl.
+#A *
+[ #x >length_nil #H destruct
+| #a #l #x >length_cons #H destruct /2 width=4 by ex2_2_intro/
+]
+qed-.
+
+lemma length_inv_succ_sn (A:Type[0]) (l:list A) (x): ↑x = |l| →
+                         ∃∃tl,a. x = |tl| & l = a ⨮ tl.
+/2 width=1 by length_inv_succ_dx/ qed.