(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaGtkMisc
open MatitaTypes
open MatitaMisc

(* ALB to link paramodulation... *)
let _ = Paramodulation.Saturation.init ()

(** {2 Initialization} *)

let _ =
  Helm_registry.load_from BuildTimeConf.matita_conf;
  CicNotation.load_notation BuildTimeConf.core_notation_script;
  Http_getter.init ();
  MetadataTypes.ownerize_tables (Helm_registry.get "matita.owner");
  MatitaDb.create_owner_environment ();
  MatitamakeLib.initialize ();
  CicEnvironment.set_trust (* environment trust *)
    (let trust = Helm_registry.get_bool "matita.environment_trust" in
     fun _ -> trust)

(** {2 GUI callbacks} *)

let gui = MatitaGui.instance ()

let script =
  let s = 
    MatitaScript.script 
      ~source_view:gui#sourceView
      ~init:(Lazy.force MatitaEngine.initial_status) 
      ~mathviewer:(MatitaMathView.mathViewer ())
      ~urichooser:(fun uris ->
        try
          MatitaGui.interactive_uri_choice ~selection_mode:`SINGLE
          ~title:"Matita: URI chooser" 
          ~msg:"Select the URI" ~hide_uri_entry:true
          ~hide_try:true ~ok_label:"_Apply" ~ok_action:`SELECT
          ~copy_cb:(fun s -> gui#sourceView#buffer#insert ("\n"^s^"\n"))
          () ~id:"boh?" uris
        with MatitaTypes.Cancel -> [])
      ~set_star:gui#setStar
      ~ask_confirmation:
        (fun ~title ~message -> 
            MatitaGtkMisc.ask_confirmation ~title ~message 
            ~parent:gui#main#toplevel ())
      ~develcreator:gui#createDevelopment
      ()
  in
  gui#sourceView#source_buffer#begin_not_undoable_action ();
  s#reset (); 
  s#template (); 
  gui#sourceView#source_buffer#end_not_undoable_action ();
  s
  
  (* math viewers *)
let _ =
  let cic_math_view = MatitaMathView.cicMathView_instance () in
  let sequents_viewer = MatitaMathView.sequentsViewer_instance () in
  cic_math_view#set_href_callback
    (Some (fun uri -> (MatitaMathView.cicBrowser ())#load
      (`Uri (UriManager.uri_of_string uri))));
  let browser_observer _ = MatitaMathView.refresh_all_browsers () in
  let sequents_observer status =
    sequents_viewer#reset;
    match status.proof_status with
    | Incomplete_proof ((proof, goal) as status) ->
        sequents_viewer#load_sequents status;
        sequents_viewer#goto_sequent goal
    | Proof proof -> 
        sequents_viewer#load_logo_with_qed
    | No_proof -> 
        sequents_viewer#load_logo
    | Intermediate _ -> 
        assert false (* only the engine may be in this state *)
  in
  script#addObserver sequents_observer;
  script#addObserver browser_observer

  (** <DEBUGGING> *)
let _ =
  if BuildTimeConf.debug then begin
    gui#main#debugMenu#misc#show ();
    let addDebugItem ~label callback =
      let item =
        GMenu.menu_item ~packing:gui#main#debugMenu_menu#append ~label ()
      in
      ignore (item#connect#activate callback)
    in
    addDebugItem "dump environment to \"env.dump\"" (fun _ ->
      let oc = open_out "env.dump" in
      CicEnvironment.dump_to_channel oc;
      close_out oc);
    addDebugItem "load environment from \"env.dump\"" (fun _ ->
      let ic = open_in "env.dump" in
      CicEnvironment.restore_from_channel ic;
      close_in ic);
    addDebugItem "dump universes" (fun _ ->
      List.iter (fun (u,_,g) -> 
        prerr_endline (UriManager.string_of_uri u); 
        CicUniv.print_ugraph g) (CicEnvironment.list_obj ())
      );
    addDebugItem "dump environment content" (fun _ ->
      List.iter (fun (u,_,_) -> 
        prerr_endline (UriManager.string_of_uri u)) 
        (CicEnvironment.list_obj ()));
    addDebugItem "print selections" (fun () ->
      let cicMathView = MatitaMathView.cicMathView_instance () in
      List.iter MatitaLog.debug (cicMathView#string_of_selections));
    addDebugItem "dump getter settings" (fun _ ->
      prerr_endline (Http_getter_env.env_to_string ()));
    addDebugItem "getter: getalluris" (fun _ ->
      List.iter prerr_endline (Http_getter.getalluris ()));
    addDebugItem "dump script status" script#dump;
    addDebugItem "dump metasenv"
      (fun _ ->
         if script#onGoingProof () then
           MatitaLog.debug (CicMetaSubst.ppmetasenv script#proofMetasenv []));
    addDebugItem "dump coercions Db" (fun _ ->
      List.iter
        (fun (s,t,u) -> 
          MatitaLog.debug
            (UriManager.name_of_uri u ^ ":"
             ^ UriManager.name_of_uri s ^ " -> " ^ UriManager.name_of_uri t))
        (CoercDb.to_list ()));
    addDebugItem "rotate light bulbs"
      (fun _ ->
         let nb = gui#main#hintNotebook in
         nb#goto_page ((nb#current_page + 1) mod 3))
  end

  (** </DEBUGGING> *)

let _ =
  at_exit (fun () -> print_endline "\nThanks for using Matita!\n");
  Sys.catch_break true;
  if Filename.basename Sys.argv.(0) = "cicbrowser" then begin (* cicbrowser *)
    Helm_registry.set "matita.mode" "cicbrowser";
    let browser = MatitaMathView.cicBrowser () in
    let entry =
      try
        `Uri (UriManager.uri_of_string Sys.argv.(1))
      with Invalid_argument _ -> `Dir "cic:/"
    in
    browser#load entry
  end else begin  (* matita *)
    Helm_registry.set "matita.mode" "matita";
    (try
       gui#loadScript Sys.argv.(1);
     with Invalid_argument _ -> ());
    gui#main#mainWin#show ();
  end;
  try
    GtkThread.main ()
  with Sys.Break -> ()