(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaGtkMisc
open MatitaTypes
open MatitaMisc

(** {2 Initialization} *)

let _ =
  Helm_registry.load_from "matita.conf.xml";
  GtkMain.Rc.add_default_file BuildTimeConf.gtkrc;
  GMain.Main.init ()

let parserr = new MatitaDisambiguator.parserr ()
let dbd =
  Mysql.quick_connect
    ~host:(Helm_registry.get "db.host")
    ~user:(Helm_registry.get "db.user")
    ~database:(Helm_registry.get "db.database")
    ()
let _ = MetadataDb.clean ~dbd ~owner:(Helm_registry.get "matita.owner")
let gui = MatitaGui.instance ()
let disambiguator =
  new MatitaDisambiguator.disambiguator ~parserr ~dbd
    ~chooseUris:(interactive_user_uri_choice ~gui)
    ~chooseInterp:(interactive_interp_choice ~gui)
    ()

let currentProof = new MatitaProof.currentProof

let sequent_viewer = MatitaMathView.sequent_viewer ~show:true ()
let sequents_viewer =
  let set_goal goal =
    if not (currentProof#onGoing ()) then assert false;
    currentProof#proof#set_goal goal
  in
  MatitaMathView.sequents_viewer ~notebook:gui#main#sequentsNotebook
    ~sequent_viewer ~set_goal ()
let _ = (* attach observers to proof status *)
  let browser_observer _ _ = MatitaMathView.refresh_all_browsers () in
  let sequents_observer _ (((_, metasenv, _, _), goal_opt), ()) =
    sequents_viewer#reset;
    (match goal_opt with
    | None -> ()
    | Some goal ->
        sequents_viewer#load_sequents metasenv;
        sequents_viewer#goto_sequent goal)
  in
  currentProof#addObserver sequents_observer;
  currentProof#addObserver browser_observer;
  currentProof#connect `Quit (fun () ->
    (* quit program, asking for confirmation if needed *)
    if not (currentProof#onGoing ()) ||
      (ask_confirmation ~gui
        ~msg:("Proof in progress, are you sure you want to quit?") ())
    then
      GMain.Main.quit ();
    false);
  currentProof#connect `Abort (fun () -> sequents_viewer#reset; false)

let currentProof = (currentProof :> MatitaTypes.currentProof)
let mathViewer =
  MatitaMathView.mathViewer ~disambiguator
    ~currentProof:(currentProof :> MatitaTypes.currentProof) ()
let interpreter =
  let console = (gui#console :> MatitaTypes.console) in
  new MatitaInterpreter.interpreter
    ~disambiguator ~currentProof:(currentProof :> MatitaTypes.currentProof)
    ~console ~mathViewer ~dbd ()
let _ =
  let href_callback uri =
    let term = CicAst.Uri (UriManager.string_of_uri uri, None) in
    ignore (interpreter#evalAst (TacticAst.Command (TacticAst.Check term)))
  in
  sequent_viewer#set_href_callback (Some href_callback)

(** {2 Script window handling} *)

let script_forward _ =
  let buf = gui#script#scriptTextView#buffer in
  let locked_iter = buf#get_iter_at_mark (`NAME "locked") in
  let (success, hide) =
    interpreter#evalPhrase
      (buf#get_text ~start:locked_iter ~stop:buf#end_iter ())
  in
  if success then
    gui#lockScript (locked_iter#offset + interpreter#endOffset)

let script_jump _ =
  let buf = gui#script#scriptTextView#buffer in
  let locked_iter = buf#get_iter_at_mark (`NAME "locked") in
  let cursor_iter = buf#get_iter_at_mark (`NAME "insert") in
  let raw_text = buf#get_text ~start:locked_iter ~stop:cursor_iter () in
  let len = String.length raw_text in
  let rec parse offset =
    if offset < len then begin
      let (success, hide) =
        interpreter#evalPhrase (String.sub raw_text offset (len - offset))
      in
      if success then begin
        let new_offset = interpreter#endOffset + offset in
        gui#lockScript (new_offset + locked_iter#offset);
        parse new_offset
      end else
        raise Exit
    end
  in
  try
    parse 0
  with Exit -> ()

let script_back _ = not_implemented "script_back"

let load_script fname =
  gui#script#scriptTextView#buffer#set_text (input_file fname);
  gui#script#scriptWin#show ();
  gui#main#showScriptMenuItem#set_active true

(** {2 GUI callbacks} *)

let _ =
  gui#setQuitCallback currentProof#quit;
  gui#setPhraseCallback interpreter#evalPhrase;
  gui#main#debugMenu#misc#hide ();
  ignore (gui#main#newProofMenuItem#connect#activate (fun _ ->
    gui#console#clear ();
    gui#console#show ~msg:"theorem " ()));
  ignore (gui#main#openMenuItem#connect#activate (fun _ ->
    match gui#chooseFile () with
    | None -> ()
    | Some f when is_proof_script f -> load_script f
    | Some f ->
        gui#console#echo_error (sprintf
          "Don't know what to do with file: %s\nUnrecognized file format."
          f)));
  ignore (gui#main#newCicBrowserMenuItem#connect#activate (fun _ ->
    let currentProof = (currentProof :> MatitaTypes.currentProof) in
    ignore (MatitaMathView.cicBrowser ~disambiguator ~currentProof ())));
  connect_button gui#script#scriptWinForwardButton script_forward;
  connect_button gui#script#scriptWinBackButton script_back;
  connect_button gui#script#scriptWinJumpButton script_jump;
  let module A = TacticAst in
  let hole = CicAst.UserInput in
  let tac ast _ = ignore (interpreter#evalAst (A.Tactic ast)) in
  let tac_w_term ast _ =
(*     gui#console#clear (); *)
    gui#console#show ~msg:(TacticAstPp.pp_tactic ast) ();
    gui#main#mainWin#present ()
  in
  let tbar = gui#toolbar in
  connect_button tbar#introsButton (tac (A.Intros (None, [])));
  connect_button tbar#applyButton (tac_w_term (A.Apply hole));
  connect_button tbar#exactButton (tac_w_term (A.Exact hole));
  connect_button tbar#elimButton (tac_w_term (A.Elim (hole, None)));
  connect_button tbar#elimTypeButton (tac_w_term (A.ElimType hole));
  connect_button tbar#splitButton (tac A.Split);
  connect_button tbar#leftButton (tac A.Left);
  connect_button tbar#rightButton (tac A.Right);
  connect_button tbar#existsButton (tac A.Exists);
  connect_button tbar#reflexivityButton (tac A.Reflexivity);
  connect_button tbar#symmetryButton (tac A.Symmetry);
  connect_button tbar#transitivityButton (tac_w_term (A.Transitivity hole));
  connect_button tbar#assumptionButton (tac A.Assumption);
  connect_button tbar#cutButton (tac_w_term (A.Cut hole));
  connect_button tbar#autoButton (tac A.Auto)

  (** <DEBUGGING> *)

let _ =
  if BuildTimeConf.debug then begin
    gui#main#debugMenu#misc#show ();
    let addDebugItem ~label callback =
      let item =
        GMenu.menu_item ~packing:gui#main#debugMenu_menu#append ~label ()
      in
      ignore (item#connect#activate callback)
    in
    addDebugItem "toggle auto disambiguation" (fun _ ->
      Helm_registry.set_bool "matita.auto_disambiguation"
        (not (Helm_registry.get_bool "matita.auto_disambiguation")));
    addDebugItem "dump proof status to stdout" (fun _ ->
      print_endline (currentProof#proof#toString));
    addDebugItem "dump environment to \"env.dump\"" (fun _ ->
      let oc = open_out "env.dump" in
      CicEnvironment.dump_to_channel oc;
      close_out oc);
    addDebugItem "print selected terms" (fun () ->
      let i = ref 0 in
      List.iter
        (fun t -> incr i; debug_print (sprintf "%d: %s" !i (CicPp.ppterm t)))
        sequent_viewer#get_selected_terms);
    addDebugItem "refresh all browsers" MatitaMathView.refresh_all_browsers;
  end

  (** </DEBUGGING> *)

let _ =
(*   CicEnvironment.set_trust (fun _ -> false); *)
(*
  (try
    load_script Sys.argv.(1)
  with Invalid_argument _ -> ());
*)
  if Pcre.pmatch ~pat:"cicbrowser$" Sys.argv.(0) then begin
    ignore (MatitaMathView.cicBrowser ~disambiguator ~currentProof ())
  end else begin
    gui#main#mainWin#show ();
    gui#toolbar#toolBarWin#show ();
    gui#console#show ()
  end;
  GtkThread.main ()