(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let default_prompt = "# "
let default_phrase_sep = "."
let default_callback = fun (phrase: string) -> ()

let history_size = 100

let message_props = [ `STYLE `ITALIC ]
let error_props = [ `WEIGHT `BOLD ]
let prompt_props = [ ]

let trailing_NL_RE = Pcre.regexp "\n\\s*$"

class console
  ?(prompt = default_prompt) ?(phrase_sep = default_phrase_sep)
  ?(callback = default_callback)
  obj
=
  object (self)
    inherit GText.view obj

    val mutable _phrase_sep = phrase_sep
    method phrase_sep = _phrase_sep
    method set_phrase_sep sep = _phrase_sep <- sep

    val mutable _callback = callback
    method set_callback f = _callback <- f

    val mutable _ignore_insert_text_signal = false
    method ignore_insert_text_signal ignore =
      _ignore_insert_text_signal <- ignore

(*
    (* TODO Zack: implement history.
       IDEA: use CTRL-P/N a la emacs.
       ISSUE: per-phrase or per-line history? *)
    val phrases_history = Array.create history_size None
    val mutable history_last_index = -1
    val mutable history_cur_index = -1
*)

    initializer
      let buf = self#buffer in
      self#set_wrap_mode `CHAR;
        (* create "USER_INPUT_START" mark. This mark will always point to the
        * beginning of user input not yet processed *)
      ignore (buf#create_mark ~name:"USER_INPUT_START"
        ~left_gravity:true buf#start_iter);
      ignore (buf#connect#after#insert_text (fun iter text ->
        if (not _ignore_insert_text_signal) &&
          (iter#compare buf#end_iter = 0) &&  (* insertion at end *)
          (Pcre.pmatch ~rex:trailing_NL_RE text)
        then
          let inserted_text =
            buf#get_text
              ~start:(buf#get_iter_at_mark (`NAME "USER_INPUT_START"))
              ~stop:buf#end_iter ()
          in
          let pat = (Pcre.quote _phrase_sep) ^ "\\s*$" in
          if Pcre.pmatch ~pat inserted_text then begin (* complete phrase *)
            self#lock;
            _callback inserted_text;
            self#echo_prompt ()
          end))

      (* lock old text and bump USER_INPUT_START mark *)
    method private lock =
      let buf = self#buffer in
      let read_only = buf#create_tag [`EDITABLE false] in
      buf#apply_tag read_only ~start:buf#start_iter ~stop:buf#end_iter;
      buf#move_mark (`NAME "USER_INPUT_START") buf#end_iter

    method echo_prompt () =
      let buf = self#buffer in
      self#ignore_insert_text_signal true;
      buf#insert ~iter:buf#end_iter ~tags:[buf#create_tag prompt_props] prompt;
      self#ignore_insert_text_signal false;
      self#lock

    method echo_message msg =
      let buf = self#buffer in
      self#ignore_insert_text_signal true;
      buf#insert ~iter:buf#end_iter ~tags:[buf#create_tag message_props]
        (msg ^ "\n");
      self#ignore_insert_text_signal false;
      self#lock

    method echo_error msg =
      let buf = self#buffer in
      self#ignore_insert_text_signal true;
      buf#insert ~iter:buf#end_iter ~tags:[buf#create_tag error_props]
        (msg ^ "\n");
      self#ignore_insert_text_signal false;
      self#lock
  end

let console
  ?(prompt = default_prompt) ?(phrase_sep = default_phrase_sep)
  ?(callback = default_callback)
  ?buffer ?editable ?cursor_visible ?justification ?wrap_mode ?border_width
  ?width ?height ?packing ?show ()
=
  let view =
    GText.view
      ?buffer ?editable ?cursor_visible ?justification ?wrap_mode ?border_width
      ?width ?height ?packing ?show ()
  in
  new console ~prompt ~phrase_sep ~callback view#as_view