(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let toggle_visibility ~(win: GWindow.window) ~(check: GMenu.check_menu_item) =
  ignore (check#connect#toggled (fun _ ->
    if check#active then win#show () else win#misc#hide ()));
  ignore (win#event#connect#delete (fun _ ->
    win#misc#hide ();
    check#set_active false;
    true))

let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  if win#is_active then win#misc#hide () else win#show ();
  match check with
  | None -> ()
  | Some check -> check#set_active (not check#active)

let add_key_binding key callback (evbox: GBin.event_box) =
  ignore (evbox#event#connect#key_press (function
    | key' when GdkEvent.Key.keyval key' = key ->
        callback ();
        false
    | _ -> false))

class stringListModel (tree_view: GTree.view) =
  let column_list = new GTree.column_list in
  let text_column = column_list#add Gobject.Data.string in
  let list_store = GTree.list_store column_list in
  object (self)

    initializer
      let renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
      let view_column = GTree.view_column ~renderer () in
      tree_view#set_model (Some (list_store :> GTree.model));
      ignore (tree_view#append_column view_column)

    method list_store = list_store

    method easy_append s =
      let tree_iter = list_store#append () in
      list_store#set ~row:tree_iter ~column:text_column s

    method easy_insert pos s =
      let tree_iter = list_store#insert pos in
      list_store#set ~row:tree_iter ~column:text_column s

    method easy_selection () =
      List.map
        (fun tree_path ->
          let iter = list_store#get_iter tree_path in
          list_store#get ~row:iter ~column:text_column)
        tree_view#selection#get_selected_rows

  end

let is_var_uri s =
  try
    String.sub s (String.length s - 4) 4 = ".var"
  with Invalid_argument _ -> false

let non p x = not (p x)

class type gui =
  object
    method newUriDialog: unit -> MatitaGeneratedGui.uriChoiceDialog
    method newConfirmationDialog :
      title:string -> msg:string -> unit ->
        MatitaGeneratedGui.confirmationDialog
  end

let interactive_user_uri_choice
  ~(gui:#gui) ~(selection_mode:Gtk.Tags.selection_mode) ?(title = "")
  ?(msg = "") ?(nonvars_button=false) uris
=
  let nonvars_uris = lazy (List.filter (non is_var_uri) uris) in
  if (selection_mode <> `SINGLE) &&
    (Helm_registry.get_bool "matita.auto_disambiguation")
  then
    Lazy.force nonvars_uris
  else begin
    let dialog = gui#newUriDialog () in
    dialog#uriChoiceTreeView#selection#set_mode selection_mode;
    let model = new stringListModel dialog#uriChoiceTreeView in
    let choices = ref None in
    let nonvars = ref false in
    dialog#uriChoiceDialog#set_title title;
    dialog#uriChoiceLabel#set_text msg;
    List.iter model#easy_append uris;
    dialog#uriChoiceConstantsButton#misc#set_sensitive nonvars_button;
    let return v =
      choices := v;
      dialog#uriChoiceDialog#destroy ();
      GMain.Main.quit ()
    in
    ignore (dialog#uriChoiceConstantsButton#connect#clicked (fun _ ->
      return (Some (Lazy.force nonvars_uris))));
    ignore (dialog#uriChoiceAutoButton#connect#clicked (fun _ ->
      Helm_registry.set_bool "matita.auto_disambiguation" true;
      return (Some (Lazy.force nonvars_uris))));
    ignore (dialog#uriChoiceSelectedButton#connect#clicked (fun _ ->
      match model#easy_selection () with
      | [] -> ()
      | uris -> return (Some uris)));
    ignore (dialog#uriChoiceAbortButton#connect#clicked (fun _ -> return None));
    ignore (dialog#uriChoiceDialog#event#connect#delete (fun _ -> true));
    dialog#uriChoiceDialog#show ();
    GtkThread.main ();
    (match !choices with 
    | None -> raise MatitaTypes.No_choice
    | Some uris -> uris)
  end

let interactive_interp_choice ~(gui:#gui) choices =
  (* TODO Zack implement interactive_interp_choice *)
  MatitaTypes.warning
    "'interactive_interp_choice' not implemented: returning 1st interpretation";
  [0]

let ask_confirmation ~(gui:#gui) ?(title = "") ?(msg = "") () =
  let dialog = gui#newConfirmationDialog ~title ~msg () in
  let result = ref None in
  let return r _ =
    result := Some r;
    dialog#confirmationDialog#destroy ();
    GMain.Main.quit ()
  in
  ignore (dialog#confirmationDialogOkButton#connect#clicked (return true));
  ignore (dialog#confirmationDialogCancelButton#connect#clicked (return false));
  ignore (dialog#confirmationDialog#event#connect#delete (fun _ -> true));
  dialog#confirmationDialog#show ();
  GtkThread.main ();
  (match !result with None -> assert false | Some r -> r)