(* Copyright (C) 2000-2002, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

open Printf

open MatitaCicMisc
open MatitaTypes

(* List utility functions *)
exception Skip

let list_map_fail f =
 let rec aux =
  function
     [] -> []
   | he::tl ->
      try
       let he' = f he in
        he'::(aux tl)
      with Skip ->
       (aux tl)
 in
  aux

class proof_viewer obj =
 object(self)

  inherit GMathViewAux.single_selection_math_view obj

(*   initializer self#set_log_verbosity 3 *)

  val mutable current_infos = None
  val mutable current_mathml = None

  method load_proof ((uri_opt, _, _, _) as proof, (goal_opt: int option)) =
    let (annobj, ids_to_terms, ids_to_father_ids, ids_to_inner_sorts,
        ids_to_inner_types, ids_to_conjectures, ids_to_hypotheses) =
      Cic2acic.acic_object_of_cic_object (cicCurrentProof proof)
    in
    current_infos <- Some (ids_to_terms, ids_to_father_ids, ids_to_conjectures,
      ids_to_hypotheses);
    let mathml =
      ApplyTransformation.mml_of_cic_object ~explode_all:true
        (unopt_uri uri_opt) annobj ids_to_inner_sorts ids_to_inner_types
    in
    match current_mathml with
    |  None ->
        debug_print "no previous MathML";
        self#load_root ~root:mathml#get_documentElement ;
        current_mathml <- Some mathml
    | Some current_mathml ->
        debug_print "Previous MathML available: xmldiffing ...";
        self#freeze ;
        XmlDiff.update_dom ~from:current_mathml mathml ;
        self#thaw
  end

class sequent_viewer obj =
 object(self)

  inherit GMathViewAux.multi_selection_math_view obj

  val mutable current_infos = None

  method get_selected_terms =
   let selections = self#get_selections in
    list_map_fail
     (function node ->
       let xpath =
        ((node : Gdome.element)#getAttributeNS
          ~namespaceURI:Misc.helmns
          ~localName:(Gdome.domString "xref"))#to_string
       in
        if xpath = "" then assert false (* "ERROR: No xref found!!!" *)
        else
         match current_infos with
            Some (ids_to_terms,_,_) ->
             let id = xpath in
              (try
                Hashtbl.find ids_to_terms id
               with _ -> raise Skip)
          | None -> assert false (* "ERROR: No current term!!!" *)
     ) selections

  method get_selected_hypotheses =
   let selections = self#get_selections in
    list_map_fail
     (function node ->
       let xpath =
        ((node : Gdome.element)#getAttributeNS
          ~namespaceURI:Misc.helmns
          ~localName:(Gdome.domString "xref"))#to_string
       in
        if xpath = "" then assert false (* "ERROR: No xref found!!!" *)
        else
         match current_infos with
            Some (_,_,ids_to_hypotheses) ->
             let id = xpath in
              (try
                Hashtbl.find ids_to_hypotheses id
               with _ -> raise Skip)
          | None -> assert false (* "ERROR: No current term!!!" *)
     ) selections
  
  method load_sequent metasenv metano =
(*
    let (annconjecture, ids_to_terms, ids_to_father_ids, ids_to_inner_sorts,
        ids_to_hypotheses) =
      Cic2acic.asequent_of_sequent metasenv conjecture
    in
*)
    let sequent = CicUtil.lookup_meta metano metasenv in
    let (mathml, (ids_to_terms, ids_to_father_ids, ids_to_hypotheses)) =
      ApplyTransformation.mml_of_cic_sequent metasenv sequent
    in
    current_infos <- Some (ids_to_terms, ids_to_father_ids, ids_to_hypotheses);
    debug_print "load_sequent: dumping MathML to /tmp/prova";
    ignore (Misc.domImpl#saveDocumentToFile ~name:"/tmp/prova" ~doc:mathml ());
    self#load_root ~root:mathml#get_documentElement
 end


class sequents_viewer ~(notebook:GPack.notebook)
  ~(sequent_viewer:MatitaTypes.sequent_viewer) ~set_goal ()
=
  object (self)
    val mutable pages = 0
    val mutable switch_page_callback = None
    val mutable page2goal = []  (* associative list: page no -> goal no *)
    val mutable goal2page = []  (* the other way round *)
    val mutable _metasenv = []

    method reset =
      for i = 1 to pages do notebook#remove_page 0 done;
      pages <- 0;
      page2goal <- [];
      goal2page <- [];
      _metasenv <- [];
      (match switch_page_callback with
      | Some id ->
          GtkSignal.disconnect notebook#as_widget id;
          switch_page_callback <- None
      | None -> ())

    method load_sequents metasenv =
      let sequents_no = List.length metasenv in
      _metasenv <- metasenv;
      debug_print (sprintf "sequents no: %d" sequents_no);
      pages <- sequents_no;
      let widget = sequent_viewer#coerce in
      let page = ref 0 in
      List.iter
        (fun (metano, _, _) ->
          page2goal <- (!page, metano) :: page2goal;
          goal2page <- (metano, !page) :: goal2page;
          incr page;
          let tab_label =
            (GMisc.label ~text:(sprintf "?%d" metano) ~show:true ())#coerce
          in
          notebook#append_page ~tab_label widget)
        metasenv;
      switch_page_callback <-
        (* TODO Zack the "#after" may probably be removed after Luca's fix for
        * widget not loading documents before being realized *)
        Some (notebook#connect#after#switch_page ~callback:(fun page ->
          debug_print "switch_page callback";
          let goal =
            try
              List.assoc page page2goal
            with Not_found -> assert false
          in
          set_goal goal;
          self#render_page goal))

    method private render_page goal =
      sequent_viewer#load_sequent _metasenv goal

    method goto_sequent goal =
      let page =
        try
          List.assoc goal goal2page
        with Not_found -> assert false
      in
      notebook#goto_page page;
      self#render_page goal

  end

 (** constructors *)

let sequent_viewer ?hadjustment ?vadjustment ?font_size ?log_verbosity =
  GtkBase.Widget.size_params
    ~cont:(OgtkMathViewProps.pack_return (fun p ->
      OgtkMathViewProps.set_params
        (new sequent_viewer (GtkMathViewProps.MathView_GMetaDOM.create p))
        ~font_size ~log_verbosity))
    []

let proof_viewer ?hadjustment ?vadjustment ?font_size ?log_verbosity =
  GtkBase.Widget.size_params
    ~cont:(OgtkMathViewProps.pack_return (fun p ->
      OgtkMathViewProps.set_params
        (new proof_viewer (GtkMathViewProps.MathView_GMetaDOM.create p))
        ~font_size ~log_verbosity))
    []

let sequents_viewer ~(notebook:GPack.notebook)
  ~(sequent_viewer:MatitaTypes.sequent_viewer) ~set_goal ()
=
  new sequents_viewer ~notebook ~sequent_viewer ~set_goal ()