(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaGtkMisc
open MatitaTypes
open MatitaMisc

(** {2 Internal status} *)

let (get_proof, set_proof, has_proof) =
  let (current_proof: MatitaTypes.proof option ref) = ref None in
  ((fun () -> (* get_proof *)
    match !current_proof with
    | Some proof -> proof
    | None -> failwith "No current proof"),
   (fun proof ->  (* set_proof *)
      current_proof := proof),
   (fun () -> (* has_proof *)
      !current_proof <> None))

(** {2 Initialization} *)

let _ =
  Helm_registry.load_from "matita.conf.xml";
  GtkMain.Rc.add_default_file BuildTimeConf.gtkrc;
  GMain.Main.init ()
let parserr = new MatitaDisambiguator.parserr ()
let dbd =
  Mysql.quick_connect
    ~host:(Helm_registry.get "db.host")
    ~user:(Helm_registry.get "db.user")
    ~database:(Helm_registry.get "db.database")
    ()
let gui = MatitaGui.instance ()
let disambiguator =
  new MatitaDisambiguator.disambiguator ~parserr ~dbd
    ~chooseUris:(interactive_user_uri_choice ~gui)
    ~chooseInterp:(interactive_interp_choice ~gui)
    ()
let proof_viewer = MatitaMathView.proof_viewer_instance ()
let sequent_viewer = MatitaMathView.sequent_viewer ~show:true ()
let sequents_viewer =
  let set_goal goal =
    if not (has_proof ()) then assert false;
    (get_proof ())#set_goal goal
  in
  MatitaMathView.sequents_viewer ~notebook:gui#main#sequentsNotebook
    ~sequent_viewer ~set_goal ()

let new_proof (proof: MatitaTypes.proof) =
  let xmldump_observer _ _ =  print_endline proof#toString in
  let proof_observer _ (status, ()) =
    let ((uri_opt, _, _, _), _) = status in
    proof_viewer#load_proof status;
  in
  let sequents_observer _ (((_, metasenv, _, _), goal_opt), ()) =
    sequents_viewer#reset;
    (match goal_opt with
    | None -> ()
    | Some goal ->
        sequents_viewer#load_sequents metasenv;
        sequents_viewer#goto_sequent goal)
  in
  ignore (proof#attach_observer ~interested_in:StatefulProofEngine.all_events
    sequents_observer);
  ignore (proof#attach_observer ~interested_in:StatefulProofEngine.all_events
    proof_observer);
(*
  ignore (proof#attach_observer ~interested_in:StatefulProofEngine.all_events
    xmldump_observer);
*)
  proof#notify;
  set_proof (Some proof)

let quit () = (* quit program, asking for confirmation if needed *)
  if not (has_proof ()) ||
    (ask_confirmation ~gui
      ~msg:("Proof in progress, are you sure you want to quit?") ())
  then
    GMain.Main.quit ()

let abort_proof () =
  if has_proof () then begin
    set_proof None;
    sequents_viewer#reset
  end

let proof_handler =
  { MatitaTypes.get_proof = get_proof;
    MatitaTypes.abort_proof = abort_proof;
    MatitaTypes.set_proof = set_proof;
    MatitaTypes.has_proof = has_proof;
    MatitaTypes.new_proof = new_proof;
    MatitaTypes.quit = quit;
  }

let interpreter =
  let console = gui#console in
  new MatitaInterpreter.interpreter ~disambiguator ~proof_handler ~console ()

  (** prompt the user for the textual input of a term and disambiguate it *)
let ask_term ?(title = "term input") ?(msg = "insert term") () =
  match gui#askText ~title ~msg () with
  | Some t ->
      let (_, _, term) = disambiguator#disambiguateTerm (Stream.of_string t) in
      Some term
  | None -> None

(** {2 Script window handling} *)

let script_forward _ =
  let buf = gui#script#scriptTextView#buffer in
  let locked_iter = buf#get_iter_at_mark (`NAME "locked") in
  interpreter#evalPhrase
    (buf#get_text ~start:locked_iter ~stop:buf#end_iter ());
  gui#lockScript (locked_iter#offset + interpreter#endOffset)

let script_jump _ =
  let buf = gui#script#scriptTextView#buffer in
  let locked_iter = buf#get_iter_at_mark (`NAME "locked") in
  let cursor_iter = buf#get_iter_at_mark (`NAME "insert") in
  let raw_text = buf#get_text ~start:locked_iter ~stop:cursor_iter () in
  let len = String.length raw_text in
  let rec parse offset =
    if offset < len then begin
      interpreter#evalPhrase ~transparent:true
        (String.sub raw_text offset (len - offset));
      let new_offset = interpreter#endOffset + offset in
      gui#lockScript (new_offset + locked_iter#offset);
      parse new_offset
    end
  in
  try
    parse 0
  with CicTextualParser2.Parse_error _ -> ()

let script_back _ = not_implemented "script_back"

let load_script fname =
  gui#script#scriptTextView#buffer#set_text (input_file fname);
  gui#script#scriptWin#show ();
  gui#main#showScriptMenuItem#set_active true

(** {2 GUI callbacks} *)

let _ =
  gui#setQuitCallback quit;
  gui#setPhraseCallback interpreter#evalPhrase;
  gui#main#debugMenu#misc#hide ();
  ignore (gui#main#newProofMenuItem#connect#activate (fun _ ->
   if has_proof () &&
      not (ask_confirmation ~gui
        ~msg:("Proof in progress, are you sure you want to start a new one?")
        ())
    then
      ()  (* abort new proof process *)
    else
      let input = ask_text ~gui ~msg:"Insert proof goal" ~multiline:true () in
      let (env, metasenv, expr) =
        disambiguator#disambiguateTerm (Stream.of_string input)
      in
      let proof = MatitaProof.proof ~typ:expr ~metasenv () in
      new_proof proof));
  ignore (gui#main#openMenuItem#connect#activate (fun _ ->
    match gui#chooseFile () with
    | None -> ()
    | Some f when is_proof_script f -> load_script f
    | Some f ->
        gui#console#echo_error (sprintf
          "Don't know what to do with file: %s\nUnrecognized file format."
          f)));
  ignore (gui#script#scriptWinForwardButton#connect#clicked script_forward);
  ignore (gui#script#scriptWinBackButton#connect#clicked script_back);
  ignore (gui#script#scriptWinJumpButton#connect#clicked script_jump);
  let tac_w_term name tac _ =
    match ask_term ~title:name ~msg:("term for " ^ name) () with
    | Some term -> (get_proof ())#apply_tactic (tac ~term)
    | None -> ()
  in
  let tac _ tac _ = (get_proof ())#apply_tactic tac in
  let tbar = gui#toolbar in
  ignore (tbar#introsButton#connect#clicked (tac "intros" (Tactics.intros ())));
  ignore (tbar#applyButton#connect#clicked (tac_w_term "apply" Tactics.apply));
  ignore (tbar#exactButton#connect#clicked (tac_w_term "exact" Tactics.exact));
  ignore (tbar#elimButton#connect#clicked (tac_w_term "elim"
    Tactics.elim_intros_simpl));
  ignore (tbar#elimTypeButton#connect#clicked (tac_w_term "elim type"
    Tactics.elim_type));
  ignore (tbar#splitButton#connect#clicked (tac "split" Tactics.split));
  ignore (tbar#leftButton#connect#clicked (tac "left" Tactics.left));
  ignore (tbar#rightButton#connect#clicked (tac "right" Tactics.right));
  ignore (tbar#existsButton#connect#clicked (tac "exists" Tactics.exists));
  ignore (tbar#reflexivityButton#connect#clicked (tac "reflexivity"
    Tactics.reflexivity));
  ignore (tbar#symmetryButton#connect#clicked (tac "symmetry"
    Tactics.symmetry));
  ignore (tbar#transitivityButton#connect#clicked (tac_w_term "transitivity"
    Tactics.transitivity));
  ignore (tbar#assumptionButton#connect#clicked (tac "assumption"
    Tactics.assumption));
  ignore (tbar#cutButton#connect#clicked (tac_w_term "cut"
    (Tactics.cut ?mk_fresh_name_callback:None)));
  ignore (tbar#autoButton#connect#clicked (tac "auto" (Tactics.auto ~dbd)))

  (** <DEBUGGING> *)

let save_dom =
  let domImpl = lazy (Gdome.domImplementation ()) in
  fun ~doc ~dest ->
    ignore
      ((Lazy.force domImpl)#saveDocumentToFile ~doc ~name:dest ~indent:true ())

let _ =
  if BuildTimeConf.debug then begin
    gui#main#debugMenu#misc#show ();
    let addDebugItem ~label callback =
      let item =
        GMenu.menu_item ~packing:gui#main#debugMenu_menu#append ~label ()
      in
      ignore (item#connect#activate callback)
    in
    addDebugItem "interactive user uri choice" (fun _ ->
      try
        let uris =
          interactive_user_uri_choice ~gui ~selection_mode:`MULTIPLE
            ~msg:"messaggio" ~nonvars_button:true
            ["cic:/uno.con"; "cic:/due.var"; "cic:/tre.con"; "cic:/quattro.con";
            "cic:/cinque.var"]
        in
        List.iter prerr_endline uris
      with MatitaGtkMisc.Cancel -> MatitaTypes.error "no choice");
    addDebugItem "toggle auto disambiguation" (fun _ ->
      Helm_registry.set_bool "matita.auto_disambiguation"
        (not (Helm_registry.get_bool "matita.auto_disambiguation")));
    addDebugItem "mono line text input" (fun _ ->
      prerr_endline (ask_text ~gui ~title:"title" ~msg:"message" ()));
    addDebugItem "multi line text input" (fun _ ->
      prerr_endline
        (ask_text ~gui ~title:"title" ~multiline:true ~msg:"message" ()));
    addDebugItem "dump proof status to stdout" (fun _ ->
      print_endline ((get_proof ())#toString));
  end

  (** </DEBUGGING> *)

let _ =
  (try
    load_script Sys.argv.(1)
  with Invalid_argument _ -> ());
  GtkThread.main ()