(* Copyright (C) 2002, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

open ProofEngineHelpers
open ProofEngineTypes

exception NotAnInductiveTypeToEliminate
exception NotTheRightEliminatorShape
exception NoHypothesesFound

(* TODO problemone del fresh_name, aggiungerlo allo status? *)
let fresh_name () = "FOO"

(* lambda_abstract newmeta ty *)
(* returns a triple [bo],[context],[ty'] where              *)
(* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
(* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
(* So, lambda_abstract is the core of the implementation of *)
(* the Intros tactic.                                       *)
let lambda_abstract context newmeta ty name =
 let module C = Cic in
  let rec collect_context context =
   function
      C.Cast (te,_)   -> collect_context context te
    | C.Prod (n,s,t)  ->
       let n' =
        match n with
           C.Name _ -> n
(*CSC: generatore di nomi? Chiedere il nome? *)
         | C.Anonimous -> C.Name name
       in
        let (context',ty,bo) =
         collect_context ((Some (n',(C.Decl s)))::context) t
        in
         (context',ty,C.Lambda(n',s,bo))
    | C.LetIn (n,s,t) ->
       let (context',ty,bo) =
        collect_context ((Some (n,(C.Def s)))::context) t
       in
        (context',ty,C.LetIn(n,s,bo))
    | _ as t ->
      let irl = identity_relocation_list_for_metavariable context in
       context, t, (C.Meta (newmeta,irl))
  in
   collect_context context ty

let eta_expand metasenv context t arg =
 let module T = CicTypeChecker in
 let module S = CicSubstitution in
 let module C = Cic in
  let rec aux n =
   function
      t' when t' = S.lift n arg -> C.Rel (1 + n)
    | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
    | C.Var _
    | C.Meta _
    | C.Sort _
    | C.Implicit as t -> t
    | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
    | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
    | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
    | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
    | C.Appl l -> C.Appl (List.map (aux n) l)
    | C.Const _ as t -> t
    | C.MutInd _
    | C.MutConstruct _ as t -> t
    | C.MutCase (sp,cookingsno,i,outt,t,pl) ->
       C.MutCase (sp,cookingsno,i,aux n outt, aux n t,
        List.map (aux n) pl)
    | C.Fix (i,fl) ->
       let tylen = List.length fl in
        let substitutedfl =
         List.map
          (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
           fl
        in
         C.Fix (i, substitutedfl)
    | C.CoFix (i,fl) ->
       let tylen = List.length fl in
        let substitutedfl =
         List.map
          (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
           fl
        in
         C.CoFix (i, substitutedfl)
  in
   let argty =
    T.type_of_aux' metasenv context arg
   in
    (C.Appl [C.Lambda ((C.Name "dummy"),argty,aux 0 t) ; arg])

(*CSC: The call to the Intros tactic is embedded inside the code of the *)
(*CSC: Elim tactic. Do we already need tacticals?                       *)
(* Auxiliary function for apply: given a type (a backbone), it returns its   *)
(* head, a META environment in which there is new a META for each hypothesis,*)
(* a list of arguments for the new applications and the indexes of the first *)
(* and last new METAs introduced. The nth argument in the list of arguments  *)
(* is the nth new META lambda-abstracted as much as possible. Hence, this    *)
(* functions already provides the behaviour of Intros on the new goals.      *)
let new_metasenv_for_apply_intros proof context ty =
 let module C = Cic in
 let module S = CicSubstitution in
  let rec aux newmeta =
   function
      C.Cast (he,_) -> aux newmeta he
    | C.Prod (name,s,t) ->
       let newcontext,ty',newargument =
         lambda_abstract context newmeta s (fresh_name ())
       in
        let (res,newmetasenv,arguments,lastmeta) =
         aux (newmeta + 1) (S.subst newargument t)
        in
         res,(newmeta,newcontext,ty')::newmetasenv,newargument::arguments,lastmeta
    | t -> t,[],[],newmeta
  in
   let newmeta = new_meta ~proof in
    (* WARNING: here we are using the invariant that above the most *)
    (* recente new_meta() there are no used metas.                  *)
    let (res,newmetasenv,arguments,lastmeta) = aux newmeta ty in
     res,newmetasenv,arguments,newmeta,lastmeta

(*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
let classify_metas newmeta in_subst_domain subst_in metasenv =
 List.fold_right
  (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
    if in_subst_domain i then
     old_uninst,new_uninst
    else
     let ty' = subst_in canonical_context ty in
      let canonical_context' =
       List.fold_right
        (fun entry canonical_context' ->
          let entry' =
           match entry with
              Some (n,Cic.Decl s) ->
               Some (n,Cic.Decl (subst_in canonical_context' s))
            | Some (n,Cic.Def s) ->
               Some (n,Cic.Def (subst_in canonical_context' s))
            | None -> None
          in
           entry'::canonical_context'
        ) canonical_context []
     in
      if i < newmeta then
       ((i,canonical_context',ty')::old_uninst),new_uninst
      else
       old_uninst,((i,canonical_context',ty')::new_uninst)
  ) metasenv ([],[])

(* Auxiliary function for apply: given a type (a backbone), it returns its   *)
(* head, a META environment in which there is new a META for each hypothesis,*)
(* a list of arguments for the new applications and the indexes of the first *)
(* and last new METAs introduced. The nth argument in the list of arguments  *)
(* is just the nth new META.                                                 *)
let new_metasenv_for_apply proof context ty =
 let module C = Cic in
 let module S = CicSubstitution in
  let rec aux newmeta =
   function
      C.Cast (he,_) -> aux newmeta he
    | C.Prod (name,s,t) ->
       let irl = identity_relocation_list_for_metavariable context in
        let newargument = C.Meta (newmeta,irl) in
         let (res,newmetasenv,arguments,lastmeta) =
          aux (newmeta + 1) (S.subst newargument t)
         in
          res,(newmeta,context,s)::newmetasenv,newargument::arguments,lastmeta
    | t -> t,[],[],newmeta
  in
   let newmeta = new_meta ~proof in
    (* WARNING: here we are using the invariant that above the most *)
    (* recente new_meta() there are no used metas.                  *)
    let (res,newmetasenv,arguments,lastmeta) = aux newmeta ty in
     res,newmetasenv,arguments,newmeta,lastmeta

let apply_tac ~term ~status:(proof, goal) =
  (* Assumption: The term "term" must be closed in the current context *)
 let module T = CicTypeChecker in
 let module R = CicReduction in
 let module C = Cic in
  let (_,metasenv,_,_) = proof in
  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
   let termty = CicTypeChecker.type_of_aux' metasenv context term in
    (* newmeta is the lowest index of the new metas introduced *)
    let (consthead,newmetas,arguments,newmeta,_) =
     new_metasenv_for_apply proof context termty
    in
     let newmetasenv = newmetas@metasenv in
      let subst,newmetasenv' =
       CicUnification.fo_unif newmetasenv context consthead ty
      in
       let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
       let apply_subst = CicUnification.apply_subst subst in
        let old_uninstantiatedmetas,new_uninstantiatedmetas =
         (* subst_in doesn't need the context. Hence the underscore. *)
         let subst_in _ = CicUnification.apply_subst subst in
          classify_metas newmeta in_subst_domain subst_in newmetasenv'
        in
         let bo' =
          if List.length newmetas = 0 then
           term
          else
           let arguments' = List.map apply_subst arguments in
            Cic.Appl (term::arguments')
         in
          let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
          let (newproof, newmetasenv''') =
           let subst_in = CicUnification.apply_subst ((metano,bo')::subst) in
            subst_meta_and_metasenv_in_proof
              proof metano subst_in newmetasenv''
          in
           (newproof, List.map (function (i,_,_) -> i) new_uninstantiatedmetas)

  (* TODO per implementare i tatticali e' necessario che tutte le tattiche
  sollevino _solamente_ Fail *)
let apply_tac ~term ~status =
  try
    apply_tac ~term ~status
      (* TODO cacciare anche altre eccezioni? *)
  with CicUnification.UnificationFailed as e ->
    raise (Fail (Printexc.to_string e))

let intros_tac ~name ~status:(proof, goal) =
 let module C = Cic in
 let module R = CicReduction in
  let (_,metasenv,_,_) = proof in
  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
   let newmeta = new_meta ~proof in
    let (context',ty',bo') = lambda_abstract context newmeta ty name in
     let (newproof, _) =
       subst_meta_in_proof proof metano bo' [newmeta,context',ty']
     in
      (newproof, [newmeta])

let cut_tac ~term ~status:(proof, goal) =
 let module C = Cic in
  let curi,metasenv,pbo,pty = proof in
  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
   let newmeta1 = new_meta ~proof in
   let newmeta2 = newmeta1 + 1 in
   let context_for_newmeta1 =
    (Some (C.Name "dummy_for_cut",C.Decl term))::context in
   let irl1 =
    identity_relocation_list_for_metavariable context_for_newmeta1 in
   let irl2 = identity_relocation_list_for_metavariable context in
    let newmeta1ty = CicSubstitution.lift 1 ty in
    let bo' =
     C.Appl
      [C.Lambda (C.Name "dummy_for_cut",term,C.Meta (newmeta1,irl1)) ;
       C.Meta (newmeta2,irl2)]
    in
     let (newproof, _) =
      subst_meta_in_proof proof metano bo'
       [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
     in
      (newproof, [newmeta1 ; newmeta2])

let letin_tac ~term ~status:(proof, goal) =
 let module C = Cic in
  let curi,metasenv,pbo,pty = proof in
  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
   let _ = CicTypeChecker.type_of_aux' metasenv context term in
    let newmeta = new_meta ~proof in
    let context_for_newmeta =
     (Some (C.Name "dummy_for_letin",C.Def term))::context in
    let irl =
     identity_relocation_list_for_metavariable context_for_newmeta in
     let newmetaty = CicSubstitution.lift 1 ty in
     let bo' = C.LetIn (C.Name "dummy_for_letin",term,C.Meta (newmeta,irl)) in
      let (newproof, _) =
        subst_meta_in_proof
          proof metano bo'[newmeta,context_for_newmeta,newmetaty]
      in
       (newproof, [newmeta])

  (** functional part of the "exact" tactic *)
let exact_tac ~term ~status:(proof, goal) =
 (* Assumption: the term bo must be closed in the current context *)
 let (_,metasenv,_,_) = proof in
 let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 let module T = CicTypeChecker in
 let module R = CicReduction in
 if R.are_convertible context (T.type_of_aux' metasenv context term) ty then
  begin
   let (newproof, metasenv') =
     subst_meta_in_proof proof metano term [] in
   (newproof, [])
  end
 else
  raise (Fail "The type of the provided term is not the one expected.")


(* not really "primite" tactics .... *)

let elim_intros_simpl_tac ~term ~status:(proof, goal) =
 let module T = CicTypeChecker in
 let module U = UriManager in
 let module R = CicReduction in
 let module C = Cic in
  let (curi,metasenv,_,_) = proof in
  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
   let termty = T.type_of_aux' metasenv context term in
   let uri,cookingno,typeno,args =
    match termty with
       C.MutInd (uri,cookingno,typeno) -> (uri,cookingno,typeno,[])
     | C.Appl ((C.MutInd (uri,cookingno,typeno))::args) ->
         (uri,cookingno,typeno,args)
     | _ ->
         prerr_endline ("MALFATTORE" ^ (CicPp.ppterm termty));
         flush stderr;
         raise NotAnInductiveTypeToEliminate
   in
    let eliminator_uri =
     let buri = U.buri_of_uri uri in
     let name = 
      match CicEnvironment.get_cooked_obj uri cookingno with
         C.InductiveDefinition (tys,_,_) ->
          let (name,_,_,_) = List.nth tys typeno in
           name
       | _ -> assert false
     in
     let ext =
      match T.type_of_aux' metasenv context ty with
         C.Sort C.Prop -> "_ind"
       | C.Sort C.Set  -> "_rec"
       | C.Sort C.Type -> "_rect"
       | _ -> assert false
     in
      U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
    in
     let eliminator_cookingno =
      UriManager.relative_depth curi eliminator_uri 0
     in
     let eliminator_ref = C.Const (eliminator_uri,eliminator_cookingno) in
      let ety =
       T.type_of_aux' [] [] eliminator_ref
      in
       let (econclusion,newmetas,arguments,newmeta,lastmeta) =
(*
        new_metasenv_for_apply context ety
*)
        new_metasenv_for_apply_intros proof context ety
       in
        (* Here we assume that we have only one inductive hypothesis to *)
        (* eliminate and that it is the last hypothesis of the theorem. *)
        (* A better approach would be fingering the hypotheses in some  *)
        (* way.                                                         *)
        let meta_of_corpse =
         let (_,canonical_context,_) =
          List.find (function (m,_,_) -> m=(lastmeta - 1)) newmetas
         in
          let irl =
           identity_relocation_list_for_metavariable canonical_context
          in
           Cic.Meta (lastmeta - 1, irl)
        in
        let newmetasenv = newmetas @ metasenv in
        let subst1,newmetasenv' =
         CicUnification.fo_unif newmetasenv context term meta_of_corpse
        in
         let ueconclusion = CicUnification.apply_subst subst1 econclusion in
          (* The conclusion of our elimination principle is *)
          (*  (?i farg1 ... fargn)                         *)
          (* The conclusion of our goal is ty. So, we can   *)
          (* eta-expand ty w.r.t. farg1 .... fargn to get   *)
          (* a new ty equal to (P farg1 ... fargn). Now     *)
          (* ?i can be instantiated with P and we are ready *)
          (* to refine the term.                            *)
          let emeta, fargs =
           match ueconclusion with
(*CSC: Code to be used for Apply
              C.Appl ((C.Meta (emeta,_))::fargs) -> emeta,fargs
            | C.Meta (emeta,_) -> emeta,[]
*)
(*CSC: Code to be used for ApplyIntros *)
              C.Appl (he::fargs) ->
               let rec find_head =
                function
                   C.Meta (emeta,_) -> emeta
                 | C.Lambda (_,_,t) -> find_head t
                 | C.LetIn (_,_,t) -> find_head t
                 | _ ->raise NotTheRightEliminatorShape
               in
                find_head he,fargs
            | C.Meta (emeta,_) -> emeta,[]
(* *)
            | _ -> raise NotTheRightEliminatorShape
          in
           let ty' = CicUnification.apply_subst subst1 ty in
           let eta_expanded_ty =
(*CSC: newmetasenv' era metasenv ??????????? *)
            List.fold_left (eta_expand newmetasenv' context) ty' fargs
           in
            let subst2,newmetasenv'' =
(*CSC: passo newmetasenv', ma alcune variabili sono gia' state sostituite
da subst1!!!! Dovrei rimuoverle o sono innocue?*)
             CicUnification.fo_unif
              newmetasenv' context ueconclusion eta_expanded_ty
            in
             let in_subst_domain i =
              let eq_to_i = function (j,_) -> i=j in
               List.exists eq_to_i subst1 ||
               List.exists eq_to_i subst2
             in
(*CSC: codice per l'elim
              (* When unwinding the META that corresponds to the elimination *)
              (* predicate (which is emeta), we must also perform one-step   *)
              (* beta-reduction. apply_subst doesn't need the context. Hence *)
              (* the underscore.                                             *)
              let apply_subst _ t =
               let t' = CicUnification.apply_subst subst1 t in
                CicUnification.apply_subst_reducing
                 subst2 (Some (emeta,List.length fargs)) t'
              in
*)
(*CSC: codice per l'elim_intros_simpl. Non effettua semplificazione. *)
              let apply_subst context t =
               let t' = CicUnification.apply_subst (subst1@subst2) t in
                ProofEngineReduction.simpl context t'
              in
(* *)
                let old_uninstantiatedmetas,new_uninstantiatedmetas =
                 classify_metas newmeta in_subst_domain apply_subst
                  newmetasenv''
                in
                 let arguments' = List.map (apply_subst context) arguments in
                  let bo' = Cic.Appl (eliminator_ref::arguments') in
                   let newmetasenv''' =
                    new_uninstantiatedmetas@old_uninstantiatedmetas
                   in
                    let (newproof, newmetasenv'''') =
                     (* When unwinding the META that corresponds to the *)
                     (* elimination predicate (which is emeta), we must *)
                     (* also perform one-step beta-reduction.           *)
                     (* The only difference w.r.t. apply_subst is that  *)
                     (* we also substitute metano with bo'.             *)
                     (*CSC: Nota: sostituire nuovamente subst1 e' superfluo, *)
                     (*CSC: no?                                              *)
(*CSC: codice per l'elim
                     let apply_subst' t =
                      let t' = CicUnification.apply_subst subst1 t in
                       CicUnification.apply_subst_reducing
                        ((metano,bo')::subst2)
                        (Some (emeta,List.length fargs)) t'
                     in
*)
(*CSC: codice per l'elim_intros_simpl *)
                     let apply_subst' t =
                      CicUnification.apply_subst
                       ((metano,bo')::(subst1@subst2)) t
                     in
(* *)
                      subst_meta_and_metasenv_in_proof
                        proof metano apply_subst' newmetasenv'''
                    in
                     (newproof,
                      List.map (function (i,_,_) -> i) new_uninstantiatedmetas)