X-Git-Url: http://matita.cs.unibo.it/gitweb/?a=blobdiff_plain;f=helm%2Fmeta_style%2Fpositive.xsl;fp=helm%2Fmeta_style%2Fpositive.xsl;h=f52b64702e89623bc081fc68697aa1e587df5961;hb=a2dcdb25b6efbd2623913ecf8f0f7ad3fb60bc75;hp=0000000000000000000000000000000000000000;hpb=5216557e4adc44b1f53eac3377d9c63b0ecad478;p=helm.git

diff --git a/helm/meta_style/positive.xsl b/helm/meta_style/positive.xsl
new file mode 100644
index 000000000..f52b64702
--- /dev/null
+++ b/helm/meta_style/positive.xsl
@@ -0,0 +1,177 @@
+<?xml version="1.0"?>
+
+<!-- Copyright (C) 2000, HELM Team                                     -->
+<!--                                                                   -->
+<!-- This file is part of HELM, an Hypertextual, Electronic            -->
+<!-- Library of Mathematics, developed at the Computer Science         -->
+<!-- Department, University of Bologna, Italy.                         -->
+<!--                                                                   -->
+<!-- HELM is free software; you can redistribute it and/or             -->
+<!-- modify it under the terms of the GNU General Public License       -->
+<!-- as published by the Free Software Foundation; either version 2    -->
+<!-- of the License, or (at your option) any later version.            -->
+<!--                                                                   -->
+<!-- HELM is distributed in the hope that it will be useful,           -->
+<!-- but WITHOUT ANY WARRANTY; without even the implied warranty of    -->
+<!-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the     -->
+<!-- GNU General Public License for more details.                      -->
+<!--                                                                   -->
+<!-- You should have received a copy of the GNU General Public License -->
+<!-- along with HELM; if not, write to the Free Software               -->
+<!-- Foundation, Inc., 59 Temple Place - Suite 330, Boston,            -->
+<!-- MA  02111-1307, USA.                                              -->
+<!--                                                                   -->
+<!-- For details, see the HELM World-Wide-Web page,                    -->
+<!-- http://cs.unibo.it/helm/.                                         -->
+
+<!--******************************************************************--> 
+<!-- Arithmetics                                                      -->
+<!-- First draft: March 20 2001, Ferruccio Guidi                      -->
+<!-- Zarith: July 2001, Andrea Asperti                                -->
+<!--******************************************************************-->
+
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                              xmlns:m="http://www.w3.org/1998/Math/MathML"
+                              xmlns:helm="http://www.cs.unibo.it/helm">
+
+<!-- ************************** ARITHMETICS ****************************** -->
+
+<!-- S and O -->
+<xsl:template match="APPLY[*[position()=1 and name()='MUTCONSTRUCT' and @uri='cic:/Coq/Init/Datatypes/nat.ind' and @noConstr='2'] and count(*)=2]" mode="pure">
+   <xsl:apply-templates select="*[2]" mode="succ">
+    <xsl:with-param name="n" select="1"/>
+    <xsl:with-param name="iden" select="@id"/>
+   </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="*" mode="succ">
+ <xsl:param name="n" select="0"/>
+ <xsl:param name="iden" select="''"/>
+ <xsl:choose>
+  <xsl:when test="name()='APPLY' and *[position()=1 and name()='MUTCONSTRUCT'
+and @uri='cic:/Coq/Init/Datatypes/nat.ind' and @noConstr='2']">
+   <xsl:apply-templates select="*[2]" mode="succ">
+    <xsl:with-param name="n" select="$n +1"/>
+    <xsl:with-param name="iden" select="$iden"/>
+   </xsl:apply-templates>
+  </xsl:when>
+  <xsl:when test="name()='MUTCONSTRUCT' and @uri='cic:/Coq/Init/Datatypes/nat.ind' and @noConstr='1'">
+   <m:cn helm:xref="{$iden}"><xsl:value-of select="$n"/></m:cn>
+  </xsl:when>
+  <xsl:otherwise>
+   <m:apply helm:xref="{$iden}">
+    <m:plus/>
+    <m:cn><xsl:value-of select="$n"/></m:cn>
+    <xsl:apply-templates select="." mode="pure"/>
+   </m:apply>
+  </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+
+<!-- **************************** Zarith ******************************** -->
+
+
+
+<xsl:template match="APPLY[*[position()=1 and name()='MUTCONSTRUCT' and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/Z.ind' and @noConstr='2'] and count(*)=2]" mode="pure">
+   <xsl:apply-templates select="*[2]" mode="Zpositive">
+    <xsl:with-param name="base" select="0"/>
+    <xsl:with-param name="exp" select="1"/>
+    <xsl:with-param name="iden" select="*[2]/@id"/>
+   </xsl:apply-templates>
+</xsl:template>
+ 
+<xsl:template match="APPLY[*[position()=1 and name()='MUTCONSTRUCT' and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/Z.ind' and @noConstr='3'] and count(*)=2]" mode="pure">
+   <m:apply helm:xref="{@id}">
+    <m:minus definitionURL="{*[1]/@uri}" helm:xref="{*[1]/@id}"/>
+    <xsl:apply-templates select="*[2]" mode="Zpositive">
+     <xsl:with-param name="base" select="0"/>
+     <xsl:with-param name="exp" select="1"/>
+     <xsl:with-param name="iden" select="*[2]/@id"/>
+    </xsl:apply-templates>
+   </m:apply>
+</xsl:template>
+
+<xsl:template match="MUTCONSTRUCT[@uri='cic:/Coq/ZArith/fast_integer/fast_integers/Z.ind' and @noConstr='1']" mode="pure">
+   <m:ci definitionURL="{@uri}" helm:xref="{@id}">0</m:ci>
+</xsl:template>
+
+<!-- prova di notazione per positive -->
+
+<xsl:template match="APPLY[*[position()=1 and name()='MUTCONSTRUCT' and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/positive.ind']]" mode="pure">
+   <xsl:apply-templates select="." mode="Zpositive">
+    <xsl:with-param name="base" select="0"/>
+    <xsl:with-param name="exp" select="1"/>
+    <xsl:with-param name="iden" select="@id"/>
+   </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="MUTCONSTRUCT[@uri='cic:/Coq/ZArith/fast_integer/fast_integers/positive.ind' and @noConstr='3']" mode="pure">
+ <m:ci definitionURL="{@uri}" helm:xref="{@id}">1</m:ci>
+</xsl:template> 
+
+<xsl:template match="*" mode="Zpositive">
+ <xsl:param name="base" select="0"/>
+ <xsl:param name="exp" select="1"/>
+ <xsl:param name="iden" select="''"/>
+ <xsl:choose>
+  <xsl:when test="name()='APPLY' and *[position()=1 and name()='MUTCONSTRUCT'
+and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/positive.ind' and @noConstr='1']">
+   <xsl:apply-templates select="*[2]" mode="Zpositive">
+    <xsl:with-param name="base" select="$base + $exp"/>
+    <xsl:with-param name="exp" select="2 * $exp"/>
+    <xsl:with-param name="iden" select="$iden"/>
+   </xsl:apply-templates>
+  </xsl:when>
+  <xsl:when test="name()='APPLY' and *[position()=1 and name()='MUTCONSTRUCT' 
+and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/positive.ind' and @noConstr='2']">
+   <xsl:apply-templates select="*[2]" mode="Zpositive">
+    <xsl:with-param name="base" select="$base"/>
+    <xsl:with-param name="exp" select="2 * $exp"/>
+    <xsl:with-param name="iden" select="$iden"/>
+   </xsl:apply-templates>
+  </xsl:when>
+  <xsl:when test="name()='MUTCONSTRUCT' and @uri='cic:/Coq/ZArith/fast_integer/fast_integers/positive.ind' and @noConstr='3'">
+   <m:ci helm:xref="{$iden}"><xsl:value-of select="$base + $exp"/></m:ci>
+  </xsl:when>
+  <xsl:otherwise>
+   <xsl:choose>
+    <xsl:when test="$base = 0">
+     <xsl:choose>
+      <xsl:when test="$exp = 1">
+       <xsl:apply-templates select="." mode="pure"/>
+      </xsl:when>
+      <xsl:otherwise>
+       <m:apply helm:xref="{$iden}">
+        <m:times/>
+        <m:ci><xsl:value-of select="$exp"/></m:ci>
+        <xsl:apply-templates select="." mode="pure"/>
+       </m:apply>
+      </xsl:otherwise>
+     </xsl:choose>
+    </xsl:when>
+    <xsl:otherwise>
+     <m:apply helm:xref="{$iden}">
+      <m:plus/>
+      <m:ci><xsl:value-of select="$base"/></m:ci>
+      <xsl:choose>
+       <xsl:when test="$exp = 1">
+        <xsl:apply-templates select="." mode="pure"/>
+       </xsl:when>
+       <xsl:otherwise>
+        <m:apply helm:xref="{$iden}">
+         <m:times/>
+         <m:ci><xsl:value-of select="$exp"/></m:ci>
+         <xsl:apply-templates select="." mode="pure"/>
+        </m:apply>
+       </xsl:otherwise>
+      </xsl:choose>
+     </m:apply>
+    </xsl:otherwise>
+   </xsl:choose>
+  </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+
+</xsl:stylesheet>