open Printf

let mqi_debug_fun = ignore
let mqi_flags = []
let mqi_handle = MQIConn.init mqi_flags mqi_debug_fun

let verbose = false

exception Failure of string
exception Multiple_interpretations
let fail msg = raise (Failure msg)

let uri_predicate = ref BatchParser.constants_only

module DisambiguateCallbacks =
 struct
  let output_html ?(append_NL = true) msg =
    if verbose then
      (if append_NL then print_string else print_endline)
        (Ui_logger.string_of_html_msg msg)

  let interactive_user_uri_choice
   ~selection_mode ?ok ?enable_button_for_non_vars ~title ~msg ~id choices =
     List.filter !uri_predicate choices

  let interactive_interpretation_choice _ = raise Multiple_interpretations
  let input_or_locate_uri ~title = fail "Unknown identifier"
 end

module Disambiguate' = Disambiguate.Make (DisambiguateCallbacks)

let debug_print s = prerr_endline ("^^^^^^ " ^ s)

let test_uri uri =
  let obj = CicEnvironment.get_obj uri in
  let (annobj, _, _, ids_to_inner_sorts, _, _, _) =
    Cic2acic.acic_object_of_cic_object ~eta_fix:false obj
  in
  let ids_to_uris = Hashtbl.create 1023 in
  let round_trip annterm =
    debug_print "(1) acic -> ast";
    let (ast, _) =
      Acic2Ast.ast_of_acic ids_to_inner_sorts ids_to_uris annterm
    in
    debug_print ("ast: " ^ CicAstPp.pp_term ast);
    let (_, _, term) =
      Disambiguate'.disambiguate_term mqi_handle [] [] ast
        DisambiguateTypes.Environment.empty
    in
    debug_print ("term: " ^ CicPp.ppterm term)
  in
  match annobj with
  | Cic.AConstant (_, _, _, None, ty, _) ->
      debug_print "Cic.AConstant (ty)";
      round_trip ty
  | Cic.AConstant (_, _, _, Some bo, ty, _) ->
(*
      debug_print "Cic.AConstant (bo)";
      round_trip bo;
*)
      debug_print "Cic.AConstant (ty)";
      round_trip ty
  | Cic.AVariable (_, _, None, ty, _) ->
      debug_print "Cic.AVariable (ty)";
      round_trip ty
  | Cic.AVariable (_, _, Some bo, ty, _) ->
      debug_print "Cic.AVariable (bo)";
      round_trip bo;
      debug_print "Cic.AVariable (ty)";
      round_trip ty
  | Cic.ACurrentProof (_, _, _, _, proof, ty, _) ->
      debug_print "Cic.ACurrentProof (proof)";
      round_trip proof;
      debug_print "Cic.ACurrentProof (ty)";
      round_trip ty
  | Cic.AInductiveDefinition _ ->
      debug_print "AInductiveDefinition: boh ..."

let test_uri uri =
  try
    test_uri uri;
    `Ok
  with
  | Multiple_interpretations -> `Maybe
  | exn ->
      prerr_endline (sprintf "Top Level Uncaught Exception: %s"
        (Printexc.to_string exn));
      `Nok

let report (ok,nok,maybe) =
  print_newline ();
  print_endline "TestLibrary report";
  print_endline "Succeeded URIs:";
  List.iter (fun s -> print_endline ("\t" ^ s)) (List.rev !ok);
  print_endline "Failed URIs:";
  List.iter (fun s -> print_endline ("\t" ^ s)) (List.rev !nok);
  print_endline "Multiple answers URIs:";
  List.iter (fun s -> print_endline ("\t" ^ s)) (List.rev !maybe);
  print_newline ()

let do_uri (ok, nok, maybe) uri =
  let uri_str = UriManager.string_of_uri uri in
  printf "Testing URI: %-55s %!" (uri_str ^ " ...");
  match test_uri uri with
  | `Ok ->
      print_endline "[   OK   ]";
      ok := uri_str :: !ok
  | `Nok ->
      print_endline "[ FAILED ]";
      nok := uri_str :: !nok
  | `Maybe ->
      print_endline "[  MANY  ]";
      maybe := uri_str :: !maybe

let do_file status fname =
  try
    let ic = open_in fname in
    (try
      while true do
        let line = input_line ic in
        try
          let uri = UriManager.uri_of_string line in
          do_uri status uri
        with UriManager.IllFormedUri _ ->
          printf "Error parsing URI '%s', ignoring it" line
      done
    with End_of_file ->
     close_in ic)
  with exn ->
    printf "Error trying to access '%s' (%s), skipping the file\n%!"
      fname (Printexc.to_string exn)

let _ =
  let names = ref [] in
  let tryvars = ref false in
  let varsprefix = ref "" in
  let usage = "testlibrary [OPTION] ... (uri1 | file1) (uri2 | file2) ..." in
  let spec =
    [ "-vars", Arg.Set tryvars, "try also variables" ;
      "-novars", Arg.Clear tryvars, "do not try variables (default)" ;
      "-varsprefix", Arg.Set_string varsprefix,
        "limit variable choices to URIs beginning with prefix" ;
    ]
  in
  Arg.parse spec (fun name -> names := name :: !names) usage;
  let names = List.rev !names in
  uri_predicate := BatchParser.uri_pred_of_conf !tryvars !varsprefix;
  let status = (ref [], ref [], ref []) in  (* <ok, nok, maybe> URIs *)
  List.iter
    (fun name ->
      try
        let uri = UriManager.uri_of_string name in
        do_uri status uri
      with UriManager.IllFormedUri _ ->
        if Sys.file_exists name then
          do_file status name
        else
          printf "Don't know what to do with '%s', ignoring it\n%!" name)
    names ;
  report status