+
+ let build_clause bag filter rule t subst vl id id2 pos dir =
+ let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
+ let t = Subst.apply_subst subst t in
+ if filter t then
+ let literal =
+ match t with
+ | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
+ let o = Order.compare_terms l r in
+ Terms.Equation (l, r, ty, o)
+ | t -> Terms.Predicate t
+ in
+ let bag, uc =
+ Utils.add_to_bag bag (0, literal, vl, proof)
+ in
+ Some (bag, uc)
+ else
+ ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
+ ;;
+
+
+ (* ============ simplification ================= *)
+
+ let demod table varlist subterm pos context =
+ let cands = IDX.DT.retrieve_generalizations table subterm in
+ list_first
+ (fun (dir, (id,lit,vl,_)) ->
+ match lit with
+ | Terms.Predicate _ -> assert false
+ | Terms.Equation (l,r,_,o) ->
+ let side, newside = if dir=Terms.Left2Right then l,r else r,l in
+ try
+ let subst, varlist =
+ Unif.unification (varlist@vl) varlist subterm side
+ in
+ if o = Terms.Incomparable then
+ let side = Subst.apply_subst subst side in
+ let newside = Subst.apply_subst subst newside in
+ let o = Order.compare_terms side newside in
+ (* Riazanov, pp. 45 (ii) *)
+ if o = Terms.Lt then
+ Some (context newside, subst, varlist, id, pos, dir)
+ else
+ ((*prerr_endline ("Filtering: " ^
+ Pp.pp_foterm side ^ " =(< || =)" ^
+ Pp.pp_foterm newside ^ " coming from " ^
+ Pp.pp_unit_clause uc );*)None)
+ else
+ Some (context newside, subst, varlist, id, pos, dir)
+ with FoUnif.UnificationFailure _ -> None)
+ (IDX.ClauseSet.elements cands)
+ ;;
+
+ (* XXX: possible optimization, if the literal has a "side" already
+ * in normal form we should not traverse it again *)
+ let demodulate_once bag (id, literal, vl, _) table =
+ let t =
+ match literal with
+ | Terms.Predicate t -> t
+ | Terms.Equation (l,r,ty,_) -> Terms.Node [ Terms.Leaf B.eqP; ty; l; r ]
+ in
+ match first_position [] (fun x -> x) t (demod table vl) with
+ | None -> None
+ | Some (newt, subst, varlist, id2, pos, dir) ->
+ build_clause bag (fun _ -> true) Terms.Demodulation
+ newt subst varlist id id2 pos dir
+ ;;
+
+ let rec demodulate bag clause table =
+ match demodulate_once bag clause table with
+ | None -> bag, clause
+ | Some (bag, clause) -> demodulate bag clause table
+ ;;
+
+ (* move away *)
+ let is_identity_clause = function
+ | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
+ | _, Terms.Predicate _, _, _ -> assert false
+ | _ -> false
+ ;;
+
+ let is_subsumed (id, lit, vl, _) table =
+ match lit with
+ | Terms.Predicate _ -> assert false
+ | Terms.Equation (l,r,ty,_) ->
+ let lcands = IDX.DT.retrieve_generalizations table l in
+ let rcands = IDX.DT.retrieve_generalizations table l in
+ let f b c =
+ let dir, l, r, vl =
+ match c with
+ | (d, (_,Terms.Equation (l,r,ty,_),vl,_))-> d, l, r, vl
+ |_ -> assert false
+ in
+ let l, r = if (dir = Terms.Left2Right) = b then l,r else r,l in
+ Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl
+ in
+ let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
+ let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
+ let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
+ List.exists
+ (fun (c, vl1) ->
+ try ignore(Unif.unification (vl@vl1) vl c t); true
+ with FoUnif.UnificationFailure _ -> false)
+ (cands1 @ cands2)
+ ;;
+
+ (* demodulate and check for subsumption *)
+ let forward_simplify table bag clause =
+ let bag, clause = demodulate bag clause table in
+ if is_identity_clause clause then None
+ else
+ if is_subsumed clause table then None
+ else Some (bag, clause)
+ ;;
+
+ (* =================== inference ===================== *)