(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaTypes

exception Ambiguous_input
exception DisambiguationError of string Lazy.t list list

type choose_uris_callback =
  id:string -> UriManager.uri list -> UriManager.uri list

type choose_interp_callback = (string * string) list list -> int list

let mono_uris_callback ~id =
 if Helm_registry.get_bool "matita.auto_disambiguation" then
  function l -> l
 else
  raise Ambiguous_input

let mono_interp_callback _ = raise Ambiguous_input

let _choose_uris_callback = ref mono_uris_callback
let _choose_interp_callback = ref mono_interp_callback
let set_choose_uris_callback f = _choose_uris_callback := f
let set_choose_interp_callback f = _choose_interp_callback := f

module Callbacks =
  struct
    let interactive_user_uri_choice ~selection_mode ?ok
          ?(enable_button_for_non_vars = true) ~title ~msg ~id uris =
              !_choose_uris_callback ~id uris

    let interactive_interpretation_choice interp =
      !_choose_interp_callback interp

    let input_or_locate_uri ~(title:string) ?id =
      (* Zack: I try to avoid using this callback. I therefore assume that
      * the presence of an identifier that can't be resolved via "locate"
      * query is a syntax error *)
      let msg = match id with Some id -> id | _ -> "_" in
      raise (Unbound_identifier msg)
  end
  
module Disambiguator = Disambiguate.Make (Callbacks)

(* implement module's API *)

let disambiguate_thing ~aliases ~universe
  ~(f:?fresh_instances:bool ->
      aliases:DisambiguateTypes.environment ->
      universe:DisambiguateTypes.multiple_environment option ->
      'a -> 'b)
  ~(drop_aliases: 'b -> 'b)
  ~(drop_aliases_and_clear_diff: 'b -> 'b)
  (thing: 'a)
=
  assert (universe <> None);
  let library = false, DisambiguateTypes.Environment.empty, None in
  let multi_aliases=false, DisambiguateTypes.Environment.empty, universe in
  let mono_aliases = true, aliases, None in
  let passes =  (* <fresh_instances?, aliases, coercions?> *)
    [ (false, mono_aliases, false);
      (false, multi_aliases, false);
      (true, mono_aliases, false);
      (true, multi_aliases, false);
      (true, mono_aliases, true);
      (true, multi_aliases, true);
      (true, library, true);
    ]
  in
  let try_pass (fresh_instances, (_, aliases, universe), use_coercions) =
    CoercDb.use_coercions := use_coercions;
    f ~fresh_instances ~aliases ~universe thing
  in
  let set_aliases (instances,(use_mono_aliases,_,_),_) (_, user_asked as res) =
   if use_mono_aliases && not instances then
    drop_aliases res
   else if user_asked then
    drop_aliases res (* one shot aliases *)
   else
    drop_aliases_and_clear_diff res
  in
  let rec aux errors =
    function
    | [ pass ] ->
        (try
          set_aliases pass (try_pass pass)
         with Disambiguate.NoWellTypedInterpretation newerrors ->
          raise (DisambiguationError (errors @ [newerrors])))
    | hd :: tl ->
        (try
          set_aliases hd (try_pass hd)
        with Disambiguate.NoWellTypedInterpretation newerrors ->
         aux (errors @ [newerrors]) tl)
    | [] -> assert false
  in
  let saved_use_coercions = !CoercDb.use_coercions in
  try
    let res = aux [] passes in
    CoercDb.use_coercions := saved_use_coercions;
    res
  with exn ->
    CoercDb.use_coercions := saved_use_coercions;
    raise exn

type disambiguator_thing =
 { do_it :
    'a 'b.
    aliases:DisambiguateTypes.environment ->
    universe:DisambiguateTypes.multiple_environment option ->
    f:(?fresh_instances:bool ->
       aliases:DisambiguateTypes.environment ->
       universe:DisambiguateTypes.multiple_environment option ->
       'a -> 'b * bool) ->
    drop_aliases:('b * bool -> 'b * bool) ->
    drop_aliases_and_clear_diff:('b * bool -> 'b * bool) -> 'a -> 'b * bool
 }

let disambiguate_thing =
 let profiler = HExtlib.profile "disambiguate_thing" in
  { do_it =
     fun ~aliases ~universe ~f ~drop_aliases ~drop_aliases_and_clear_diff thing
     -> profiler.HExtlib.profile
         (disambiguate_thing ~aliases ~universe ~f ~drop_aliases
           ~drop_aliases_and_clear_diff) thing
  }

let drop_aliases (choices, user_asked) =
  (List.map (fun (d, a, b, c) -> d, a, b, c) choices),
  user_asked

let drop_aliases_and_clear_diff (choices, user_asked) =
  (List.map (fun (_, a, b, c) -> [], a, b, c) choices),
  user_asked

let disambiguate_term ?fresh_instances ~dbd ~context ~metasenv ?initial_ugraph
  ~aliases ~universe term
 =
  assert (fresh_instances = None);
  let f =
    Disambiguator.disambiguate_term ~dbd ~context ~metasenv ?initial_ugraph
  in
  disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
   ~drop_aliases_and_clear_diff term

let disambiguate_obj ?fresh_instances ~dbd ~aliases ~universe ~uri obj =
  assert (fresh_instances = None);
  let f = Disambiguator.disambiguate_obj ~dbd ~uri in
  disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
   ~drop_aliases_and_clear_diff obj