X-Git-Url: http://matita.cs.unibo.it/gitweb/?a=blobdiff_plain;f=helm%2Focaml%2Fcic%2FcicUtil.ml;h=f2ea4171bf356923effb70662b800f757f778c32;hb=2026624f827b29c35d54aa67b301250123ea7311;hp=a8195a311079922607949411fb77add571e8a2cb;hpb=fb3367a180abd237b4096fe398178dd14b994f6d;p=helm.git

diff --git a/helm/ocaml/cic/cicUtil.ml b/helm/ocaml/cic/cicUtil.ml
index a8195a311..f2ea4171b 100644
--- a/helm/ocaml/cic/cicUtil.ml
+++ b/helm/ocaml/cic/cicUtil.ml
@@ -24,9 +24,246 @@
  *)
 
 exception Meta_not_found of int
+exception Subst_not_found of int
+
 
 let lookup_meta index metasenv =
   try
     List.find (fun (index', _, _) -> index = index') metasenv
   with Not_found -> raise (Meta_not_found index)
 
+let lookup_subst n subst =
+  try
+    List.assoc n subst
+  with Not_found -> raise (Subst_not_found n)
+
+let exists_meta index = List.exists (fun (index', _, _) -> (index = index'))
+
+(* clean_up_meta take a substitution, a metasenv a meta_inex and a local
+context l and clean up l with respect to the hidden hipothesis in the 
+canonical context *)
+
+let clean_up_local_context subst metasenv n l =
+  let cc =
+    (try
+       let (cc,_,_) = lookup_subst n subst in cc
+     with Subst_not_found _ ->
+       try
+	 let (_,cc,_) = lookup_meta n metasenv in cc
+       with Meta_not_found _ -> assert false) in
+  (try 
+     List.map2
+       (fun t1 t2 ->
+	  match t1,t2 with 
+	      None , _ -> None
+	    | _ , t -> t) cc l
+   with 
+       Invalid_argument _ -> assert false)
+
+let is_closed =
+ let module C = Cic in
+ let rec is_closed k =
+  function
+      C.Rel m when m > k -> false
+    | C.Rel m -> true
+    | C.Meta (_,l) ->
+       List.fold_left
+        (fun i t -> i && (match t with None -> true | Some t -> is_closed k t)
+        ) true l
+    | C.Sort _ -> true
+    | C.Implicit _ -> assert false
+    | C.Cast (te,ty) -> is_closed k te && is_closed k ty
+    | C.Prod (name,so,dest) -> is_closed k so && is_closed (k+1) dest
+    | C.Lambda (_,so,dest) -> is_closed k so && is_closed (k+1) dest
+    | C.LetIn (_,so,dest) -> is_closed k so && is_closed (k+1) dest
+    | C.Appl l ->
+       List.fold_right (fun x i -> i && is_closed k x) l true
+    | C.Var (_,exp_named_subst)
+    | C.Const (_,exp_named_subst)
+    | C.MutInd (_,_,exp_named_subst)
+    | C.MutConstruct (_,_,_,exp_named_subst) ->
+       List.fold_right (fun (_,x) i -> i && is_closed k x)
+        exp_named_subst true
+    | C.MutCase (_,_,out,te,pl) ->
+       is_closed k out && is_closed k te &&
+        List.fold_right (fun x i -> i && is_closed k x) pl true
+    | C.Fix (_,fl) ->
+       let len = List.length fl in
+        let k_plus_len = k + len in
+         List.fold_right
+          (fun (_,_,ty,bo) i -> i && is_closed k ty && is_closed k_plus_len bo
+          ) fl true
+    | C.CoFix (_,fl) ->
+       let len = List.length fl in
+        let k_plus_len = k + len in
+         List.fold_right
+          (fun (_,ty,bo) i -> i && is_closed k ty && is_closed k_plus_len bo
+          ) fl true
+in 
+ is_closed 0
+;;
+
+let rec is_meta_closed =
+  function
+      Cic.Rel _ -> true
+    | Cic.Meta _ -> false
+    | Cic.Sort _ -> true
+    | Cic.Implicit _ -> assert false
+    | Cic.Cast (te,ty) -> is_meta_closed te && is_meta_closed ty
+    | Cic.Prod (name,so,dest) -> is_meta_closed so && is_meta_closed dest
+    | Cic.Lambda (_,so,dest) -> is_meta_closed so && is_meta_closed dest
+    | Cic.LetIn (_,so,dest) -> is_meta_closed so && is_meta_closed dest
+    | Cic.Appl l ->
+       List.fold_right (fun x i -> i && is_meta_closed x) l true
+    | Cic.Var (_,exp_named_subst)
+    | Cic.Const (_,exp_named_subst)
+    | Cic.MutInd (_,_,exp_named_subst)
+    | Cic.MutConstruct (_,_,_,exp_named_subst) ->
+       List.fold_right (fun (_,x) i -> i && is_meta_closed x)
+        exp_named_subst true
+    | Cic.MutCase (_,_,out,te,pl) ->
+       is_meta_closed out && is_meta_closed te &&
+        List.fold_right (fun x i -> i && is_meta_closed x) pl true
+    | Cic.Fix (_,fl) ->
+        List.fold_right
+          (fun (_,_,ty,bo) i -> i && is_meta_closed ty && is_meta_closed bo
+          ) fl true
+    | Cic.CoFix (_,fl) ->
+         List.fold_right
+          (fun (_,ty,bo) i -> i && is_meta_closed ty && is_meta_closed bo
+          ) fl true
+;;
+
+let xpointer_RE = Str.regexp "\\([^#]+\\)#xpointer(\\(.*\\))"
+let slash_RE = Str.regexp "/"
+
+let term_of_uri s =
+  let uri = UriManager.uri_of_string s in
+  try
+    (if String.sub s (String.length s - 4) 4 = ".con" then
+      Cic.Const (uri, [])
+    else if String.sub s (String.length s - 4) 4 = ".var" then
+      Cic.Var (uri, [])
+    else if not (Str.string_match xpointer_RE s 0) then
+      raise (UriManager.IllFormedUri s)
+    else
+      let (baseuri,xpointer) = (Str.matched_group 1 s, Str.matched_group 2 s) in
+      let baseuri = UriManager.uri_of_string baseuri in
+      (match Str.split slash_RE xpointer with
+      | [_; tyno] -> Cic.MutInd (baseuri, int_of_string tyno - 1, [])
+      | [_; tyno; consno] ->
+          Cic.MutConstruct
+            (baseuri, int_of_string tyno - 1, int_of_string consno, [])
+      | _ -> raise Exit))
+  with
+  | Exit
+  | Failure _
+  | Not_found -> raise (UriManager.IllFormedUri s)
+
+let select ~term ~context =
+  let rec aux context term =
+    match (context, term) with
+    | Cic.Implicit (Some `Hole), t -> [t]
+    | Cic.Meta (_, ctxt1), Cic.Meta (_, ctxt2) ->
+        List.concat
+          (List.map2
+            (fun t1 t2 ->
+              (match (t1, t2) with Some t1, Some t2 -> aux t1 t2 | _ -> []))
+            ctxt1 ctxt2)
+    | Cic.Cast (te1, ty1), Cic.Cast (te2, ty2) -> aux te1 te2 @ aux ty1 ty2
+    | Cic.Prod (_, s1, t1), Cic.Prod (_, s2, t2)
+    | Cic.Lambda (_, s1, t1), Cic.Lambda (_, s2, t2)
+    | Cic.LetIn (_, s1, t1), Cic.LetIn (_, s2, t2) -> aux s1 s2 @ aux t1 t2
+    | Cic.Appl terms1, Cic.Appl terms2 -> auxs terms1 terms2
+    | Cic.Var (_, subst1), Cic.Var (_, subst2)
+    | Cic.Const (_, subst1), Cic.Const (_, subst2)
+    | Cic.MutInd (_, _, subst1), Cic.MutInd (_, _, subst2)
+    | Cic.MutConstruct (_, _, _, subst1), Cic.MutConstruct (_, _, _, subst2) ->
+        auxs (List.map snd subst1) (List.map snd subst2)
+    | Cic.MutCase (_, _, out1, t1, pat1), Cic.MutCase (_ , _, out2, t2, pat2) ->
+        aux out1 out2 @ aux t1 t2 @ auxs pat1 pat2
+    | Cic.Fix (_, funs1), Cic.Fix (_, funs2) ->
+        List.concat
+          (List.map2
+            (fun (_, _, ty1, bo1) (_, _, ty2, bo2) -> aux ty1 ty2 @ aux bo1 bo2)
+            funs1 funs2)
+    | Cic.CoFix (_, funs1), Cic.CoFix (_, funs2) ->
+        List.concat
+          (List.map2
+            (fun (_, ty1, bo1) (_, ty2, bo2) -> aux ty1 ty2 @ aux bo1 bo2)
+            funs1 funs2)
+    | _ -> assert false
+  and auxs terms1 terms2 =  (* as aux for list of terms *)
+    List.concat (List.map2 aux terms1 terms2)
+  in
+  aux context term
+
+let context_of ?(equality=(==)) ~term terms =
+  let (===) x y = equality x y in
+  let rec aux t =
+    match t with
+    | t when List.exists (fun t' -> t === t') terms -> Cic.Implicit (Some `Hole)
+    | Cic.Var (uri, subst) -> Cic.Var (uri, aux_subst subst)
+    | Cic.Meta (i, ctxt) ->
+        let ctxt =
+          List.map (function None -> None | Some t -> Some (aux t)) ctxt
+        in
+        Cic.Meta (i, ctxt)
+    | Cic.Cast (t, ty) -> Cic.Cast (aux t, aux ty)
+    | Cic.Prod (name, s, t) -> Cic.Prod (name, aux s, aux t)
+    | Cic.Lambda (name, s, t) -> Cic.Lambda (name, aux s, aux t)
+    | Cic.LetIn (name, s, t) -> Cic.LetIn (name, aux s, aux t)
+    | Cic.Appl terms -> Cic.Appl (List.map aux terms)
+    | Cic.Const (uri, subst) -> Cic.Const (uri, aux_subst subst)
+    | Cic.MutInd (uri, tyno, subst) -> Cic.MutInd (uri, tyno, aux_subst subst)
+    | Cic.MutConstruct (uri, tyno, consno, subst) ->
+        Cic.MutConstruct (uri, tyno, consno, aux_subst subst)
+    | Cic.MutCase (uri, tyno, outty, t, pat) ->
+        Cic.MutCase (uri, tyno, aux outty, aux t, List.map aux pat)
+    | Cic.Fix (funno, funs) ->
+        let funs =
+          List.map (fun (name, i, ty, bo) -> (name, i, aux ty, aux bo)) funs
+        in
+        Cic.Fix (funno, funs)
+    | Cic.CoFix (funno, funs) ->
+        let funs =
+          List.map (fun (name, ty, bo) -> (name, aux ty, aux bo)) funs
+        in
+        Cic.CoFix (funno, funs)
+    | Cic.Rel _
+    | Cic.Sort _
+    | Cic.Implicit _ -> t
+  and aux_subst subst =
+    List.map (fun (uri, t) -> (uri, aux t)) subst
+  in
+  aux term
+
+let pack terms =
+  List.fold_right
+    (fun term acc -> Cic.Prod (Cic.Anonymous, term, acc))
+    terms (Cic.Sort (Cic.Type (CicUniv.fresh ())))
+
+let rec unpack = function
+  | Cic.Prod (Cic.Anonymous, term, Cic.Sort (Cic.Type _)) -> [term]
+  | Cic.Prod (Cic.Anonymous, term, tgt) -> term :: unpack tgt
+  | _ -> assert false
+
+let rec strip_prods n = function
+  | t when n = 0 -> t
+  | Cic.Prod (_, _, tgt) when n > 0 -> strip_prods (n-1) tgt
+  | _ -> failwith "not enough prods"
+
+let params_of_obj = function
+  | Cic.Constant (_, _, _, params, _)
+  | Cic.Variable (_, _, _, params, _)
+  | Cic.CurrentProof (_, _, _, _, params, _)
+  | Cic.InductiveDefinition (_, params, _, _) ->
+      params
+
+let attributes_of_obj = function
+  | Cic.Constant (_, _, _, _, attributes)
+  | Cic.Variable (_, _, _, _, attributes)
+  | Cic.CurrentProof (_, _, _, _, _, attributes)
+  | Cic.InductiveDefinition (_, _, _, attributes) ->
+      attributes
+