+(* Copyright (C) 2005, HELM Team.
+ *
+ * This file is part of HELM, an Hypertextual, Electronic
+ * Library of Mathematics, developed at the Computer Science
+ * Department, University of Bologna, Italy.
+ *
+ * HELM is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * as published by the Free Software Foundation; either version 2
+ * of the License, or (at your option) any later version.
+ *
+ * HELM is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with HELM; if not, write to the Free Software
+ * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+ * MA 02111-1307, USA.
+ *
+ * For details, see the HELM World-Wide-Web page,
+ * http://helm.cs.unibo.it/
+ *)
+
+(* $Id: cicCoercion.ml 7077 2006-12-05 15:44:54Z fguidi $ *)
+
+let debug = false
+let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
+
+(* given the new coercion uri from src to tgt returns the list
+ * of new coercions to create. hte list elements are
+ * (source, list of coercions to follow, target)
+ *)
+let get_closure_coercions src tgt uri coercions =
+ let eq_carr s t =
+ try
+ CoercDb.eq_carr s t
+ with
+ | CoercDb.EqCarrNotImplemented _ | CoercDb.EqCarrOnNonMetaClosed -> false
+ in
+ match src,tgt with
+ | CoercDb.Uri _, CoercDb.Uri _ ->
+ let c_from_tgt =
+ List.filter
+ (fun (f,t,_) -> eq_carr f tgt (*&& not (eq_carr t src)*))
+ coercions
+ in
+ let c_to_src =
+ List.filter
+ (fun (f,t,_) -> eq_carr t src (*&& not (eq_carr f tgt)*))
+ coercions
+ in
+ (HExtlib.flatten_map
+ (fun (_,t,ul) -> List.map (fun u -> src,[uri; u],t) ul) c_from_tgt) @
+ (HExtlib.flatten_map
+ (fun (s,_,ul) -> List.map (fun u -> s,[u; uri],tgt) ul) c_to_src) @
+ (HExtlib.flatten_map
+ (fun (s,_,u1l) ->
+ HExtlib.flatten_map
+ (fun (_,t,u2l) ->
+ HExtlib.flatten_map
+ (fun u1 ->
+ List.map
+ (fun u2 -> (s,[u1;uri;u2],t))
+ u2l)
+ u1l)
+ c_from_tgt)
+ c_to_src)
+ | _ -> [] (* do not close in case source or target is not an indty ?? *)
+;;
+
+let obj_attrs n = [`Class (`Coercion n); `Generated]
+
+exception UnableToCompose
+
+(* generate_composite (c2 (c1 s)) in the universe graph univ
+ * both living in the same context and metasenv *)
+let generate_composite c1 c2 context metasenv univ arity last_lam_with_inn_arg =
+ let module RT = RefinementTool in
+ let c1_ty,univ = CicTypeChecker.type_of_aux' metasenv context c1 univ in
+ let c2_ty,univ = CicTypeChecker.type_of_aux' metasenv context c2 univ in
+ let rec mk_implicits = function
+ | 0 -> [] | n -> (Cic.Implicit None) :: mk_implicits (n-1)
+ in
+ let rec mk_lambda_spline c namer = function
+ | 0 -> c
+ | n ->
+ Cic.Lambda
+ (namer n,
+ (Cic.Implicit None),
+ mk_lambda_spline (CicSubstitution.lift 1 c) namer (n-1))
+ in
+ let count_saturations_needed t arity =
+ let rec aux acc n = function
+ | Cic.Prod (name,src, ((Cic.Prod _) as t)) ->
+ aux (acc@[name]) (n+1) t
+ | _ -> n,acc
+ in
+ let len,names = aux [] 0 t in
+ let len = len - arity in
+ List.fold_left
+ (fun (n,l) x -> if n < len then n+1,l@[x] else n,l) (0,[])
+ names
+ in
+ let compose c1 nc1 c2 nc2 =
+ Cic.Lambda
+ (Cic.Name "x", (Cic.Implicit None),
+ (Cic.Appl ( CicSubstitution.lift 1 c2 :: mk_implicits nc2 @
+ [ Cic.Appl ( CicSubstitution.lift 1 c1 :: mk_implicits nc1 @
+ [if last_lam_with_inn_arg then Cic.Rel 1 else Cic.Implicit None])
+ ])))
+ in
+(*
+ let order_metasenv metasenv =
+ let module OT = struct type t = int let compare = Pervasives.compare end in
+ let module S = HTopoSort.Make (OT) in
+ let dep i =
+ let _,_,ty = List.find (fun (j,_,_) -> j=i) metasenv in
+ let metas = List.map fst (CicUtil.metas_of_term ty) in
+ HExtlib.list_uniq (List.sort Pervasives.compare metas)
+ in
+ let om =
+ S.topological_sort (List.map (fun (i,_,_) -> i) metasenv) dep
+ in
+ List.map (fun i -> List.find (fun (j,_,_) -> i=j) metasenv) om
+ in
+*)
+ let rec create_subst_from_metas_to_rels n = function
+ | [] -> []
+ | (metano, ctx, ty)::tl ->
+ (metano,(ctx,Cic.Rel (n+1),ty)) ::
+ create_subst_from_metas_to_rels (n-1) tl
+ in
+ let split_metasenv metasenv n =
+ List.partition (fun (_,ctx,_) -> List.length ctx > n) metasenv
+ in
+ let purge_unused_lambdas metasenv t =
+ let rec aux = function
+ | Cic.Lambda (_, Cic.Meta (i,_), t) when
+ List.exists (fun (j,_,_) -> j = i) metasenv ->
+ aux (CicSubstitution.subst (Cic.Rel ~-100) t)
+ | Cic.Lambda (name, s, t) ->
+ Cic.Lambda (name, s, aux t)
+ | t -> t
+ in
+ aux t
+ in
+ let order_body_menv term body_metasenv =
+ let rec purge_lambdas = function
+ | Cic.Lambda (_,_,t) -> purge_lambdas t
+ | t -> t
+ in
+ let skip_appl = function | Cic.Appl l -> List.tl l | _ -> assert false in
+ let metas_that_saturate l =
+ List.fold_left
+ (fun (acc,n) t ->
+ let metas = CicUtil.metas_of_term t in
+ let metas = List.map fst metas in
+ let metas =
+ List.filter
+ (fun i -> List.for_all (fun (j,_) -> j<>i) acc)
+ metas
+ in
+ let metas = List.map (fun i -> i,n) metas in
+ metas @ acc, n+1)
+ ([],0) l
+ in
+ let l_c2 = skip_appl (purge_lambdas term) in
+ let l_c1 =
+ match HExtlib.list_last l_c2 with
+ | Cic.Appl l -> List.tl l
+ | _ -> assert false
+ in
+ (* i should cut off the laet elem of l_c2 *)
+ let meta2no = fst (metas_that_saturate (l_c1 @ l_c2)) in
+ List.sort
+ (fun (i,ctx1,ty1) (j,ctx1,ty1) ->
+ try List.assoc i meta2no - List.assoc j meta2no
+ with Not_found ->
+ assert false)
+ body_metasenv
+ in
+ let namer l n =
+ let l = List.map (function Cic.Name s -> s | _ -> "A") l in
+ let l = List.fold_left
+ (fun acc s ->
+ let rec add' s =
+ if List.exists ((=) s) acc then add' (s^"'") else s
+ in
+ acc@[add' s])
+ [] l
+ in
+ let l = List.rev l in
+ Cic.Name (List.nth l (n-1))
+ in
+ debug_print (lazy ("\nCOMPOSING"));
+ debug_print (lazy (" c1= "^CicPp.ppterm c1 ^" : "^ CicPp.ppterm c1_ty));
+ debug_print (lazy (" c2= "^CicPp.ppterm c2 ^" : "^ CicPp.ppterm c2_ty));
+ let saturations_for_c1, names_c1 = count_saturations_needed c1_ty 0 in
+ let saturations_for_c2, names_c2 = count_saturations_needed c2_ty arity in
+ let c = compose c1 saturations_for_c1 c2 saturations_for_c2 in
+ let spline_len = saturations_for_c1 + saturations_for_c2 in
+ let c = mk_lambda_spline c (namer (names_c1 @ names_c2)) spline_len in
+ debug_print (lazy ("COMPOSTA: " ^ CicPp.ppterm c));
+ let c, metasenv, univ =
+ try
+ let term, ty, metasenv, ugraph =
+ CicRefine.type_of_aux' metasenv context c univ
+ in
+ debug_print(lazy("COMPOSED REFINED: "^CicPp.ppterm term));
+(* let metasenv = order_metasenv metasenv in *)
+(* debug_print(lazy("ORDERED MENV: "^CicMetaSubst.ppmetasenv [] metasenv)); *)
+ let body_metasenv, lambdas_metasenv =
+ split_metasenv metasenv (spline_len + List.length context)
+ in
+ debug_print(lazy("B_MENV: "^CicMetaSubst.ppmetasenv [] body_metasenv));
+ debug_print(lazy("L_MENV: "^CicMetaSubst.ppmetasenv [] lambdas_metasenv));
+ let body_metasenv = order_body_menv term body_metasenv in
+ debug_print(lazy("ORDERED_B_MENV: "^CicMetaSubst.ppmetasenv [] body_metasenv));
+ let subst = create_subst_from_metas_to_rels spline_len body_metasenv in
+ debug_print (lazy("SUBST: "^CicMetaSubst.ppsubst body_metasenv subst));
+ let term = CicMetaSubst.apply_subst subst term in
+ debug_print (lazy ("COMPOSED SUBSTITUTED: " ^ CicPp.ppterm term));
+ let term, ty, metasenv, ugraph =
+ CicRefine.type_of_aux' metasenv context term ugraph
+ in
+ let body_metasenv, lambdas_metasenv =
+ split_metasenv metasenv (spline_len + List.length context)
+ in
+ let term = purge_unused_lambdas lambdas_metasenv term in
+ debug_print (lazy ("COMPOSED: " ^ CicPp.ppterm term));
+ debug_print(lazy("MENV: "^CicMetaSubst.ppmetasenv [] metasenv));
+ term, metasenv, ugraph
+ with
+ | CicRefine.RefineFailure s
+ | CicRefine.Uncertain s -> debug_print s;
+ raise UnableToCompose
+ in
+ c, metasenv, univ
+;;
+
+let build_obj c univ arity =
+ let c_ty,univ =
+ try
+ CicTypeChecker.type_of_aux' [] [] c univ
+ with CicTypeChecker.TypeCheckerFailure s ->
+ debug_print (lazy (Printf.sprintf "Generated composite coercion:\n%s\n%s"
+ (CicPp.ppterm c) (Lazy.force s)));
+ raise UnableToCompose
+ in
+ let cleaned_ty =
+ FreshNamesGenerator.clean_dummy_dependent_types c_ty
+ in
+ let obj = Cic.Constant ("xxxx",Some c,cleaned_ty,[],obj_attrs arity) in
+ obj,univ
+;;
+
+(* removes from l the coercions that are in !coercions *)
+let filter_duplicates l coercions =
+ List.filter (
+ fun (src,l1,tgt) ->
+ not (List.exists (fun (s,t,l2) ->
+ CoercDb.eq_carr s src &&
+ CoercDb.eq_carr t tgt &&
+ try
+ List.for_all2 (fun u1 u2 -> UriManager.eq u1 u2) l1 l2
+ with
+ | Invalid_argument "List.for_all2" -> false)
+ coercions))
+ l
+
+let mangle s t l =
+ (*List.fold_left
+ (fun s x -> s ^ "_" ^ x)
+ (s ^ "_OF_" ^ t ^ "_BY" ^ string_of_int (List.length l)) l*)
+ s ^ "_OF_" ^ t
+;;
+
+exception ManglingFailed of string
+
+let number_if_already_defined buri name l =
+ let err () =
+ raise
+ (ManglingFailed
+ ("Unable to give an altenative name to " ^ buri ^ "/" ^ name ^ ".con"))
+ in
+ let rec aux n =
+ let suffix = if n > 0 then string_of_int n else "" in
+ let suri = buri ^ "/" ^ name ^ suffix ^ ".con" in
+ let uri = UriManager.uri_of_string suri in
+ let retry () =
+ if n < 100 then
+ begin
+ HLog.warn ("Uri " ^ suri ^ " already exists.");
+ aux (n+1)
+ end
+ else
+ err ()
+ in
+ if List.exists (UriManager.eq uri) l then retry ()
+ else
+ try
+ let _ = Http_getter.resolve' ~writable:true uri in
+ if Http_getter.exists' uri then retry () else uri
+ with
+ | Http_getter_types.Key_not_found _ -> uri
+ | Http_getter_types.Unresolvable_URI _ -> assert false
+ in
+ aux 0
+;;
+
+(* given a new coercion uri from src to tgt returns
+ * a list of (new coercion uri, coercion obj, universe graph)
+ *)
+let close_coercion_graph _ src tgt uri baseuri =
+ (* check if the coercion already exists *)
+ let coercions = CoercDb.to_list () in
+ let todo_list = get_closure_coercions src tgt uri coercions in
+ let todo_list = filter_duplicates todo_list coercions in
+ try
+ let new_coercions =
+ List.fold_left
+ (fun acc (src, l , tgt) ->
+ try
+ (match l with
+ | [] -> assert false
+ | he :: tl ->
+ let arity = match tgt with CoercDb.Fun n -> n | _ -> 0 in
+ let first_step =
+ Cic.Constant ("",
+ Some (CoercDb.term_of_carr (CoercDb.Uri he)),
+ Cic.Sort Cic.Prop, [], obj_attrs arity)
+ in
+ let o,_ =
+ List.fold_left (fun (o,univ) coer ->
+ match o with
+ | Cic.Constant (_,Some c,_,[],_) ->
+ let t, menv, univ =
+ generate_composite c
+ (CoercDb.term_of_carr (CoercDb.Uri coer))
+ [] [] univ arity true
+ in
+ assert (menv = []);
+ build_obj t univ arity
+ | _ -> assert false
+ ) (first_step, CicUniv.empty_ugraph) tl
+ in
+ let name_src = CoercDb.name_of_carr src in
+ let name_tgt = CoercDb.name_of_carr tgt in
+ let by = List.map UriManager.name_of_uri l in
+ let name = mangle name_tgt name_src by in
+ let c_uri =
+ number_if_already_defined baseuri name
+ (List.map (fun (_,_,u,_) -> u) acc)
+ in
+ let named_obj =
+ match o with
+ | Cic.Constant (_,bo,ty,vl,attrs) ->
+ Cic.Constant (name,bo,ty,vl,attrs)
+ | _ -> assert false
+ in
+ (src,tgt,c_uri,named_obj))::acc
+ with UnableToCompose -> acc
+ ) [] todo_list
+ in
+ new_coercions
+ with ManglingFailed s -> HLog.error s; []
+;;
+
+CicCoercion.set_close_coercion_graph close_coercion_graph;;