(*
 *  Copyright (C) 2003, HELM Team.
 *
 *  This file is part of HELM, an Hypertextual, Electronic
 *  Library of Mathematics, developed at the Computer Science
 *  Department, University of Bologna, Italy.
 *
 *  HELM is free software; you can redistribute it and/or
 *  modify it under the terms of the GNU General Public License
 *  as published by the Free Software Foundation; either version 2
 *  of the License, or (at your option) any later version.
 *
 *  HELM is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with HELM; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 *  MA  02111-1307, USA.
 *
 *  For details, see the HELM World-Wide-Web page,
 *  http://cs.unibo.it/helm/.
 *)

open Http_getter_debugger;;
open Printf;;

let fold_file f init fname =
  let inchan = open_in fname in
  let rec fold_lines' value =
    try 
      let line = input_line inchan in 
      fold_lines' (f value line)
    with End_of_file -> value
  in
  let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  close_in inchan;
  res
let iter_file f = fold_file (fun _ line -> f line) ()

let hashtbl_sorted_fold f tbl init =
  let sorted_keys =
    List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  in
  List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys

let cp src dst =
  Shell.call
    ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
    [Shell.cmd "cp" [src; dst]]

let file_scheme_RE = Pcre.regexp "^file://"
let wget ?output url =
  let use_wget () =
    let flags =
      (match output with Some file -> ["-O"; file] | None -> []) @ [url]
    in
    debug_print ("wget " ^ String.concat " " flags);
    Shell.call
      ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
      [Shell.cmd "wget" flags]
  in
  if Pcre.pmatch ~rex:file_scheme_RE url then begin (* file:// URL *)
    let src_fname = Pcre.replace ~rex:file_scheme_RE url in
    match output with
    | Some dst_fname -> cp src_fname dst_fname
    | None ->
        let dst_fname = Filename.basename src_fname in
        if src_fname <> dst_fname then
          cp src_fname dst_fname
        else  (* src and dst are the same: do nothing *)
          ()
  end else  (* other URL, pass it to wget *)
    use_wget ()

  (* stderr shown as usual *)
let gzip ?(keep = false) fname =
  if keep then begin  (* keep original file *)
    debug_print ("gzip -f -c " ^ fname);
    Shell.call
      ~stdout:(Shell.to_file (fname ^ ".gz"))
      [Shell.cmd "gzip" ["-f"; "-c"; fname]]
  end else begin  (* don't keep original file *)
    debug_print ("gzip -f " ^ fname);
    Shell.call [Shell.cmd "gzip" ["-f"; fname]]
  end

  (* stderr shown as usual *)
let gunzip ?(keep = false) fname =
  if not (Pcre.pmatch ~pat:"\\.gz$" fname) then
    failwith "gunzip: source file doesn't end with '.gz'";
  let basename = Pcre.replace ~pat:"\\.gz$" fname in
  if keep then begin  (* keep original file *)
    debug_print ("gunzip -f -c " ^ fname);
    Shell.call
      ~stdout:(Shell.to_file basename)
      [Shell.cmd "gunzip" ["-f"; "-c"; fname]]
  end else begin  (* don't keep original file *)
    debug_print ("gunzip -f " ^ fname);
    Shell.call [Shell.cmd "gunzip" ["-f"; fname]]
  end

let tempfile () =
  let buf = Buffer.create 28 in (* strlen("/tmp/fileSzb3Mw_http_getter") *)
  Shell.call
    ~stdout:(Shell.to_buffer buf)
    [Shell.cmd "tempfile" ["--suffix=_http_getter"]];
  Pcre.replace ~pat:"\n" (Buffer.contents buf)

let mkdir ?(parents = false) dirname =
  if not (Sys.file_exists dirname) then begin
    let flags = if parents then ["-p"; dirname] else [dirname] in
    debug_print ("mkdir " ^ String.concat " " flags);
    Shell.call [Shell.cmd "mkdir" flags]
  end

let string_of_proc_status = function
  | Unix.WEXITED code -> sprintf "[Exited: %d]" code
  | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
  | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg

let http_get url =
  if Pcre.pmatch ~rex:file_scheme_RE url then begin
      (* file:// URL. Read data from file system *)
    let fname = Pcre.replace ~rex:file_scheme_RE url in
    try
      let size = (Unix.stat fname).Unix.st_size in
      let buf = String.create size in
      let ic = open_in fname in
      really_input ic buf 0 size;
      close_in ic;
      Some buf
    with Unix.Unix_error (Unix.ENOENT, "stat", _) -> None
  end else  (* other URL, pass it to netclient *)
    try
      Some (Http_client.Convenience.http_get url)
    with Http_client.Http_error (code, _) -> None