(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaGtkMisc
open MatitaTypes
open MatitaMisc

(** {2 Initialization} *)

let _ =
  Helm_registry.load_from "matita.conf.xml";  (* read conf *)
  Http_getter.init ();
  MetadataTypes.ownerize_tables (Helm_registry.get "matita.owner");
  MatitaDb.clean_owner_environment ();
  MatitaDb.create_owner_environment ();
  GtkMain.Rc.add_default_file BuildTimeConf.gtkrc;  (* loads gtk rc files *)
  ignore (GMain.Main.init ())

let gui = MatitaGui.instance ()
let disambiguator = MatitaDisambiguator.instance ()
let _ = (* set disambiguator callbacks *)
  disambiguator#setChooseUris (interactive_user_uri_choice ~gui);
  disambiguator#setChooseInterp (interactive_interp_choice ~gui)

let _ = (* environment trust *)
  CicEnvironment.set_trust
    (let trust = Helm_registry.get_bool "matita.environment_trust" in
     fun _ -> trust)

let currentProof = MatitaProof.instance ()

let sequent_viewer = MatitaMathView.sequent_viewer_instance ()
let sequents_viewer = MatitaMathView.sequents_viewer_instance ()
let _ = (* attach observers to proof status *)
  let browser_observer _ _ = MatitaMathView.refresh_all_browsers () in
  let sequents_observer _ (((_, metasenv, _, _), goal_opt), ()) =
    sequents_viewer#reset;
    (match goal_opt with
    | None -> ()
    | Some goal ->
        sequents_viewer#load_sequents metasenv;
        sequents_viewer#goto_sequent goal)
  in
  currentProof#addObserver sequents_observer;
  currentProof#addObserver browser_observer;
  currentProof#connect `Quit (fun () ->
    (* quit program, asking for confirmation if needed *)
    if not (currentProof#onGoing ()) ||
      (ask_confirmation ~gui
        ~msg:("Proof in progress, are you sure you want to quit?") ())
    then
      GMain.Main.quit ();
    false);
  currentProof#connect `Abort (fun () -> sequents_viewer#reset; false)

let interpreter =
  let mathViewer = MatitaMathView.mathViewer () in
  MatitaInterpreter.interpreter ~console:gui#console ~mathViewer ()
let script = MatitaScript.script ~interpreter
let _ =
  let href_callback uri =
    let term = CicAst.Uri (uri, None) in
    ignore (interpreter#evalAst (TacticAst.Command (TacticAst.Check term)))
  in
  sequent_viewer#set_href_callback (Some href_callback)

let console_callback s =
  let module A = TacticAst in
  let rec strip_locations = function
    | A.LocatedTactical (loc, tac) -> strip_locations tac
    | tac -> tac
  in
  let needed_by_script ast =
    prerr_endline (TacticAstPp.pp_tactical ast);
    match strip_locations ast with
    | A.Tactic _
    | A.Command
      (A.Inductive _ | A.Theorem _ | A.Coercion _ | A.Qed _ | A.Proof) ->
        true
    | _ -> false
  in
  let ast = disambiguator#parserr#parseTactical (Stream.of_string s) in
  if needed_by_script ast then
    script#advance ast
  else
    interpreter#evalAst ast

let console_callback s =
  match gui#console#wrap_exn (fun () -> console_callback s) with
  | None -> (false, false)
  | Some outcome -> outcome

(** {2 GUI callbacks} *)

let _ =
  gui#setQuitCallback currentProof#quit;
  gui#setPhraseCallback console_callback;
  gui#main#debugMenu#misc#hide ();
  ignore (gui#main#newProofMenuItem#connect#activate (fun _ ->
    gui#console#clear ();
    gui#console#show ~msg:"theorem " ()));
  ignore (gui#main#openMenuItem#connect#activate (fun _ ->
    match gui#chooseFile () with
    | None -> ()
    | Some f when is_proof_script f ->
        ignore (gui#console#wrap_exn (fun () -> script#loadFrom f))
    | Some f ->
        gui#console#echo_error (sprintf
          "Don't know what to do with file: %s\nUnrecognized file format."
          f)));
  ignore (gui#main#newCicBrowserMenuItem#connect#activate (fun _ ->
    ignore (MatitaMathView.cicBrowser ())));
  let module A = TacticAst in
  let hole = CicAst.UserInput in
  let tac ast _ =
    let ast = A.Tactic ast in
    ignore (interpreter#evalAst ast);
    ignore (script#advance ast)
  in
  let tac_w_term ast _ =
(*     gui#console#clear (); *)
    gui#console#show ~msg:(TacticAstPp.pp_tactic ast) ();
    gui#main#mainWin#present ()
  in
  let tbar = gui#toolbar in
  connect_button tbar#introsButton (tac (A.Intros (None, [])));
  connect_button tbar#applyButton (tac_w_term (A.Apply hole));
  connect_button tbar#exactButton (tac_w_term (A.Exact hole));
  connect_button tbar#elimButton (tac_w_term (A.Elim (hole, None)));
  connect_button tbar#elimTypeButton (tac_w_term (A.ElimType hole));
  connect_button tbar#splitButton (tac A.Split);
  connect_button tbar#leftButton (tac A.Left);
  connect_button tbar#rightButton (tac A.Right);
  connect_button tbar#existsButton (tac A.Exists);
  connect_button tbar#reflexivityButton (tac A.Reflexivity);
  connect_button tbar#symmetryButton (tac A.Symmetry);
  connect_button tbar#transitivityButton (tac_w_term (A.Transitivity hole));
  connect_button tbar#assumptionButton (tac A.Assumption);
  connect_button tbar#cutButton (tac_w_term (A.Cut hole));
  connect_button tbar#autoButton (tac A.Auto)

  (** <DEBUGGING> *)

let _ =
  if BuildTimeConf.debug then begin
    gui#main#debugMenu#misc#show ();
    let addDebugItem ~label callback =
      let item =
        GMenu.menu_item ~packing:gui#main#debugMenu_menu#append ~label ()
      in
      ignore (item#connect#activate callback)
    in
    addDebugItem "dump environment to \"env.dump\"" (fun _ ->
      let oc = open_out "env.dump" in
      CicEnvironment.dump_to_channel oc;
      close_out oc);
    addDebugItem "print selected terms" (fun () ->
      let i = ref 0 in
      List.iter
        (fun t -> incr i; debug_print (sprintf "%d: %s" !i (CicPp.ppterm t)))
        sequent_viewer#get_selected_terms);
    addDebugItem "dump getter settings" (fun _ ->
      prerr_endline (Http_getter_env.env_to_string ()));
    addDebugItem "getter: update" Http_getter.update;
    addDebugItem "getter: getalluris" (fun _ ->
      List.iter prerr_endline (Http_getter.getalluris ()));
  end

  (** </DEBUGGING> *)

let _ =
  (try script#loadFrom Sys.argv.(1) with Invalid_argument _ -> ());
  if Filename.basename Sys.argv.(0) = "cicbrowser" then begin (* cicbrowser *)
    Helm_registry.set "matita.mode" "cicbrowser";
    let browser = MatitaMathView.cicBrowser () in
    try
      browser#loadUri Sys.argv.(1)
    with Invalid_argument _ -> ()
  end else begin  (* matita *)
    Helm_registry.set "matita.mode" "matita";
    gui#main#mainWin#show ();
    gui#toolbar#toolBarWin#show ();
    gui#console#show ()
  end;
  GtkThread.main ()