X-Git-Url: http://matita.cs.unibo.it/gitweb/?a=blobdiff_plain;f=matita%2Fmatita%2Fcontribs%2Flambdadelta%2Fbasic_2%2Frt_transition%2Frpx_rdeq.ma;fp=matita%2Fmatita%2Fcontribs%2Flambdadelta%2Fbasic_2%2Frt_transition%2Frpx_rdeq.ma;h=e2513c96fc63d0cc016163d200df5f578bc43f0f;hb=222044da28742b24584549ba86b1805a87def070;hp=0000000000000000000000000000000000000000;hpb=5c186c72f508da0849058afeecc6877cd9ed6303;p=helm.git

diff --git a/matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_rdeq.ma b/matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_rdeq.ma
new file mode 100644
index 000000000..e2513c96f
--- /dev/null
+++ b/matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_rdeq.ma
@@ -0,0 +1,168 @@
+(**************************************************************************)
+(*       ___                                                              *)
+(*      ||M||                                                             *)
+(*      ||A||       A project by Andrea Asperti                           *)
+(*      ||T||                                                             *)
+(*      ||I||       Developers:                                           *)
+(*      ||T||         The HELM team.                                      *)
+(*      ||A||         http://helm.cs.unibo.it                             *)
+(*      \   /                                                             *)
+(*       \ /        This file is distributed under the terms of the       *)
+(*        v         GNU General Public License Version 2                  *)
+(*                                                                        *)
+(**************************************************************************)
+
+include "basic_2/static/rdeq_fqup.ma".
+include "basic_2/static/rdeq_rdeq.ma".
+include "basic_2/rt_transition/rpx_fsle.ma".
+
+(* UNBOUND PARALLEL RT-TRANSITION FOR REFERRED LOCAL ENVIRONMENTS ***********)
+
+(* Properties with degree-based equivalence for local environments **********)
+
+lemma rpx_pair_sn_split: ∀h,G,L1,L2,V. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ∀o,I,T.
+                         ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≛[h, o, V] L2.
+/3 width=5 by rpx_fsge_comp, rex_pair_sn_split/ qed-.
+
+lemma rpx_flat_dx_split: ∀h,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ∀o,I,V.
+                         ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≛[h, o, T] L2.
+/3 width=5 by rpx_fsge_comp, rex_flat_dx_split/ qed-.
+
+lemma rpx_bind_dx_split: ∀h,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 → ∀o,p.
+                         ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≛[h, o, T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
+/3 width=5 by rpx_fsge_comp, rex_bind_dx_split/ qed-.
+
+lemma rpx_bind_dx_split_void: ∀h,G,K1,L2,T. ⦃G, K1.ⓧ⦄ ⊢ ⬈[h, T] L2 → ∀o,p,I,V.
+                              ∃∃K2. ⦃G, K1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] K2 & K2.ⓧ ≛[h, o, T] L2.
+/3 width=5 by rpx_fsge_comp, rex_bind_dx_split_void/ qed-.
+
+lemma rpx_tdeq_conf: ∀h,o,G. s_r_confluent1 … (cdeq h o) (rpx h G).
+/2 width=5 by tdeq_rex_conf/ qed-.
+
+lemma rpx_tdeq_div: ∀h,o,T1,T2. T1 ≛[h, o] T2 →
+                    ∀G,L1,L2. ⦃G, L1⦄ ⊢ ⬈[h, T2] L2 → ⦃G, L1⦄ ⊢ ⬈[h, T1] L2.
+/2 width=5 by tdeq_rex_div/ qed-.
+
+lemma cpx_tdeq_conf_sex: ∀h,o,G. R_confluent2_rex … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
+#h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
+[ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
+  elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
+  /4 width=3 by tdeq_sort, deg_next, ex2_intro/
+| #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
+  >(tdeq_inv_lref1 … H0) -H0
+  elim (rpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
+  elim (rdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
+  elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
+  elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
+| #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
+  >(tdeq_inv_lref1 … H0) -H0
+  elim (rpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
+  elim (rdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
+  elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
+  elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
+| #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
+  elim (rpx_inv_bind … H1) -H1 #HL01 #H1
+  elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
+  lapply (rdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
+  elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
+  elim (IHT … HT02 … H1 … H2) -L0 -T0
+  /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
+| #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
+  elim (rpx_inv_flat … H1) -H1 #HL01 #H1
+  elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
+  elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
+  elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
+  /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
+| #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
+  elim (rpx_inv_bind … H1) -H1 #HL01 #H1
+  elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
+  lapply (rdeq_bind_repl_dx … H2 (BPair Abbr V2) ?) -H2 /2 width=1 by ext2_pair/ -HV02 #H2
+  elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
+  elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
+  /3 width=5 by cpx_zeta, ex2_intro/
+| #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
+  elim (rpx_inv_flat … H1) -H1 #HL01 #H1
+  elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
+  elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
+  /3 width=3 by cpx_eps, ex2_intro/
+| #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
+  elim (rpx_inv_flat … H1) -H1 #HL01 #H1
+  elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
+  elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
+  /3 width=3 by cpx_ee, ex2_intro/
+| #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
+  elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
+  elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
+  elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
+  elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
+  elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
+  lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
+  elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
+  elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
+  elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
+  /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
+| #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
+  elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
+  elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
+  elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
+  elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
+  elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
+  elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
+  lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
+  elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
+  elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
+  elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
+  elim (tdeq_lifts_sn … HV1 … HVU1) -V1
+  /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
+]
+qed-.
+
+lemma cpx_tdeq_conf: ∀h,o,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
+                     ∀T2. T0 ≛[h, o] T2 →
+                     ∃∃T. T1 ≛[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
+#h #o #G #L #T0 #T1 #HT01 #T2 #HT02
+elim (cpx_tdeq_conf_sex … HT01 … HT02 L … L) -HT01 -HT02
+/2 width=3 by rex_refl, ex2_intro/
+qed-.
+
+lemma tdeq_cpx_trans: ∀h,o,G,L,T2. ∀T0:term. T2 ≛[h, o] T0 →
+                      ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 → 
+                      ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≛[h, o] T1.
+#h #o #G #L #T2 #T0 #HT20 #T1 #HT01
+elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
+qed-.
+
+(* Basic_2A1: uses: cpx_lleq_conf *)
+lemma cpx_rdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
+                     ∀L2. L0 ≛[h, o, T0] L2 →
+                     ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≛[h, o] T.
+#h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
+elim (cpx_tdeq_conf_sex … HT01 T0 … L0 … HL02) -HT01 -HL02
+/2 width=3 by rex_refl, ex2_intro/
+qed-.
+
+(* Basic_2A1: uses: lleq_cpx_trans *)
+lemma rdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≛[h, o, T0] L0 →
+                      ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
+                      ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≛[h, o] T1.
+#h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
+elim (cpx_rdeq_conf … o … HT01 L2) -HT01
+/3 width=3 by rdeq_sym, tdeq_sym, ex2_intro/
+qed-.
+
+lemma rpx_rdeq_conf: ∀h,o,G,T. confluent2 … (rpx h G T) (rdeq h o T).
+/3 width=6 by rpx_fsge_comp, rdeq_fsge_comp, cpx_tdeq_conf_sex, rex_conf/ qed-.
+
+lemma rdeq_rpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
+                      ∀L1. L1 ≛[h, o, T] L2 →
+                      ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≛[h, o, T] K2.
+#h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
+elim (rpx_rdeq_conf … o … HLK2 L1)
+/3 width=3 by rdeq_sym, ex2_intro/
+qed-.