(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id$ *)

module C = NCic
module Ref = NReference

module type Strategy = sig
  type stack_term
  type env_term
  type config = int * env_term list * C.term * stack_term list
  val to_env :
   reduce: (config -> config) -> unwind: (config -> C.term) ->
    config -> env_term
  val from_stack : stack_term -> config
  val from_stack_list_for_unwind :
   unwind: (config -> C.term) -> stack_term list -> C.term list
  val from_env : env_term -> config
  val from_env_for_unwind :
   unwind: (config -> C.term) -> env_term -> C.term
  val stack_to_env :
   reduce: (config -> config) -> unwind: (config -> C.term) ->
    stack_term -> env_term
  val compute_to_env :
   reduce: (config -> config) -> unwind: (config -> C.term) ->
    int -> env_term list -> C.term -> env_term
  val compute_to_stack :
   reduce: (config -> config) -> unwind: (config -> C.term) ->
    config -> stack_term
 end
;;

module CallByValueByNameForUnwind' = struct
  type config = int * env_term list * C.term * stack_term list
  and stack_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  and env_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  let to_env ~reduce ~unwind c = lazy (reduce c),lazy (unwind c)
  let from_stack (c,_) = Lazy.force c
  let from_stack_list_for_unwind ~unwind:_ l = 
   List.map (function (_,c) -> Lazy.force c) l
  let from_env (c,_) = Lazy.force c
  let from_env_for_unwind ~unwind:_ (_,c) = Lazy.force c
  let stack_to_env ~reduce:_ ~unwind:_ config = config
  let compute_to_env ~reduce ~unwind k e t =
   lazy (reduce (k,e,t,[])), lazy (unwind (k,e,t,[]))
  let compute_to_stack ~reduce ~unwind config = 
   lazy (reduce config), lazy (unwind config)
 end
;;

module Reduction(RS : Strategy) = struct
  type env = RS.env_term list
  type stack = RS.stack_term list
  type config = int * env * C.term * stack

  let rec unwind (k,e,t,s) =
    let t = 
      if k = 0 then t 
      else 
        NCicSubstitution.psubst ~avoid_beta_redexes:true  
          (RS.from_env_for_unwind ~unwind) e t
    in
    if s = [] then t 
    else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  ;;

  let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  let rec replace i s t =
    match i,s with
    |  0,_::tl -> t::tl
    | n,he::tl -> he::(replace (n - 1) tl t)
    | _,_ -> assert false
  ;;

  let rec reduce ~delta ?(subst = []) context : config -> config = 
   let rec aux = function
     | k, e, C.Rel n, s when n <= k ->
        let k',e',t',s' = RS.from_env (list_nth e (n-1)) in
        aux (k',e',t',s'@s)
     | k, _, C.Rel n, s as config (* when n > k *) ->
        let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
         (match x with
         | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
         | _ -> config)
     | (k, e, C.Meta (n,l), s) as config ->
        (try 
           let _,_, term,_ = NCicUtils.lookup_subst n subst in
           aux (k, e, NCicSubstitution.subst_meta l term,s)
         with  NCicUtils.Subst_not_found _ -> config)
     | (_, _, C.Implicit _, _) -> assert false
     | (_, _, C.Sort _, _)
     | (_, _, C.Prod _, _)
     | (_, _, C.Lambda _, []) as config -> config
     | (k, e, C.Lambda (_,_,t), p::s) ->
         aux (k+1, (RS.stack_to_env ~reduce:aux ~unwind p)::e, t,s)
     | (k, e, C.LetIn (_,_,m,t), s) ->
        let m' = RS.compute_to_env ~reduce:aux ~unwind k e m in
         aux (k+1, m'::e, t, s)
     | (_, _, C.Appl ([]|[_]), _) -> assert false
     | (k, e, C.Appl (he::tl), s) ->
        let tl' =
         List.map (fun t->RS.compute_to_stack ~reduce:aux ~unwind (k,e,t,[])) tl
        in
         aux (k, e, he, tl' @ s)
     | (_, _, C.Const
            (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
         if delta >= height then config else 
           let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
           aux (0, [], body, s) 
     | (_, _, C.Const (Ref.Ref (_,
            (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config -> config
     | (_, _, C.Const (Ref.Ref 
           (_,Ref.Fix (fixno,recindex,height)) as refer),s) as config ->
        if delta >= height then config else
        (match
          try Some (RS.from_stack (List.nth s recindex))
          with Failure _ -> None
        with 
        | None -> config
        | Some recparam ->
           let fixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
           match reduce ~delta:0 ~subst context recparam with
           | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c ->
               let new_s =
                 replace recindex s (RS.compute_to_stack ~reduce:aux ~unwind c)
               in
               let _,_,_,_,body = List.nth fixes fixno in
               aux (0, [], body, new_s)
           | _ -> config)
     | (k, e, C.Match (_,_,term,pl),s) as config ->
        let decofix = function
          | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
             let cofixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
             let _,_,_,_,body = List.nth cofixes c in
             reduce ~delta:0 ~subst context (0,[],body,s)
          | config -> config
        in
        (match decofix (reduce ~delta:0 ~subst context (k,e,term,[])) with
        | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
            aux (k, e, List.nth pl (j-1), s)
        | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
          let _,params = HExtlib.split_nth lno s' in
          aux (k, e, List.nth pl (j-1), params@s)
        | _ -> config)
   in
    aux
  ;;

  let whd ?(delta=0) ?(subst=[]) context t = 
   unwind (reduce ~delta ~subst context (0, [], t, []))
  ;;

 end
;;


module RS = CallByValueByNameForUnwind';;
module R = Reduction(RS);;

let whd = R.whd

let (===) x y = Pervasives.compare x y = 0 ;;

(* t1, t2 must be well-typed *)
let are_convertible whd ?(subst=[])  =
 let rec aux test_eq_only context t1 t2 =
   let rec alpha_eq test_eq_only t1 t2 =
     if t1 === t2 then
       true
     else
       match (t1,t2) with
       | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only -> 
           NCicEnvironment.universe_leq a b
       | (C.Sort (C.Type a), C.Sort (C.Type b)) -> 
           NCicEnvironment.universe_eq a b
       | (C.Sort s1,C.Sort (C.Type _)) -> (not test_eq_only)
       | (C.Sort s1, C.Sort s2) -> s1 = s2

       | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
           aux true context s1 s2 &&
           aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
       | (C.Lambda (name1,s1,t1), C.Lambda(_,s2,t2)) ->
          aux true context s1 s2 && 
          aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
       | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
          aux test_eq_only context ty1 ty2 &&
          aux test_eq_only context s1 s2 &&
          aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2

       | (C.Meta (n1,(s1, C.Irl i1)), C.Meta (n2,(s2, C.Irl i2))) 
          when n1 = n2 && s1 = s2 -> true
       | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
          let l1 = NCicUtils.expand_local_context l1 in
          let l2 = NCicUtils.expand_local_context l2 in
          (try List.for_all2 
            (fun t1 t2 -> aux test_eq_only context 
              (NCicSubstitution.lift s1 t1) 
              (NCicSubstitution.lift s2 t2))  
            l1 l2
          with Invalid_argument _ -> assert false) -> true

       | C.Meta (n1,l1), _ ->
          (try 
             let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
             let term = NCicSubstitution.subst_meta l1 term in
              aux test_eq_only context term t2
           with NCicUtils.Subst_not_found _ -> false)
       | _, C.Meta (n2,l2) ->
          (try 
             let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
             let term = NCicSubstitution.subst_meta l2 term in
              aux test_eq_only context t1 term
           with NCicUtils.Subst_not_found _ -> false)

       | (C.Appl (C.Const r1::tl1), C.Appl (C.Const r2::tl2)) ->
          r1 = r2 &&
           let relevance = NCicEnvironment.get_relevance r1 in
           (try
             HExtlib.list_forall_default3
              (fun t1 t2 b -> not b || aux test_eq_only context t1 t2)
              tl1 tl2 true relevance
            with Invalid_argument _ -> false)

       | (C.Appl l1, C.Appl l2) ->
          (try List.for_all2 (aux test_eq_only context) l1 l2
           with Invalid_argument _ -> false)

       | (C.Match (ref1,outtype1,term1,pl1),
          C.Match (ref2,outtype2,term2,pl2)) -> 
           Ref.eq ref1 ref2 &&
           aux test_eq_only context outtype1 outtype2 &&
           aux test_eq_only context term1 term2 &&
           (try List.for_all2 (aux test_eq_only context) pl1 pl2
            with Invalid_argument _ -> false)

       | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
       | (_,_) -> false
  in
   if alpha_eq test_eq_only t1 t2 then 
     true
   else
     let height_of = function
      | C.Const (Ref.Ref (_,Ref.Def h)) 
      | C.Const (Ref.Ref (_,Ref.Fix (_,_,h))) 
      | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_) 
      | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
      | _ -> 0
     in
     let small_delta_step (_,_,t1,_ as m1) (_,_,t2,_ as m2) = 
       let h1 = height_of t1 in 
       let h2 = height_of t2 in
       let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
       R.reduce ~delta ~subst context m1,
       R.reduce ~delta ~subst context m2,
       delta
     in
     let rec convert_machines ((k1,e1,t1,s1 as m1),(k2,e2,t2,s2 as m2),delta) =
       (alpha_eq test_eq_only
         (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
        let relevance =
          match t1 with
              C.Const r -> NCicEnvironment.get_relevance r
            | _ -> [] in
        try
         HExtlib.list_forall_default3
           (fun t1 t2 b  ->
             not b ||
             let t1 = RS.from_stack t1 in
             let t2 = RS.from_stack t2 in
             convert_machines (small_delta_step t1 t2)) s1 s2 true relevance
        with Invalid_argument _ -> false) || 
       (delta > 0 &&
          let delta = delta - 1 in 
          let red = R.reduce ~delta ~subst context in
          convert_machines (red m1,red m2,delta))
     in
     convert_machines (small_delta_step (0,[],t1,[]) (0,[],t2,[]))
 in
  aux false 
;;

let are_convertible = are_convertible whd

let rec head_beta_reduce ?(delta=max_int) ?(upto=(-1)) t l =
 match upto, t, l with
  | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
  | 0, t, [] -> t
  | 0, t, _ -> C.Appl (t::l)
  | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto hd (tl @ l)
  | _, C.Lambda(_,_,bo), arg::tl ->
     let bo = NCicSubstitution.subst arg bo in
     head_beta_reduce ~delta ~upto:(upto - 1) bo tl
  | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _ 
    when delta <= height ->
      let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
      head_beta_reduce ~upto ~delta bo l
  | _, t, [] -> t
  | _, t, _ -> C.Appl (t::l)
;;

let head_beta_reduce ?delta ?upto t = head_beta_reduce ?delta ?upto t [];;

(* vim:set foldmethod=marker: *)